10 PRINT CHR$(26):REM SCREEN CLEAR
20 PRINT"YOU ARE NOW GOING TO PLAY A COMPUTERIZED VERSION OF BINGO--"
30 PRINT
40 CLEAR
50 IF PEEK(3)<>3 THEN X1=14 ELSE X1=2:REM Define STATUS port
60 PRINT:PRINT:PRINT
70 F=1
80 V=0
90 DIM B(10,10),L(75)
100 FOR I=1 TO 5:READ A$(I):NEXT I
110 DATA B,I,N,G,O
120 FOR K1=1 TO 75
130 LET L(K1)=0
140 NEXT K1
150 LINEINPUT "PRESS RETURN TO PRINT CARDS >";A$
160 IF X1=14 THEN POKE 3,3:REM TURN ON HARD COPY
170 PRINT:PRINT" ","     HERE'S ";
180 IF F>1 THEN 210
190 PRINT"YOUR CARD"
200 GOTO 220
210 PRINT"MY CARD"
220 M=16:G=F+4
230 FOR Y=F TO G
240 FOR X=F TO G
250 R=INT(RND(1)*M)
260 IF R<M-15 THEN 250
270 IF L(R)<>0 THEN 250
280 LET B(X,Y)=R
290 LET L(R)=1
300 NEXT X
310 M=M+15
320 NEXT Y
330 PRINT
340 PRINT"--B--","--I--","--N--","--G--","--O--"
350 FOR X=F TO G
360 PRINT:PRINT
370 FOR Y=F TO G
380 IF B(X,Y)=B(F+2,F+2) THEN 410
390 PRINT B(X,Y),
400 GOTO 420
410 PRINT"FREE",
420 NEXT Y
430 NEXT X
440 PRINT:PRINT
450 PRINT"-----------------------------------------------------------";
460 PRINT"-----------"
470 PRINT"      (TEAR OFF AFTER MACHINE AUTOMATICALLY ADVANCES PAPER)"
480 FOR K9=1 TO 9
490 PRINT
500 NEXT K9
510 IF X1=14 THEN POKE 3,1:REM TURN OFF HARD COPY
520 FOR Z=1 TO 3000:NEXT Z
530 IF F=6 THEN 560
540 F=6
550 GOTO 120
560 PRINT
570 PRINT"NOW WE'RE ALL SET TO PLAY THE GAME. USE A PENCIL TO MARK OFF"
580 PRINT"THE NUMBERS ON YOUR CARD AS THEY ARE CALLED."
590 PRINT"  (PLEASE PLAY MY CARD AS WELL AS YOUR OWN)"
600 PRINT"***DON'T GET SMART. I'LL BE PLAYING BOTH YOUR CARD AND MINE."
610 PRINT"IMPORTANT: DON'T FORGET TO MARK OFF THE FREE SPACE!"
620 PRINT
630 INPUT"ARE YOU READY";R$
640 IF LEFT$(R$,1)<>"N" THEN 680
650 PRINT
660 PRINT"**********!HURRY UP!**********"
670 GOTO 620
680 FOR K1=1 TO 75
690 LET L(K1)=0
700 NEXT K1
710 PRINT
720 LET B(3,3)=0
730 LET B(8,8)=0
740 LET U=INT(75*RND(2)+1)
750 IF L(U)<>0 THEN 740
760 LET L(U)=1
770 IF RND(3)>.5 THEN 800
780 PRINT"THE NUMBER COMES UP:",
790 GOTO 810
800 PRINT"THE NEXT ONE IS:",
810 PRINT A$(INT((U-1)/15)+1);U
820 FOR Y=1 TO 10
830 FOR X=1 TO 10
840 IF B(X,Y)=U THEN 960
850 NEXT X
860 NEXT Y
870 F=1
880 GOSUB 980
890 F=6
900 GOSUB 980
910 IF V=0 THEN 940
920 IF W=1 THEN 1600
930 GOTO 1670
940 IF W=0 THEN 740
950 GOTO 1730
960 LET B(X,Y)=0
970 GOTO 850
980 G=F+4
990 FOR Y=F TO G
1000 FOR X=F TO G
1010 IF B(X,Y)<>0 THEN 1130
1020 IF X<F+4 THEN 1120
1030 IF F=6 THEN 1080
1040 PRINT
1050 PRINT"YOU'VE GOT A  B I N G O * * *"
1060 W=1
1070 RETURN
1080 PRINT
1090 PRINT"I'VE GOT A  B I N G O * * * * *"
1100 V=1
1110 GOTO 1140
1120 NEXT X
1130 NEXT Y
1140 G=F+4
1150 FOR X=F TO G
1160 FOR Y=F TO G
1170 IF B(X,Y)<>0 THEN 1290
1180 IF Y<F+4 THEN 1280
1190 IF F=6 THEN 1240
1200 PRINT
1210 PRINT"YOU'VE GOT A  B I N G O * * *"
1220 W=1
1230 RETURN
1240 PRINT
1250 PRINT"I'VE GOT A  B I N G O * * * * *"
1260 V=1
1270 GOTO 1300
1280 NEXT Y
1290 NEXT X
1300 LET X=F
1310 LET Y=F
1320 IF B(X,Y)<>0 THEN 1440
1330 X=X+1
1340 Y=Y+1
1350 IF Y<F+5 THEN 1320
1360 IF Y=11 THEN 1420
1370 W=1
1380 PRINT
1390 PRINT"YOU'VE GOT A  B I N G O * * *"
1400 RETURN
1410 PRINT
1420 PRINT"I'VE GOT A  B I N G O * * * * *"
1430 V=1
1440 RETURN
1450 X=F+4
1460 LET Y=X
1470 IF B(X,Y)<>0 THEN 1590
1480 X=X-1
1490 Y=Y+1
1500 IF Y<F+5 THEN 1470
1510 IF Y=11 THEN 1560
1520 PRINT
1530 PRINT"YOU'VE GOT A  B I N G O * * *"
1540 W=1
1550 RETURN
1560 PRINT
1570 PRINT"I'VE GOT A  B I N G O * * * * *"
1580 V=1
1590 RETURN
1600 PRINT
1610 PRINT" ********** IT'S A TIE **********"
1620 PRINT
1630 INPUT"DO YOU WANT TO PLAY AGAIN";E$
1640 PRINT
1650 IF LEFT$(E$,1)="Y" THEN 30
1660 GOTO 1760
1670 PRINT
1680 FOR S=1 TO 6
1690 PRINT"I WIN. ";
1700 NEXT S
1710 PRINT
1720 GOTO 1620
1730 PRINT
1740 PRINT"  YOU WIN..... YOU WIN..... YOU WIN....."
1750 GOTO 1620
1760 FOR I=1 TO 500:NEXT I
1770 RUN "DIR"
1780 END
T
1740 PRINT"  YOU WIN..... YOU WIN..... YOU WIN....."
1750 GOTO 1620
1760 FOR I=1 TO 500:NEXT I
1770 RUN "D