                             PDP COMPUTER
                MASSACHUSETTS INSTITUTE OF TECHNOLOGY
                     CAMBRIDGE 39, MASSACHUSETTS



                           MEMORANDUM PDP-2

                                                      October 9, 1961

               PDP BINARY TAPE FORMAT AND INPUT ROUTINE

     The binary tape format for PDP under consideration in this
memorandum has the following features:
         1)  A short (27 octal registers) input-routine
         2)  Easy to hand-read block format
         3)  Sum checking on each block
     The input routine (attached) occupies registers 7751 through
7777, and is entered at location 7751.
     The standard tape format is:
         1)  Title in hand-readable format (i.e., no 8th hole).
             This part is optional.
         2)  Input routine in read-in mode terminated by a "jmp 7751".
         3)  Data blocks consisting of
                 dio fa
                 dio la+1
                 (la-fa+1 data words)
                    .
                    .
                    .
                 checksum (sum of all other words in this block)
         4)  A word "jmp x" (where x is the first executed instruction
             of the program).
     There may be as many data blocks as desired.  The length of each
block is arbitrary; however, it is desirable to limit each block to a
maximum of 100 (octal) words.  Blocks are generally separated by 5 lines
of blank tape.
     The jmp x instruction at the end of the tape is executed without an
intervening halt, so if it is desired for the program to halt, a suitable
instruction should be placed in the loaded program. 
     Should the computer stop before reaching the end of the tape, two
alternatives are available:
         1)  Start over at the beginning of the tape.
         2)  Pull the tape back one block and continue.
The first choice is safer, since the error may have caused a previously
read in portion of memory to have been changed.
     This format is the one punched by PDP-1 PUNCHY and the soon to be
available TX-0 PROGRAM TRANSLATOR.



                                                      Alan KotokPDP-1 Input Routine

readin

7751|

in,	rpb
	dio a
	xct a
	dio ck
	rpb
	dio en1
b,	rpb
a,	xx
	lac i a
	add ck
	dac ck
	idx a
	sas en1
	jmp b
	lac ck
	add en1
	rpb
	dio ck
	sas ck
	hlt
	jmp in
ck,	0
en1,	0

start add in
