10  REM ****  HP TIME-SHARED BASIC PROGRAM LIBRARY  *******************
20  REM
30  REM              MASSD:  MASS DEFECT
40  REM
50  REM              36310  (A833)  REV A -- 10/71
60  REM
70  REM ****  CONTRIBUTED PROGRAM  ************************************
80  REM MASSD - COPYRIGHT 1971, POLYTECHNIC INSTITUTE OF BROOKLYN
90  REM JOHN MARCHISOTTO  PIB SUMMER 69   BASIC
100  REM  REVISED BY C.LOSIK  7-22-70 
110  REM  AT NO=A, MASS=B, MASS NO=C
120  REM  MASS DEFECT IS F
130  PRINT "   THIS PROGRAM IS DESIGNED TO INVESTIGATE MASS DEFECT"
140  PRINT 
150  PRINT "   WHICH OF THE ELEMENTS WOULD YOU LIKE TO CONSIDER? "
160  PRINT " REMEMBER WE ARE DEALING WITH A SINGLE ATOM, THEREFORE"
170  PRINT " IN ADDITION TO THE ATOMIC NUMBER WE ARE GOING TO NEED THE"
180  PRINT " ACTUAL MASS (IN AMU) AND THE MASS NUMBER OF THE ISOTOPE"
190  PRINT " YOU WANT TO WORK WITH."
200  PRINT 
210  PRINT " WHEN THE MACHINE TYPES A QUESTION MARK (?) TYPE IN"
220  PRINT " YOUR ANSWER THEN HIT RETURN KEY. USE NUMBERS OF UP TO"
230  PRINT " SIX SIGNIFICANT FIGURES. ROUND IF NECESSARY TO 6 DIGITS."
240  PRINT "IN THE VALUES FOR MASS DEFECT."
250  PRINT 
260  PRINT 
270  PRINT " THE ATOMIC NUMBER IS ";
280  INPUT A
290  PRINT " THE ACTUAL MASS IS ";
300  INPUT C
310  PRINT " THE MASS NUMBER IS ";
320  INPUT B
330  PRINT 
340  REM  G IS AVOGADRO'S NUMBER
350  LET G=6.023E+23
360  LET D=B-A
370  LET E=(1.00728*A)+(1.00867*D)+(.000548597*A)
380  LET F=INT(10000*(E-C)+.5)/10000
390  PRINT " THE SUM OF THE MASS OF THE"A"PROTONS AND THE"D"NEUTRONS"
400  PRINT " PLUS THE WEIGHT OF THE"A"ELECTRONS IS THE CALCULLATED"
410  PRINT " MASS."
420  PRINT 
430  PRINT "  CALCULATED MASS  -  ACTUAL MASS  =  MASS DEFECT"
440  PRINT "     "E,"    -  "C;"    =   "F
450  PRINT 
460  REM   CONVVERSION FACTORS:
470  REM        1.49 X 10-3 ERGS PER AMU
480  REM        4.19 X 10 7 ERGS PER CAL. 
490  REM        3.6  X 10 13 ERGS PER KW-H
500  REM         931.0 MEV PER AMU
510  LET H=(.00149*F*G)/4.19E+07
520  PRINT " THE MASS DEFECT IN TERMS OF ENERGY IS THE EQUIVALENT OF"
530  PRINT INT(H/1.E+09+.5)"X 10^9 CAL. PER MOLE OF THIS SUBSTANCE,"
540  PRINT "OR"INT((H/C)/1.E+09+.5)"X 10^9 CAL. PER GRAM."
550  PRINT 
560  PRINT " IF WE DIVIDE THIS BINDING ENERGY BY THE NUMBER OF"
570  PRINT " PARTICLES IN THE NUCLEUS, WE GET A RATIO KNOWN AS THE"
580  PRINT " BINDING ENERGY PER NUCLEON, WHICH IS A MEASURE OF THE"
590  PRINT " STABILITY OF THE NUCLEUS.  THE MORE 'BINDING'"
600  PRINT " PER NUCLEON, THE MORE STABLE IS THE NUCLEUS."
610  PRINT " THE BINDING ENERGY PER NUCLEON IS :";
620  PRINT .00149*F/B"ERGS. PER NUCLEON, OR";
630  PRINT .00149*F/(B*4.19E+07)"CAL. PER NUC.,"
640  PRINT " WHICH IS MORE COMMONLY EXPRESSED AS"100*INT(931*F/B+.5)"MEV."
650  LET J=((H/C)*4.19E+07/3.6E+13)/15
660  PRINT 
670  PRINT " THE AMOUNT OF ENERGY (BINDING ENERGY) CONTAINED IN ONE"
680  PRINT " GRAM OF THIS SUBSTANCE WOULD BE SUFFICIENT TO SUPPLY ALL"
690  PRINT " THE ELECTRICAL NEEDS IN AN AVERAGE ONE FAMILY HOUSE USING"
700  PRINT " 15 KW-HRS. PER DAY FOR A PERIOD OF"INT(J+.5)"DAYS OR"
710  PRINT INT((J/365)+.5)"YEARS."
720  PRINT 
730  PRINT " IF YOU WOULD LIKE TO RUN ANOTHER PROBLEM TYPE IN 1,"
740  PRINT " IF NOT TYPE IN 0."
750  INPUT M
760  PRINT 
770  PRINT " ","***************"
780  IF M=1 THEN 260
790  IF M <> 0 THEN 730
800  END 
