10  REM**PREFIX**C.A.I.**TESTS KNOWLEDGE OF PREFIXES**MAY 8, 1972
15  REM VOCAB, HP 36880A, 6/74
20  DIM A$[72],B[500],N$[72],W$[72],B$[72]
30  H=0
40  PRINT "HI,I'M GLAD YOU LIKE THIS WAY OF LEARNING,TOO."
50  PRINT "DID YOU KNOW THAT THE PREFIXES THAT YOU WILL LEARN IN"
60  PRINT "THIS PROGRAM WILL GIVE YOU KEYS TO UNLOCK THE MEANINGS"
70  PRINT "OF OVER 14,000 COMMONLY USED WORDS?"
80  PRINT "WHAT IS YOUR FIRST NAME?"
90  INPUT N$
100  PRINT "IN THIS PROGRAM YOU WILL BE ASKED TO GIVE A ONE WORD"
110  PRINT "MEANING FOR EACH PREFIX THAT YOU ARE ASKED TO"
120  PRINT "DEFINE. YOU WILL RECEIVE 10 POINTS FOR EACH"
130  PRINT "CORRECT ANSWER. THE COMPUTER WILL KEEP SCORE."
140  PRINT "       GOOD LUCK,"N$
150  I=0
160  IF TYP(0)=3 THEN 200
170  I=I+1
180  READ A$
190  GOTO 160
200  RESTORE 
210  J=INT(I/2)
220  PRINT '10'10
230  FOR M=1 TO J
240  READ A$,B$
250  PRINT "                      "A$
260  NEXT M
270  RESTORE 
280  FOR L=1 TO J
290  B[L]=INT(J*RND(0)+1)
300  FOR K=1 TO L-1
310  IF B[L]=B[K] THEN 290
320  NEXT K
330  NEXT L
340  FOR L=1 TO J
350  FOR K=1 TO B[L]
360  READ A$,B$
370  NEXT K
380  RESTORE 
390  PRINT "WHICH PREFIX MEANS ";
400  PRINT B$
410  INPUT W$
420  IF W$=A$ THEN 450
430  PRINT "SORRY, YOU MISSED THAT ONE, "N$", THE RIGHT ANSWER IS, "A$
440  GOTO 470
450  PRINT "VERY GOOD, YOUR ANSWER IS CORRECT, "N$
460  H=H+1
470  NEXT L
480  DATA "PRE-","BEFORE","DE-"," DOWN","MONO-","ONE","INTER-","BETWEEN"
490  DATA "UN-","NOT OR INTENSIFIES A VERB","RE-","AGAIN OR BACK"
500  DATA "TRANS-","ACROSS OR BEHIND"
510  DATA "PRO-","IN FAVOR OF OR FORWARD"
520  DATA "NON-","NOT OR ABSENSE OF SOMETHING"
530  DATA "EPI-"," UPON OR OVER","MIS-"," WRONG","OB-"," BEHING OR AGAINST"
540  DATA "EX-"," OUT","DIS-","APART OR NOT","IN-","INTO OR NOT"
550  DATA "COM-"," TOGETHER OR WITH","SUB-"," UNDER","AD-"," TO OR TOWARD"
9000  PRINT "YOUR SCORE IS"H"OUT OF"J"WHICH IS"H/J*100"%."
9010  IF H=J THEN 9040
9020  PRINT "YOU COULD PRACTICE A LITTLE MORE "N$
9030  GOTO 9050
9040  PRINT N$", YOU DID THIS WITHOUT ONE MISTAKE.  CONGRATULATIONS!"
9050  END 
