10 FOR I=1 TO 6
20 PRINT
30 NEXT I
40 PRINT "           AMATEUR LOG AND SEARCH PROGRAM"
50 PRINT "              BY TRUMAN BOERKOEL, K8JUG"
60 PRINT "              RCVD 26 JAN 78 / MODS F.B.GHOFULPO"
70 FOR I=1 TO 6
80 PRINT
90 NEXT I
100 CLEAR 4000
110 DIM D$(300),T$(300),ST$(300),B$(300),RS$(300)
120 DIM RR$(300),S$(300),R$(300)
130 INPUT"WHAT IS YOUR CALL";C$
140 GOSUB 980
150 LET Q=1
160 GOSUB 560
170 PRINT
180 INPUT"COMMAND";A$
190 IF A$=C$ THEN GOSUB 970
200 IF A$="ENTER" THEN GOSUB 380:GOTO 170
210 IF A$="END" THEN 710
220 IF A$="MOD" THEN Q=Q-1:PRINT"RE-ENTER DATA":GOTO 170
230 IF A$="80" THEN GOSUB 940:GOSUB 720:GOTO 170
240 IF A$="40" THEN GOSUB 940:GOSUB 750:GOTO 170
250 IF A$="20" THEN GOSUB 940:GOSUB 780:GOTO 170
260 IF A$="15" THEN GOSUB 940:GOSUB 810:GOTO 170
270 IF A$="10" THEN GOSUB 940:GOSUB 840:GOTO 170
280 IF A$="HELP" THEN GOSUB 560:GOTO 170
290 IF A$="SEARCH"THEN GOSUB 450:GOTO 170
300 IF A$="SEQ" THEN PRINT:PRINT:PRINT:GOSUB 980: GOSUB 870:GOTO 170
310 IF A$<>"LOG" THEN 350
320 PRINT:PRINT:PRINT:GOSUB 980:GOSUB 940
330 GOSUB 720:GOSUB 750:GOSUB 780:GOSUB 810:GOSUB 840
340 GOTO 170
350 IF A$="HALT" THEN STOP
360 PRINT"ILLEGAL COMMAND - RETYPE 'HELP' FOR INSTRUCTIONS"
370 GOTO 170
380 PRINT"INPUT DATE,TIME,STATION,BAND,RST SENT,RST RCVD";
390 PRINT"# SENT,# RCVD"
400 I=Q
410 INPUT D$(I),T$(I),ST$(I),B$(I),RS$(I),RR$(I),S$(I),R$(I)
420 PRINT:GOSUB 940:GOSUB 910
430 Q=Q+1
440 RETURN
450 PRINT"STATION CALL";
460 INPUT H$
470 IF H$=C$ THEN GOSUB 970
480 GOSUB 940
490 FOR K=1 TO 300
500 IF H$<>ST$(K) GOTO 530
510 PRINTD$(K)TAB(9);T$(K)TAB(16);ST$(K)TAB(29);B$(K)TAB(36);
520 PRINTRS$(K)TAB(41);RR$(K)TAB(48);S$(K)TAB(54);R$(K)
530 NEXT K
540 PRINT "SEARCH COMPLETED"
550 RETURN
560 PRINT"COMMAND MODE"
570 PRINT"LOG     ---  DISPLAY COMPLETE LOG 80-40-20-15-10"
580 PRINT"SEQ     ---  DISPLAY LOG ENTRIES SEQUENTIALLY"
590 PRINT"ENTER   ---  ENTERS NEW CONTACT INTO LOG"
600 PRINT"MOD     ---  MODIFY LOGS LAST ENTRY"
610 PRINT"HELP    ---  PRINTS THESE INSTRUCTIONS"
620 PRINT"END     ---  END OF PROGRAM"
630 PRINT"80      ---  DISPLAY 80 METER CONTACTS"
640 PRINT"40      ---  DISPLAY 40 METER CONTACTS"
650 PRINT"20      ---  DISPLAY 20 METER CONTACTS"
660 PRINT"15      ---  DISPLAY 15 METER CONTACTS"
670 PRINT"10      ---  DISPLAY 10 METER CONTACTS"
680 PRINT"SEARCH  ---  SEARCHES FOR CALL ON ANY AND ALL BANDS"
690 PRINT"HALT    ---  STOPS PROGRAM TYPE 'CONT' TO CONTINUE"
700 RETURN
710 END
720 FOR I=1 TO 300:IF B$(I)<>"80" GOTO 740
730 GOSUB 910
740 NEXT I:RETURN
750 FOR I=1 TO 300:IF B$(I)<>"40" GOTO 770
760 GOSUB 910
770 NEXT I:RETURN
780 FOR I=1 TO 300:IF B$(I)<>"20" GOTO 800
790 GOSUB 910
800 NEXT I:RETURN
810 FOR I=1 TO 300:IF B$(I)<>"15" GOTO 830
820 GOSUB 910
830 NEXT I:RETURN
840 FOR I=1 TO 300:IF B$(I)<>"10" GOTO 860
850 GOSUB 910
860 NEXT I:RETURN
870 GOSUB 940:FOR K=1 TO 300
880 IF K<0 OR K>Q GOTO 900
890 I=K:GOSUB 910
900 NEXT K:RETURN
910 PRINTD$(I)TAB(9);T$(I)TAB(16);ST$(I)TAB(29);B$(I)TAB(36);
920 PRINTRS$(I)TAB(41);RR$(I)TAB(48);S$(I)TAB(54);R$(I)
930 RETURN
940 PRINT"                                       RST      SERIAL NO."
950 PRINT"DATE     TIME   STATION     BAND    SENT RCVD   SENT RCVD"
960 RETURN
970 PRINT"T H A T ' S   Y O U   S T U P I D   !!!":RETURN
980 PRINT:PRINT"***** AMATEUR LOG FOR ";C$;" *****":PRINT
990 RETURN
1000 END
 A T ' S   Y O U   S T U P I D 