1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        BIRDAY:   BIRTHDAY PROBABILITY
4  REM
5  REM        36653 REV  A   10/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ************************************
100  REM BJDCVHS030573-A-
101  PRINT "INSTRUCTIONS";
102  INPUT A$[1,1]
103  IF A$[1,1]="N" THEN 117
104  PRINT 
105  PRINT "THIS PROGRAM DOES TWO (2) THINGS. THEY ARE:"
106  PRINT TAB(4);"1-  COMPUTES HOW MANY PEOPLE MUST BE PRESENT"
107  PRINT TAB(4);"    IN A GROUP TO HAVE A X% PROBABILITY THAT"
108  PRINT TAB(4);"    THEIR BIRTHDAYS FALL ON THE SAME DATE."
109  PRINT TAB(4);'10"2-  COMPUTES AND PRINTS THE PROBABILITY AND PERCENT"
110  PRINT TAB(4);"    OF N PEOPLE HAVING THE SAME BIRTHDAY."
111  PRINT 
112  REM ******************************
113  REM * BLAKE DISCHER              *
114  REM * CHIPPEWA VALLEY HIGH SCH.  *
115  REM * MT. CLEMENS, MI.  48043    *
116  REM ******************************
117  PRINT '10"WHICH FUNCTION DO YOU WANT";
118  INPUT G0
119  GOTO G0 OF 123,145
120  IF G0=999 THEN 157
121  PRINT "TYPE 1, 2 OR 999 [STOP]";
122  GOTO 118
123  PRINT "PERCENT DESIRED";
124  INPUT Z9
125  FOR S1=1 TO 400
126  S2=366-S1
127  S3=1
128  FOR S4=365 TO S2 STEP -1
129  S3=S3*S4/365
130  NEXT S4
131  X1=(INT(1000*(1-S3))/1000)*100
132  X2=INT(X1/1)*1
133  IF X2=Z9 THEN 140
134  IF X2<Z9 THEN 139
135  IMAGE"IT TAKES A GROUP OF APPROXIMATLEY ",3D," PEOPLE FOR "
136  PRINT  USING 135;S1-1
137  PRINT  USING 141;Z9
138  GOTO 117
139  NEXT S1
140  IMAGE"IT TAKES A GROUP OF ",3D," PEOPLE FOR"
141  IMAGE"THERE TO EXIST A ",2D,"% PROBABILITY."
142  PRINT  USING 140;S1
143  PRINT  USING 141;Z9
144  GOTO 117
145  PRINT "NUMBER OF PEOPLE IN GROUP";
146  INPUT S1
147  S2=366-S1
148  S3=1
149  FOR S4=365 TO S2 STEP -1
150  S3=S3*S4/365
151  NEXT S4
152  IMAGE "PROBABILITY IS: ",S1D.5D
153  IMAGE"THERE IS A ",3D.D,"% CHANCE."
154  PRINT  USING 152;INT(1000*(1-S3))/1000
155  PRINT  USING 153;(INT(1000*(1-S3))/1000)*100
156  GOTO 117
157  END 
