10 '   THIS PROGRAM IS WHAT YOU COULD CALL A "MASTER" BASIC FILE.
20 '   WITH THIS PROGRAM YOU MAY RUN A FILE WITHOUT TYPING "RUN" -
30 '   JUST TYPE IN THE NAME OF THE BASIC FILE AND THIS FILE
40 '   WILL DO THE REST.
50 '   YOU MAY ALSO "KILL" FILES FROM WITHIN THIS FILE. ALSO YOU 
60 '   CAN "RESET" THE DISK DRIVE WITH THE COMMAND `RESET',
70 '   YOU CAN SEE `BASIC' FILES OR `ALL' FILES,
80 '   AND WITH JUST ONE LETTER + A `RETURN' YOU MAY GO DIRECTLY 
90 '   TO THE `COMMAND MODE'.
100 '
110 '
120 '                    PROGRAM BY: PATRICK J. DURHAM
130 '                                OAK FOREST, ILL. 60452
140 '                                (1-312) 535-2048
150 PRINT CHR$(26)
160 CLEAR
170 PRINT
180 ON ERROR GOTO 410
190 FILES "*.BAS"
200 PRINT"===================================================================="
210 PRINT TAB(9)"ENTER ANY FILE FROM ABOVE AT THE PROMPT TO RUN, or...
220 PRINT:PRINT"TYPE <RESET>                TO RESET SYSTEM FROM `DISK CHANGE'":PRINT
230 PRINT"TYPE < CR  >                TO RETURN TO `SYSTEM'":PRINT
240 PRINT"TYPE < ALL >                TO SEE `ALL FILES'":PRINT
250 PRINT"TYPE <  C  >                TO GOTO `COMMAND MODE'":PRINT
260 PRINT"TYPE < KIL >                TO `KILL' A PROGRAM"
270 PRINT:PRINT
280 LINE INPUT "TYPE YOUR ENTRY HERE THEN PRESS <RETURN>   > ";A$
290 PRINT CHR$(26)
300 IF A$="RESET" THEN RESET:GOTO 150
310 IF A$="ALL" THEN GOTO 410
320 IF A$="CR" THEN GOTO 400
330 IF A$="C" THEN GOTO 480
340 IF A$="KIL" THEN GOTO 500
350 IF A$="" THEN GOTO 400
360 PRINT"I'm loading ";CHR$(34);A$;CHR$(34):PRINT:PRINT"Please wait..."
370 FOR N=1 TO 400:NEXT N
380 ON ERROR GOTO 420
390 RUN A$
400 SYSTEM
410 FILES:GOTO 200
420 PRINT CHR$(26):PRINT:PRINT TAB(14)"THE FILE ";CHR$(34);A$;CHR$(34);" IS EITHER TYPED WRONG OR NON-EXISTENT"
430 PRINT:PRINT TAB(27)"Try Re-entering File Name":PRINT
440 PRINT TAB(23)"Please press <RETURN> to continue."
450 LINE INPUT X$
460 CLEAR
470 GOTO 150
480 PRINT CHR$(26)
490 NEW
500 PRINT CHR$(26)
510 FILES
520 PRINT"===================================================================="
530 PRINT:PRINT"THIS `SUB-PROGRAM' IS TO ";CHR$(34);"KILL";CHR$(34);", OR ERASE A PROGRAM"
540 PRINT:PRINT"ENTER THE PROGRAM YOU WISH TO KILL"
550 PRINT:PRINT"Please include the `FILE TYPE'. e.g. PROGRAM.BAS"
560 PRINT:PRINT" ** NOTE ** Press <RETURN> to exit"
570 ON ERROR GOTO 660
580 PRINT:LINE INPUT"    > ";K$
590 IF K$="" THEN GOTO 150
600 KILL K$
610 PRINT:PRINT K$" IS GONE...FOREVER!!
620 PRINT"Please press <RETURN> to return to Directory "
630 PRINT:LINE INPUT"Or type <C> to `KILL' another file....> ";R$
640 IF R$="C" GOTO 690 ELSE GOTO 150
650 GOTO 150
660 PRINT:PRINT"THE FILE ";CHR$(34);K$;CHR$(34);" IS EITHER MISSPELLED OR NON-EXISTENT."
670 PRINT"OR YOU MIGHT HAVE FORGOTTEN THE `FILE TYPE'."
680 FOR T=1 TO 4000:NEXT T
690 CLEAR
700 PRINT CHR$(26)
710 FILES
720 PRINT"===================================================================="
730 GOTO 540

700 PRINT CHR$(26)
710 FILES
720 P