FLIT FOR MAC-FLT  6-18-62 = SECTION II

|Entrances and constant range test

prl,	amz
prw,	slr prx
	llr lwt
	slr t1
	trn srg
	llr adr
	lcc
	add cdl
	trn .+2
	tra irp
	lac
	add cul
	trn onp

|Instruction register print and symbolic range

irp,	cla
	add t1
	llr (760000
	ana
	lac
	trn ito
	cyl
ir2,	cyl
	cyl
	cyl
	cyl
	add (llr irt
	sto ir1
	lda t1
	llr (17777
	ana
	slr t1
ir1,	xx
	lcc
	tze ir3
	sto .+3
	print
	type 001000+dc
srg,	lda t1
	com
	add sll
	trn .+2
	tra onp
	lac
	add sul
	trn .+2
	tra onp
	llr (lcc
	clc
	tra flu
ir3,	lda t1
	add (60000
	sto t1
	llr (-flex slr
	tra ir1+1

ito,	cyl
	trn .+2
	tra ir2
	llr (tra fop
	cla

|Flad lookup and print

flu,	slr fl2
	llr (llr flg+2
	slr flg
fl3,	sto t6
	cla
	sto flv
	load t2,11
	 add low
	add (llr-add+1
	tra fl0
fln,	xx
	lac
	add (200000
	trn fn1
fl2,	xx
	add t1
	trn fn2
	lcc
	add flv
	trn fy1
fn1,	clad fln
	add (2
fl0,	sto fln
	 add (-llr-low
	trn fln
	llr flg
	lac
	llr t6
	trn fl1
	laz
	trn onp
fn3,	llr wrd
	slr t1
fl5,	type 001101+lc
	tra onp
fn2,	add (1
	trn fn1
	clad t1
	lpd
	trn fn1
fl6,	llr fln
	slr flm
	subr flp,tcn
fl1,	lcc
	add (1
	trn fn3
	lac
	trn fl4
	add t2
	add (-7
	trn .+2
	tra onp
fl4,	llr flv
	lcc
	add t1
	sto t1
	call flp
	add t6
	trn fl5

	add (opr
	llr t1
	slr wrd
	ora
	slr t1
	add (1
	tra fl3
fy1,	laz
	trn fn1
	slr flv
	llr fln
	slr flm
flg,	xx
	slr flg
	tra fn1
fop,	slr t4
	lcc
	trn fn1
	load t3,11
	load fog,add fom
for,	cla
fog,	xx
	llr t4
	anl
	slr t5
	llr t1
	ana
	laz
	trn fob
	clc
	add t5
	trn foj
	lpd
	amz
	trn foc
	tra fn1
fob,	add t5
	trn foc
	tra fn1
foc,	add (-1
	add t3
	sto t3
foj,	cla
	add fog
	add (1
foi,	sto fog
	add (-add-fom-nom+1
	trn for
	llr t3
	lcc
	add t2
	trn fn1
	slr t2
	laz
	trn .+3
	llr t4
	tra fy1+2
	add t6
	trn fl6
	type 001110+uc
	tra fl6

fom,	100000	40000	37000
	701	40	20
	10	6	701

irt,	-flex sto
	-flex stx
	-flex sxa
	-flex ado
	-flex slr
	-flex slx
	-flex stz
	0
	-flex add
	-flex adx
	-flex ldx
	-flex aux
	-flex llr
	-flex llx
	-flex lda
	-flex lax
	-flex trn
	-flex tze
	-flex tsx
	-flex tix
	-flex tra
	-flex trx
	-flex tlv
	-flex tpl

	nom=11

|Flad print

flp,	slr flx
	cla
	add flm
	add (-1
	sto flm
flm,	xx		|pick up -flex flad
	lcc
	sto .+3
	print 0
flx,	xx

|Octal constant print

onp,	clad t1
	llr (tra tcn


|Octal print subroutine.


opt,	slr opx
	load opu, trn opj
	sto t1
	type 0

opq,	llr t1
	lal
	cyl
	cyl
	sto t1
	llr (7
	anl
	lac
	llr opj+2
	add (add fch
	sto .+1
	xx

opu,	xx
	slr opu
	pna

opj,	cla
	add opc
	cyr
	sto opc
	trn opq
	slr opu
	add opt
	trn opq
	cla
opx,	xx

opc,	171717

fch,	flex  0t-add-fch
	flex 11 -add-fch-1
	flex 22 -add-fch-2
	flex 33 -add-fch-3
	flex 44 -add-fch-4
	flex 55 -add-fch-5
	flex 66 -add-fch-6
	flex 77 -add-fch-7
|Carriage position control

tcs,	slr prx
tcn,	llr chn
tc0,	add wdc
	trn tc1
	amz
	trn tc8
	add (1
	sto wdc
	add (-4
	trn tc2
	clc
	add rop
	trn tc7
tc6,	add (101001+200202-1
	pnt
	pna
	add (1
	tra tc4
tc8,	type 000101+lc
	llr chn
	add (1
	tra tc9
tc2,	lac
	add (-ns2+nsd
	trn tcd
	add (-ns2
	trn tct
tc3,	add (-nsd
	ala
	tra tc0
tc1,	add rop
	trn tc7
tc9,	sto wdc
	lac
	add (-ns1+nsd
	trn tct
	tra tc3
tcd,	cla
	add (100101
	pnt
tct,	llr tai
	lcc
	trn tc5
	add (100101
	pna
	tra tc5
tc7,	add (101001
	pna
tc4,	sto wdc
tc5,	clc
	sto chn
	sto tai
	add rop
	llr .
	tra .+2
prx,	xx
	trn cob
	tra cor

|Print symbol routine

psy,	lac
	add (2
	sto ps0
	add (tra-llr+1
	sto psx
ps0,	xx
	slr t2
	llr (3
ps1,	slr t3
	llr t2
	lac
	llr (111111
	anl
	cyr
	sto t2
	slr ps3+2
ps3,	type
	add (-1
	add t3
	alr+com-opr
	trn ps1
psx,	xx

|Type subroutine

typ,	lac
	add (2
	sto ty1
	add (tra-llr+1
	sto tyx
ty1,	xx
	lac
	trn ty0+1
	sto t
	cyl
	llr cas
	trn ty4
	lac
	trn ty0
	llr (111101
	tra .+2
ty5,	llr (111001
	com
	add (1
	sto cas
	lac
	pna
	tra ty0
ty4,	lac
	trn ty5
ty0,	llr t
	clad (111111
	anl
	laz
	trn ty2
	pna
	add (1
	add chn
	sto chn
ty2,	cla
tyx,	xx

|Color control

cor,	clc
	tra .+2
cob,	cla
	slr cox
	llr coi
	sto coi
	lpd+com-opr
	trn .+3
	add (010000
	pna
	add cox
	add (tra-llr+2
	sto cox
	cla
cox,	xx

|Ignore and illegal characters

i,	add ign
	trn igc
e,	redd
	type 111010+uc
	type lc
	add rop
	trn .+2
	tra igc+1
	black
igc,	add (1
	add chn
	sto chn
	tra lsn
igd,	add (-1
	tra .-4

|Error print routine

tlt,	cla
	tra pfl
erp,	cla
	add (2
del,	add (2
pfl,	add (2
uds,	add (llr pdt
	sto pd1
	add (1
	sto pd2
pd1,	xx
	slr .+5
	redd
	print
pd2,	xx
	slr .+3
	print
	add rop
	trn pd3
	llr (tra rnw
	clc
	tra tcs
pd3,	add (101001
	pna
	tra rsl

pdt,	flex ind
	000010+022020
	flex fli
	100000
	flex xxx
	111010
	flex err
	110000+020200
	
start
