
Microflit

org=14000

org-1|	tra tr

lis,	cal
	add crt
	pna

lsp,	sto num
	llr c1
	slr sgn

lsq,	cal+com-opr
	slr syl
	sto chc

lsr,	load lsa, add cht
	cal

ls1,	lcc
	trn ls1

lsa,	xx	|add cht
	trn lst

ls2,	clad lsa
	add one
	sto lsa
	add (-add-cht-nch+1
	trn ls1

err,	cla
	print flex x
	tra lsp

lst,	add one
	trn ls2
	add lsa
	add (tra dsp-add-cht-1
	sto .+2
	clc
	xx


cht,	710000	720000	660000	564000
	464000	440000	644000	614000
	424000	630000	504000	740000
	620000	430000	534000	554000
	514000	454000	434000	474000
	524000	770000

dsp,	tra bk	tra beg	tra pra	tra min
	tra pls	tra pls	tra cr	tra bs
	tra bar	tra ser	tra dot

	add mon
	add mon
	add (7-ac
	add mon
	add mon
	add mon
	add mon
	add mon
	add mon
	add mon
	com

dsz,	ala
	add syl
	cyl
	cyl
	cyl
	lad
	sto syl
	llr one
	slr chc
	tra lsr

pls,	llr c1		|plus, minus, space logic
	tra .+2

min,	load t, lcc
	llr (tra lsq

cwd,	slr cbx
	llr syl

sgn,	xx
	add num
	sto num
	llr t
	slr sgn
cbx,	xx

dot,	add baa
	tra dsz

cr,	add chc		|carriage return
	trn lsp
	call cwd

cr1,	xx
	cal
	tra lsp

bs,	add chc		|backspace
	trn bs2
	call cwd

bs1,	xx

bs2,	clad crt
	pna
	add baa
	add one
	sto baa
	call opt
	add hcn
	pna
	add baa
	tra br3

bar,	add chc		|examine routine
	trn br4
	call cwd
	sto baa
	tra br3

br4,	add brt
br3,	llr (17777
	anl
	lac
	sto cr1
	sto bs1
	add c2
	sto br1
	llr hcn
	lal
	pna

br1,	xx
	sto brt
	call opt
	add tab
	tra lsp-1


bk,	clad bkf		|break
	trn ebk
	add chc
	trn err

bk2,	call cwd
	add (slr
	sto bk1
	sto eb1
	add c2
	sto .+1
	xx
	slr bki
	llr (tra tr

bk1,	xx
	clc
	sto bkf
	tra lis

ebk,	llr bki		|cancel breakpoint

eb1,	xx
	llr prc+1
	slr bki
	cla
	sto bkf
	add chc
	trn lis
	tra bk2

tr,	sto ac		|break trap
	slr lr
	ala
	print flexo ac 
	add bk1
	add (tra-slr+1
	sto prc
	lac
	llr bki
	slr bix
	call opt
	add tab
	pna
	print flexo lr 
	add lr
	llr sr2-1
	tra opt

pra,	add crt		|proceed
	pna
	add ac
	llr lr

bix,	tra err
prc,	tra err
	tra err

beg,	add chc		|go to routine
	trn err
	call cwd
	add (tra
	sto be1
	clad crt
	pna
	add ac
	llr lr

be1,	xx
	tra err


ser,	add chc		|word search
	trn err
	call cwd
	llr msk
	ana
	slr num
	add crt
	pna
	llr ll
	slr sr1

sr,	cla
	llr msk
sr1,	xx
	sto syl
	anl
	lcc
	add num
	trn sr2

sr3,	clad sr1
	add one
	sto sr1
	add ul
	trn sr
	tra lis

sr2,	add one
	trn sr3
	add sr1
	add (-add-1
	call opt
	add hcn
	pnt
	pna
	add syl
	call opt
	add crt
	pna
	tra sr3


|Octal print subroutine.


opt,	slr opx
	load opu, trn opj
	sto t

opq,	llr t
	lal
	cyl
	cyl
	sto t
	llr (7
	anl
	lac
	llr opj+2
	add (add fch
	sto .+1
	xx

opu,	xx
	slr opu

opj,	pna
	add opc
	cyr
	sto opc
	trn opq
	slr opu
	add opt
	trn opq
	cla
opx,	xx

opc,	171717

fch,	flex  0t-add-fch
	flex 11 -add-fch-1
	flex 22 -add-fch-2
	flex 33 -add-fch-3
	flex 44 -add-fch-4
	flex 55 -add-fch-5
	flex 66 -add-fch-6
	flex 77 -add-fch-7

|Constants and variable storage

nch=26

c1,	lac
c2,	add

constants

brt,	0
mon,	-1
one,	1
hcn,	640343
tab,	char r		
crt,	char r


num,	0
syl,	0
chc,	0
t,	0
bkf,	0
bki,	0
baa,	0
ac,	0
lr,	0
msk,	-0
ll,	add
ul,	-add-17776

start lis
0