10  REM ****  HP TIME-SHARED BASIC PROGRAM LIBRARY  ********************
20  REM
30  REM            PLANK: A PHOTOELECTRIC SIMULATION
40  REM
50  REM            36350  (A833)  REV A -- 11/71
60  REM
70  REM ****  CONTRIBUTED PROGRAM  *************************************
80  REM PLANK - COPYRIGHT 1971, POLYTECHNIC INSTITUTE OF BROOKLYN
90  REM JOHN W. HOSIE  - NORTHPORT HIGH -  7/29/69 
100  REM  REVISED BY C.LOSIK  8-21-70 
110  REM  M IS WHICH METAL,C IS X-RAY INTENSITY, K IS NO. OF FREQS. 
120  REM  F(S) ARE THE FREQS. USED, V(S) ARE THE CUT OFF POINTS 
130  LET R=0
140  LET P=X=0
150  PRINT 
160  PRINT "  IN THIS EXPERIMENT YOU WILL BE GIVEN THE FREQUENCY OF THE"
170  PRINT "X-RAYS BEING USED AND YOU ARE TO DETERMINE THE VOLTAGE SET-"
180  PRINT "TING (RETARDING POTENTIAL) NECESSARY TO CAUSE THE COLLECTOR"
190  PRINT "CURRENT TO DECREASE TO ZERO."
200  PRINT 
210  PRINT "  FIRST CHOOSE THE METAL YOU WISH TO USE FOR YOUR PHOTO-"
220  PRINT "SENSITIVE SURFACE."
230  PRINT 
240  PRINT "  1 SILVER,  2 BISMUTH,  3 CADMIUM,  4 LEAD,  5 PLATINUM"
250  PRINT 
260  LET K=0
270  PRINT "WHICH METAL DO YOU CHOOSE";
280  INPUT M
290  IF M >= 1 THEN 310
300  GOTO 460
310  IF M>1 THEN 340
320  LET F0=9.74
330  GOTO 480
340  IF M>2 THEN 370
350  LET F0=8.88
360  GOTO 480
370  IF M>3 THEN 400
380  LET F0=9.43
390  GOTO 480
400  IF M>4 THEN 430
410  LET F0=8.82
420  GOTO 480
430  IF M>5 THEN 460
440  LET F0=7.79
450  GOTO 480
460  PRINT "SORRY - THE METALS HAVE NUMBERS FROM 1 TO 5"
470  GOTO 270
480  DIM F[10],V[10]
490  PRINT 
500  PRINT "WHAT INTENSITY OF X-RAYS WILL YOU USE (FROM 1 TO 5)";
510  INPUT C
520  IF C>5 THEN 500
530  IF C<1 THEN 500
540  LET S=0
550  PRINT 
560  PRINT "HOW MANY DIFFERENT X-RAY FREQUENCIES WOULD YOU LIKE TO"
570  PRINT "USE TO RADIATE YOUR SAMPLE (FROM 5 TO 8)";
580  INPUT K
590  PRINT 
600  IF K >= 5 THEN 630
610  PRINT "I SAID BETWEEN 5 AND 8 FREQUENCIES."
620  GOTO 550
630  IF K <= 8 THEN 670
640  PRINT "TOO MANY TRIALS FOR THE AVAILABLE TIME."
650  GOTO 550
660  LET R=0
670  FOR I=1 TO 100
680  LET F=RND(X)
690  LET F=INT(2000*F+.5)/100
700  IF F>7 THEN 720
710  NEXT I
720  LET V=4.14*(F-F0)
730  LET J=0
740  PRINT "THE X-RAY FREQUENCY IS"F"  E15"
750  PRINT 
760  IF R>0 THEN 790
770  PRINT "VOLTAGES HIGHER THAN CUT OFF WILL GIVE CURRENT READINGS OF"
780  PRINT "ZERO SO TRY LOWER ONES.  I'LL NOTIFY YOU OF CUT OFF."
790  PRINT "  FIND THE CUT OFF (STOPPING) VOLTAGE."
800  PRINT 
810  PRINT "V=";
820  INPUT V1
830  LET R=R+1
840  LET J=J+1
850  LET I=(20*C*(V-V1))/V+.05*RND(X)
860  IF I<C*20.5 THEN 880
870  LET I=20*C+.1*RND(X)
880  IF V-V1>0 THEN 900
890  LET I=0
900  IF ABS(V-V1)<.1 THEN 990
910  IF V>0 THEN 940
920  LET I=0
930  IF J=3 THEN 1010
940  IF I=0 THEN 970
950  PRINT "          I="I"  E-6"
960  GOTO 810
970  PRINT "          I=0"
980  GOTO 810
990  PRINT "           CUT OFF   I=0"
1000  GOTO 1050
1010  PRINT "THIS FREQUENCY IS TOO LOW TO CAUSE PHOTOELECTRIC EMISSION"
1020  PRINT "I'LL GIVE YOU A NEW FREQUENCY."
1030  PRINT 
1040  GOTO 670
1050  LET S=S+1
1060  LET F[S]=F
1070  LET V[S]=V1
1080  PRINT 
1090  IF S <> K THEN 670
1100  PRINT "  X-RAY","CUT OFF"
1110  PRINT "FREQUENCY","VOLTAGE"
1120  PRINT " E15 FPS"," VOLTS"
1130  PRINT "---------","-------"
1140  PRINT 
1150  FOR S=1 TO K
1160  PRINT F[S],V[S]
1170  NEXT S
1180  LET P=P+1
1190  PRINT 
1200  PRINT "  PLOT A GRAPH OF CUT OFF VOLTAGES (Y AXIS) VS. FREQUENCY"
1210  PRINT 
1220  IF P>1 THEN 1450
1230  PRINT "WHAT IS THE MEANING OF THE POINT AT WHICH THE EXTRAPOLATED"
1240  PRINT "GRAPH INTERCEPTS THE VOLTAGE AXIS?"
1250  PRINT 
1260  PRINT "WHAT IS THE LOWEST FREQUENCY THAT WILL CAUSE EMISSION OF"
1270  PRINT "PHOTOELECTRONS FROM THIS METAL?"
1280  PRINT 
1290  PRINT "REMEMBER THAT THE RETARDING POTENTIAL APPLIED BETWEEN THE"
1300  PRINT "EMITTER AND THE COLLECTOR AT CUT OFF, EXPRESSED IN ELECTRON"
1310  PRINT "VOLTS, IS EQUAL TO THE KINETIC ENERGY OF THE FASTEST"
1320  PRINT "ELECTRONS ESCAPING FROM THE EMITTER.  FIND THE SLOPE OF THE"
1330  PRINT "GRAPH BUT EXPRESS THE STOPPING POTENTIAL IN JOULES."
1340  PRINT 
1350  PRINT "WHAT IS THE VALUE OF THE SLOPE OF THE GRAPH AND WHAT SPECIAL"
1360  PRINT "NAME IS GIVEN TO THIS CONSTANT?"
1370  PRINT 
1380  PRINT "THE SAME METAL WITH A DIFFERENT INTENSITY IS WORTH"
1390  PRINT "INVESTIGATING.  WHEN YOU DO THIS EXPLAIN THE MEANING"
1400  PRINT "OF ITS GRAPH WHEN COMPARED TO THE PREVIOUS ONE."
1410  PRINT 
1420  PRINT "YOU MAY ALSO WISH TO TRY A DIFFERENT METAL AND EXPLAIN"
1430  PRINT "THE MEANING OF ITS GRAPH WHEN COMPARED TO YOUR OTHER ONES,"
1440  PRINT "OR COMPARED WITH THOSE OF ANOTHER STUDENT."
1450  PRINT 
1460  PRINT "DO YOU WISH TO TRY A DIFFERENT INTENSITY OR A"
1470  PRINT "DIFFERENT METAL (1=YES, 0=NO) : ";
1480  INPUT Q
1490  IF Q=1 THEN 200
1500  IF Q <> 0 THEN 1450
1510  END 
