1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        FUNDTH:   COMPUTER-AUGMENTED CALCULUS TOPICS (TRAPEZOID
4  REM                  METHOD)
5  REM        36664 REV  A   10/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ************************************
100  PRINT "THIS PROGRAM COMPUTES APPROXIMATIONS TO THE DEFINITE"
110  PRINT "INTEGRAL OF THE FUNCTION Y=F(X) WHICH YOU SUPPLIED ON"
120  PRINT "LINE 300, OVER THE INTERVAL (A,B), AND COMPARES THE"
130  PRINT "APPROXIMATION TO G(B)-G(A), WHERE Z=G(X) IS A"
140  PRINT "PRIMITIVE OF F(X) SUPPLIED BY YOU ON LINE 500."
150  PRINT 
160  PRINT "WHAT IS A";
170  INPUT A
180  PRINT "WHAT IS B";
190  INPUT B
200  IF A >= B THEN 680
210  PRINT "HOW MANY SUBINTERVALS ON [A,B]";
220  INPUT N
230  LET N=INT(ABS(N))
240  LET S=0
250  LET W=(B-A)/N
260  FOR X=A TO B STEP W
300  LET Y=SIN(X)
310  IF X=B THEN 350
320  IF X=A THEN 350
330  LET S=S+2*Y
340  GOTO 360
350  LET S=S+Y
360  NEXT X
370  LET T=((B-A)/(2*N))*S
380  PRINT "INTERVAL [";A;",";B;"].";N;"TRAPEZOIDS."
390  PRINT 
400  PRINT "APPROXIMATION TO INTEGRAL IS *******";T;"*******"
410  PRINT 
420  LET L=0
430  LET X=A
500  LET Z=-COS(X)
510  IF L=1 THEN 560
520  LET L=L+1
530  LET C=Z
540  LET X=B
550  GOTO 500
560  LET D=Z
570  LET R=D-C
580  PRINT "G(B)-G(A) = ";D;" - ";C;" = ";R;" ."
590  PRINT 
600  PRINT 
610  PRINT "TYPE THE CODE";
620  INPUT E
630  IF E=1 THEN 210
640  IF E=2 THEN 150
650  IF E=3 THEN 700
660  PRINT "THE CODE MUST BE 1, 2, OR 3."
670  GOTO 610
680  PRINT " A MUST BE LESS THAN B."
690  GOTO 160
700  END 
