1  REM ****  HP BASIC PROGRAM LIBRARY  ******************************
2  REM
3  REM       SIPRAC: PRACTICE WITH SIGNED NUMBERS
4  REM
5  REM       36238 REV A
6  REM
7  REM ****  CONTRIBUTED PROGRAM  ***********************************
8  REM          PROGRAMMER: M.S. BOLDUAN
9  REM          LINE 20 GOVERNS THE LENGTH OF RESPONSE TIME
10  DIM X$[10]
20  K=5
30  PRINT "SIGNED NUMBER MANIPULATION PRACTICE ......."'10'10
40  PRINT "DO YOU WANT DIRECTIONS";
50  INPUT X$
60  IF X$="NO" THEN 120
70  PRINT "IN THIS PROGRAM YOU WILL BE PRACTICING ADDITION,SUBTRACTION,"
80  PRINT "AND MULTIPLICATION OF SIGNED NUMBERS . YOU WILL HAVE"
90  PRINT K;"SECONDS AFTER THE PROBLEM IS STATED IN WHICH TO"
100  PRINT "TYPE IN YOUR ANSWER. (MULTIPLICATION WILL BE SHOWN"
110  PRINT "BY USING AN 'X'."
120  J=1
130  R=0
140  DIM A$[5],B$[5],W[30]
150  PRINT "WHAT'S YOUR LUCKY NUMBER";
160  INPUT L
170  N=INT(RND(0)*L)+5
180  PRINT "YOU'LL BE DOING ";N;"PROBLEMS. GOOD LUCK!!"'10'10
190  FOR X=1 TO N
200  S=INT(RND(0)*3)
210  IF S=1 OR S=2 THEN 240
220  A1=-1*INT(RND(0)*20)
230  GOTO 250
240  A1=INT(RND(0)*20)
250  IF S=0 OR S=1 THEN 280
260  A2=-1*INT(RND(0)*20)
270  GOTO 290
280  A2=INT(RND(0)*20)
290  PRINT "NO. ";X;":      ";
300  PRINT A1;
310  A=INT(RND(0)*3)+1
320  GOTO A OF 330,390,450
330  PRINT "+  ";A2;"=";
340  ENTER K,P,Q
350  IF P=-256 THEN 870
360  PRINT 
370  A$="+"
380  GOTO 500
390  PRINT "-  ";A2;"=";
400  ENTER K,P,Q
410  IF P=-256 THEN 870
420  PRINT 
430  A$="-"
440  GOTO 500
450  PRINT "X  ";A2;"=";
460  ENTER K,P,Q
470  IF P=-256 THEN 870
480  PRINT 
490  A$="X"
500  IF A$="+" THEN 550
510  IF A$="-" THEN 590
520  IF A$="X" THEN 630
530  PRINT "ERROR"
540  GOTO 870
550  IF Q=A1+A2 THEN 670
560  W[J]=X
570  J=J+1
580  GOTO 680
590  IF Q=A1-A2 THEN 670
600  W[J]=X
610  J=J+1
620  GOTO 680
630  IF Q=A1*A2 THEN 670
640  W[J]=X
650  J=J+1
660  GOTO 680
670  R=R+1
680  NEXT X
690  PRINT '10'10'10"HERE'S HOW YOU DID:"'10'10
700  PRINT TAB(12);"YOU GOT ";R;"RIGHT OUT OF ";X-1
710  X=X-1
720  PRINT TAB(12);"THIS IS ";(R/X)*100;"PERCENT."
730  IF R=X THEN 810
740  PRINT TAB(12);"YOU MISSED THE FOLLOWING PROBLEMS:"'10
750  PRINT TAB(5);
760  FOR H=1 TO X-R
770  PRINT "NO. ";W[H];"    ";
780  NEXT H
790  PRINT "CORRECT YOUR ERRORS AND TURN IN YOUR PAPER FOR CREDIT."
800  END 
810  PRINT "WAY TO GO!!"'7'7'7'7" DO YOU WANT TO TRY TO GET 100% TWO TIMES"
820  PRINT "IN A ROW";
830  INPUT B$
840  IF B$="YES" THEN 120
850  PRINT "IT'S BEEN FUN AND NOW I'M";
860  END 
870  PRINT 
880  PRINT "TOO LATE! TRY THE NEXT ONE."
890  W[J]=X
900  J=J+1
910  GOTO 680
920  END 
