1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        LANDIN:   COMPUTER-AUGMENTED PHYSICS TOPICS (NEWTON)
4  REM
5  REM        36670 REV  A   10/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ************************************
10  PRINT "PLEASE USE THE METRIC SYSTEM THROUGHOUT."
20  PRINT "WOULD YOU LIKE SOME ACTUAL FIGURES FOR"
25  PRINT "AIRCRAFT CARRIERS (0=NO, 1=YES)?"
30  INPUT Q
40  IF Q=0 THEN 75
50  IF Q=1 THEN 520
60  PRINT "PLEASE TYPE 1 OR 0"
70  GOTO 30
75  PRINT 
80  PRINT "DO YOU WANT A LISTING WITH PROGRESSIVELY LARGER"
90  PRINT "MASS AND SPEED (0=NO, 1=YES)?"
100  INPUT L
110  IF L=0 THEN 210
120  IF L=1 THEN 150
130  PRINT "PLEASE TYPE 0 OR 1"
140  GOTO 100
150  PRINT "INPUT THE SMALLEST AND GREATEST VALUE OF THE LANDING"
160  PRINT "SPEEDS AND THE STEP SIZE IN KM/HR."
170  INPUT V0,V1,K
180  PRINT "NOW, DO THE SAME FOR THE AIRPLANE'S MASS IN KG."
190  INPUT M0,M1,K1
200  GOTO 230
210  PRINT "INPUT THE MASS IN KG, AND THE LANDING SPEED IN KM/HR."
220  INPUT M,V
230  PRINT "INPUT THE RUNOUT DISTANCE AND THE RUNWAY WIDTH"
240  PRINT "IN METERS."
250  INPUT R,W
255  PRINT "INPUT THE BRAKING STRENGTH (NEGATIVE) IN NEWTONS."
257  INPUT B
260  PRINT "MY CALCULATIONS ARE ACCURATE TO THE NEAREST N METERS."
262  PRINT "INPUT A VALUE FOR N."
270  INPUT X
280  IF L=0 THEN 330
290  FOR M=M0 TO M1 STEP K1
300  PRINT M;"KG"
310  FOR V=V0 TO V1 STEP K
320  PRINT "      ";V;"KM/HR"
330  LET V2=V/3.6
340  FOR D=X TO R STEP X
350  LET B1=-((D-X/2)*2*B)/SQR((D-X/2)^2+W^2)
360  LET V3=V2^2-2*ABS(B1)*X/M
370  IF V3<0 THEN 430
380  LET V2=SQR(V3)
390  NEXT D
400  PRINT "THE PLANE COULD NOT BE STOPPED IN";R;"METERS."
410  IF L=0 THEN 460
420  GOTO 490
430  IF L=1 THEN 470
440  PRINT "THE PLANE WAS SUCCESSFULLY STOPPED."
450  PRINT "ITS LANDING DISTANCE WAS";D;"M"
460  PRINT "LIKE TO TRY AGAIN, WITH DIFFERENT VALUES (0=NO, 1=YES)"
462  INPUT Q
464  IF Q=1 THEN 210
466  STOP 
470  PRINT "          LANDING DISTANCE =";D;"M"
480  NEXT V
490  NEXT M
500  PRINT "WELL, I'M FINALLY FINISHED NOW.  GOODBYE !"
510  STOP 
520  PRINT "ON AN AIRCRAFT CARRIER, THE RUNOUT DISTANCE IS"
530  PRINT "ABOUT 305 METERS."
540  PRINT "THE MASS AND LANDING SPEED OF REAL AIRPLANES RANGE"
550  PRINT "FROM ABOUT 419 KG AND 72.5 KM/HR FOR THE BOWERS"
560  PRINT "FLY BABY I-4, TO ABOUT 157,500 KG AND 230 KM/HR FOR"
570  PRINT "THE LONG-RANGE RUSSIAN AIRLINER, ILYUSHIN II-62."
580  PRINT "THE MASS OF THE BOEING 747-21 IS ABOUT 238,815 KG."
590  GOTO 75
600  END 
