10  PRINT "          THIS IS THE COUNTRY ROAD"
20  PRINT "               ROAD RALLY" 
30  PRINT 
40 PRINT "YOU HAVE YOUR CHOICE OF A 1,VW; 2,283 NOVA" 
50 PRINT "3,Z-28; OR A 4,FERRARI" 
60 PRINT "INPUT THE CAR YOU WANT BY THE NUMBER IN FRONT OF"       
70  PRINT "IT, BUT REMEMBER THE BETTER THE CAR THE MORE GAS"
80  PRINT "IT USES. ";
90  INPUT C1
100  LET C1=INT(C1)
110  IF C1 > 4 THEN 140
120 IF C1 <1 THEN 140
130 GOTO 160
140 PRINT "INVALID CAR NUMBER. NEW CAR ";
150 GOTO 90 
160 PRINT
170 PRINT "WHAT COURSE DO YOU WANT FROM 1 TO 5 WITH" 
180 PRINT "5 BEING THE MOST DIFFICULT "; 
190 INPUT C2 
200 LET C2=INT(C2) 
210 IF C2 < 1 THEN 240 
220 IF C2 >5 THEN 240
230 GOTO 260
240 PRINT "INVALID COURSE NUMBER. NEW CHOICE ";
250  GOTO 190 
260 PRINT "YOU WILL TRAVEL 5 MILES WITH .5 GALLONS OF GAS" 
270 PRINT "EACH INTERVAL IS 10 SECONDS. THE INPUT IS -10 TO 10"
280 PRINT "-10 IS HARD BRAKING, 10 IS FAST ACCELLERATION"
290 PRINT "AND ANYTHING IN BETWEEN"
300 FOR I=1 TO C1
310 READ B,M,S 
320 LET B=B/10 
330 NEXT I 
340 LET A1=.5
350 LET M1=0 
360 LET C1=C1/2
370 LET V=0
380 PRINT
390 LET R1=0 
400 LET T=0
410 LET D=0
420 LET Q1=0 
430 PRINT "PRESENT VELOCITY = ";V;" NO. OF GALLONS = ";A1
440 PRINT "NO. OF MILES = ";M1;" TIME PASSED = ";T;" SECONDS"
450 IF M1>=5 THEN 1280 
460 PRINT "WHAT IS YOUR NEW RATE OF GAS "; 
470 INPUT G
480 IF G<-10 THEN 510
490 IF G>10 THEN 510 
500 GOTO 530
510 PRINT "NOT VALID. NEW RATE ";
520 GOTO 470
530 IF G<9 THEN 590
540 LET Z=Z+1
550 IF Z>4 THEN 570
560 GOTO 600
570 PRINT "YOUR ENGINE BLEW.  YOU GOT HIT BY A PISTON."
580 GOTO 1080
590 LET Z=0
600 LET V=INT(B*G-M*V+V) 
610 LET T=T+10 
620 PRINT
630 PRINT "ROAD CONDITIONS ;"; 
640 IF V>0 THEN 660
650 LET V=0
660 LET M1=M1+V/460
670 IF G<0 THEN 700
680 LET A1=A1-(G*S)/5000 
690 IF A1<0THEN 1200 
700 IF R1=1 THEN 860 
710 IF Q1=1 THEN 790 
720  LET Q=INT((C2+1)*RND(X))
730 LET R=INT((3.75-C2)*RND(X))
740 IF R>0 THEN 1100
750 IF Q>0 THEN 1160 
760 PRINT " CLEAR AND STRAIGHT"
770 PRINT
780 GOTO 430
790 LET H=INT(15+35!*RND(X)) 
800 LET H=H+5*C1 
810 IF V>H THEN 1320 
820 PRINT "THROUGH CURVE"
830 PRINT
840 LET Q1=0 
850 GOTO 430
860 LET E=E-(V-D)*3!
870 IF E<0 THEN 910
880 PRINT "VEHICLE ";E;" FEET AHEAD" 
890 PRINT
900 GOTO 430
910 IF V-D<5 THEN 990
920 PRINT "VEHICLE PASSED BY ";
930 LET D=V-D
940 PRINT D; 
950 PRINT " MPH" 
960 PRINT
970 LET R1=0 
980 GOTO 430
990 PRINT "VEHICLE BEING PASSED "
1000 LET  D=INT(25+40*RND(X)) 
1010 PRINT "GRAYHOUND IN OTHER LANE ";
1020 PRINT "DOING ";
1030 PRINT D; 
1040 PRINT " MPH "; 
1050 LET D=V+D
1060 PRINT "CRASH VELOCITY = "; 
1070 PRINT D
1080 PRINT "WHERE IS YOUR FUNERAL BEING HELD ?" 
1090 GOTO 1380 
1100 PRINT "VEHICLE AHEAD 1000 FEET"
1110 PRINT
1120 LET D=INT(25+35*RND(X))
1130 LET E=1000 
1140 LET R1=1 
1150 GOTO 430
1160 PRINT " WARNING: CURVE AHEAD " 
1170 LET Q1=1 
1180 PRINT
1190 GOTO 430  
1200 PRINT "EXCELLENT BUT WAIT!"
1210 PRINT
1220 PRINT "YOU RAN OUT OF GAS" 
1230 GOTO 1370 
1240 PRINT "BUT SOME HOW YOU MADE IT" 
1250 PRINT
1260 LET R1=0 
1270 GOTO 430
1280 PRINT
1290 PRINT
1300 PRINT "YOU MADE IT (LUCKY) !!!!!!!"
1310 GOTO 1380 
1320  PRINT "ARE TERRIBLE"
1330 LET H=H-5*C1 
1340 PRINT H;" WAS THE SPEED THROUGH THE CURVE" 
1350 PRINT V;" WAS YOUR SPEED. BY THE WAY"
1360 GOTO 1080
1370 PRINT "YOU LEAD FOOTED *#$%#$#&" 
1380 PRINT "YOU WANT TO TRY AGAIN, RIGHT !!!!"
1390 PRINT "1-YES, 2-NO ";
1400 INPUT V
1410 IF V=1 THEN 1440 
1420 PRINT "CHICKEN"
1430 GOTO 1500 
1440 RESTORE
1450 GOTO 30 
1460 DATA 45,.53,10 
1470 DATA 60,.5,13
1480 DATA 70,.41,15 
1490 DATA 80,.39,18 
1500 END

1440 RESTORE
1450 GOTO 30 
1460 DATA 45,.53,10 
1470 DATA 60,.5,13
1480 DATA 70,.41,15 
1490 DATA 80,.39,18