100 REM: ******************** LOAN **********************
110 REM:
120 REM: PROGRAM TO COMPUTE INTEREST PAYMENTS
130 REM:
140 REM: BY BOB SCALF, 22 APRIL 1978
150 REM:
160 INPUT "INTEREST IN PERCENT";J
170 J=J/100
180 INPUT"AMOUNT OF LOAN";A
190 INPUT"NUMBER OF YEARS";N
200 INPUT"NO. OF PAYMENTS PER YEAR";M
210 N=N*M: I=J/M: B=1+I: R=A*I/(1-1/B^N)
220 A$=" ###        $###.##          $###.##         $#####.##"
230 PRINT:PRINT "AMOUNT PER PAYMENT =  ";
240 PRINT USING "$###.##";R
250 PRINT "TOTAL INTEREST     =  ";
260 PRINT USING "$#####.##";R*N-A
270 PRINT: B=A
280 X$=" MONTH      INTEREST        PRINCIPAL     PRIN. BALANCE"
290 Y=1
300 PRINT "YEAR -";Y:PRINT
310 PRINT X$
320 X=1:II=0
330 L=B*I: P=R-L: B=B-P
340 II=II+L
350 PRINT USING A$;X,L,P,B
360 X=X+1
370 IF X<13 THEN 420
380 PRINT:PRINT"INTEREST FOR YEAR - ";
390 PRINT USING "$####.##";II:PRINT
400 X=1:Y=Y+1:PRINT:PRINT "YEAR -";Y:PRINT:PRINT X$:PRINT
410 II=0
420 IF B>=R THEN 330
430 PRINT B*I,R-B*I
440 PRINT "LAST PAYMENT WAS "B*I+B
450 PRINT:PRINT "INTEREST FOR YEAR - ";
460 PRINT USING "$###.##";II:PRINT
470 END
B*I
440 PRINT "LAST PA