10  COM X$[72],C
20  REM**CL5-2**BASIC C.A.I.**GEOGRAPHY**CHAIN FROM CL5-1**JUNE 20, 1972
25  REM CLIMAT, HP 36760A, 6/74
30  DIM R$[72],S$[72],G$[72]
40  FILES SCRA
50  PRINT 
60  PRINT "NOW ";X$;" , PLEASE TELL ME THE KOPPEN SYMBOLS FOR THIS"
70  PRINT "STATION    (TYPE 'HELP' IF YOU NEED IT)"
80  LET Y=0
90  INPUT G$
100  PRINT 
110  IF G$="CS" THEN 420
120  IF G$="CSA" THEN 420
130  IF G$="C" THEN 290
140  IF G$="HELP" THEN 170
150  LET Z=Z+1
160  GOSUB 1570
170  IF Y=1 THEN 230
180  IF Y=2 THEN 370
190  PRINT "HINTS - HUMID CLIMATE, QUITE WARM, MARKED SUMMER DROUGHT"
200  PRINT "TRY THE FIRST LETTER AT LEAST."
210  LET Y=Y+1
220  GOTO 90
230  PRINT "HUMID CLIMATES ARE:"
240  PRINT "    'A' (ALL MONTHS ABOVE 64.4 F.)"
250  PRINT "   'C' (ALL MONTHS WARMER THAN 26.6 F.)"
260  PRINT "   'D' (AT LEAST ONE MONTH BELOW 26.6 F.)"
270  PRINT "   'E' (ALL MONTHS 50 F. OR COLDER)"
280  GOTO 90
290  PRINT "'C' IS THE CORRECT FIRST LETTER."
300  PRINT "   SECOND LETTER: 'S'(SUMMER DRY), 'W'(WINTER DRY), 'F'(WET)"
310  PRINT 
320  PRINT "   THIRD LETTER CHOICES ARE:"
330  PRINT "      'A' (AT LEAST ONE MONTH ABOVE 71.6 F.)"
340  PRINT "      'B' (> 3 MONTHS ABOVE 50 F., NONE ABOVE 71.6)"
350  PRINT "      'C' (< 4 MONTHS ABOVE 50)"
360  GOTO 390
370  PRINT X$;", IF YOU MAKE IT THROUGH THIS PROGR@M, I STRONGLY"
380  PRINT "URGE THAT YOU START AGAIN WITH 'CLIMAT-1***"
390  PRINT "    OUR STATION IS 'CSA' - MEDITERRANEAN."
400  PRINT 
410  GOTO 430
420  PRINT "CONGRATULATIONS!!  YOU APPEAR TO KNOW KOPPEN."
430  PRINT 
440  PRINT "BY FAR THE LARGEST AND MOST SIGNIFICANT AREA OF THIS CLIMATE"
450  PRINT "IS IN EUROPE WHERE IT EXTENDS FROM LISBON TO BEIRUT AND FROM"
460  PRINT "CASABLANCA TO MARSEILLE."
470  PRINT 
480  PRINT X$;", I WOULD LIKE YOU TO DESCRIBE THE NATURAL VEGETATION OF"
490  PRINT "THE MEDITERRANEAN AREA IN YOUR OWN WORDS.  (YOU MAY USE UP"
500  PRINT "TO A FULL LINE)"
510  LET A=0
520  INPUT G$
530  PRINT 
540  J=2
550  GOSUB 1720
560  IF F=1 THEN 710
570  J=10
580  GOSUB 1720
590  IF F=1 THEN 780
600  J=3
610  GOSUB 1720
620  IF F=1 THEN 750
630  J=1
640  GOSUB 1720
650  IF F=1 THEN 800
660  LET A=A+1
670  IF A=2 THEN 800
680  IF A=3 THEN 840
690  GOSUB 2020
700  GOTO 520
710  PRINT "YOU HAVE THE RIGHT IDEA. NATURAL VEGETATION IS DROUGHT"
720  PRINT "RESISTANT; A MIXTURE OF SHORT, WIDELY SPACED TREES, MANY"
730  PRINT "SHRUBS AND SOME GRASS. OFTEN CALLED CHAPARRAL."
740  GOTO 870
750  PRINT "I THINK THAT YOU HAVE NAMED SOME COMMON PLANTS. I WANT A "
760  PRINT "MORE GENERAL DESCRIPTION OF THE VEGETATION. TRY AGAIN."
770  GOTO 520
780  GOSUB 1980
790  PRINT 
800  PRINT "THE NATURAL VEGETATION IS A RESPONSE TO A LONG, HOT,DRY"
810  PRINT "SUMMER AND A SHORT,COOL,MOIST WINTER;  CONDITIONS NOT"
820  PRINT "FAVORABLE FOR HEAVY FOREST OR FINE GRASSES. TRY AGAIN."
830  GOTO 520
840  PRINT "WELL, ";X$;", I'LL ANSWER FOR YOU. NATURAL VEGETATION IS"
850  PRINT "DROUGHT RESISTANT; A MIXTURE OF SHORT WIDELY SPACED TREES"
860  PRINT "WITH MANY SHRUBS AND SOME POOR GRASSES."
870  PRINT 
880  PRINT "NOW, WITHOUT NAMING CROPS, PLEASE CHARACTERIZE MEDITERRANEAN"
890  PRINT "AGRICULTURE.  (LIMIT OF 1 LINE)"
900  LET A=0
910  INPUT G$
920  PRINT 
930  J=4
940  GOSUB 1720
950  IF F=1 THEN 1100
960  J=10
970  GOSUB 1720
980  IF F=1 THEN 1160
990  J=3
1000  GOSUB 1720
1010  IF F=1 THEN 1140
1020  J=1
1030  GOSUB 1720
1040  IF F=1 THEN 1180
1050  LET A=A+1
1060  IF A=2 THEN 1180
1070  IF A=3 THEN 1200
1080  GOSUB 2020
1090  GOTO 910
1100  PRINT "NOT BAD - INTENSIVE FARMING WITH WINTER GRAINS,ORCHARDS,"
1110  PRINT "AND VEGETABLES; OFTEN IN TWO STORY COMBINATION, AND WITH"
1120  PRINT "SOME IRRIGATION IS COMMON."
1130  GOTO 1230
1140  PRINT "PLEASE DONT LIST CROPS - GIVE A GENERAL CHARACTERIZATION."
1150  GOTO 910
1160  GOSUB 1980
1170  PRINT 
1180  PRINT "TRY TO DESCRIBE FARMING IN ITALY,GREECE OR SO. CALIFORNIA."
1190  GOTO 910
1200  PRINT "YOU COULD HAVE SAID THAT FARMING IS INTENSIVE AND IRRIGATION"
1210  PRINT "COMMON.  WINTER GRAINS, ORCHARDS AND VEGETABLES DOMINATE."
1220  PRINT "          LET'S GO ON TO THE NEXT QUESTION"
1230  PRINT 
1240  PRINT "WHAT SPECIFIC CROPS WOULD YOU EXPECT TO FIND IN SUCH AN AREA"
1250  INPUT G$
1260  PRINT 
1270  J=3
1280  GOSUB 1720
1290  IF F=1 THEN 1320
1300  GOSUB 2020
1310  GOTO 1230
1320  PRINT "GRAPES, OLIVES, FIGS, WINTER WHEAT, BARLEY, CITRUS,NUTS,"
1330  PRINT "VEGETABLES AND OAK CORK ARE COMMON.";X$;" YOU ARE RIGHT."
1340  PRINT 
1350  PRINT "WHAT ARE SOME IMPORTANT CHARACTERISTICS OF ANIMAL HUSBANDRY"
1360  PRINT "IN THIS CLIMATIC REGION"
1370  INPUT G$
1380  PRINT 
1390  J=5
1400  GOSUB 1720
1410  IF F=1 THEN 1500
1420  J=10
1430  GOSUB 1720
1440  IF F=1 THEN 1530
1450  J=1
1460  GOSUB 1720
1470  IF F=1 THEN 1550
1480  GOSUB 2020
1490  GOTO 1370
1500  PRINT "GOOD TRY - MANY SHEEP AND GOATS SHARE THE DRY GRASSES OF"
1510  PRINT "OVERGRAZED SLOPES WITH A FEW CATTLE AND DONKEYS."
1520  GOTO 2280
1530  GOSUB 1980
1540  PRINT 
1550  PRINT "WHAT KINDS OF ANIMALS ARE RAISED IN SO. AUSTRALIA OR SPAIN"
1560  GOTO 1370
1570  PRINT 
1580  IF Z=2 THEN 1620
1590  IF Z=3 THEN 1660
1600  IF Z=4 THEN 1690
1610  IF Z<2 THEN 1650
1620  PRINT "THAT IS YOUR SECOND MISTAKE. IF YOU HAVE DONE THE FIRST FOUR"
1630  PRINT "LESSONS CAREFULLY AND HAVE COMPLETED THE READING, YOU SHOULD"
1640  PRINT "DO BETTER. KEEP TRYING."
1650  RETURN 
1660  PRINT "WOW!  YOUR THIRD MISTAKE!  ONE MORE AND I WILL QUIT TRYING"
1670  PRINT "TO HELP YOU.  TRY AGAIN BUT BE CAREFUL."
1680  RETURN 
1690  PRINT "TOO BAD - YOUR FOURTH MISTAKE - I QUIT!  YOU BETTER START"
1700  PRINT "AGAIN WITH ONE OF THE EASIER LESSONS."
1710  STOP 
1720  RESTORE 
1730  READ R$
1740  IF R$#"DICTIONARY" THEN 1730
1750  READ T,N
1760  IF T=9999 THEN 1720
1770  READ #1,1
1780  FOR I=1 TO N
1790  READ R$
1800  IF T#J THEN 1820
1810  PRINT #1;R$, END 
1820  NEXT I
1830  IF T#J THEN 1750
1840  READ #1,1
1850  IF  END #1 THEN 1940
1860  READ #1;S$
1870  FOR L=1 TO LEN(G$)-LEN(S$)+1
1880  FOR K=1 TO LEN(S$)
1890  IF G$[L+K-1,L+K-1]#S$[K,K] THEN 1920
1900  NEXT K
1910  GOTO 1960
1920  NEXT L
1930  GOTO 1860
1940  F=0
1950  GOTO 1970
1960  F=1
1970  RETURN 
1980  PRINT 
1990  PRINT "   $%&%%$**#$#   GOODNESS - SHAME ON YOU ! !! !!!"
2000  PRINT "WATCH YOUR LANGUAGE OR I'LL CUSS BACK AT YOUR"
2010  RETURN 
2020  PRINT 
2030  PRINT "I AM SORRY BUT I DON'T UNDERSTAND YOUR ANSWER. HAVE YOU"
2040  PRINT "MISSPELLED AN IMPT. WORD? PLEAS CHECK AND REPHRASE YOUR"
2050  PRINT "ANSWER."
2060  RETURN 
2070  DATA "DICTIONARY"
2080  DATA 2,14
2090  DATA "CHAPARRAL","SCRUB","THORN","SHRUB","BARK","DROU","SHORT TREE"
2100  DATA "MAQUIS","SCATTERED","SPACED","THIN","LIGHT","POOR","XERO"
2110  DATA 1,10
2120  DATA "QUERY","ASK","WHAT DO","KNOW HOW","DONT KNOW","DON'T KNOW"
2130  DATA "HOW","DON'T UNDER","DONT UNDER","HELP"
2140  DATA 3,10
2150  DATA "FIG","GRAPE","OLIV","WHEAT","VEGETAB","BARLEY","CITRUS","ORANG"
2160  DATA "WINE","CORK"
2170  DATA 4,16
2180  DATA "INTENSIVE","GRAIN","SMALL FIELD","SPECIALI","FRUIT"
2190  DATA "VEGETABL","XEROPH","SMALL FARM","ORCHARD","SMALL PLOT"
2200  DATA "IRRIGAT","DROU","WINTER","MULTI","VARIETY","NUMER"
2210  DATA 5,11
2220  DATA "SHEEP","GOAT","FEW CATTLE","NO CATTLE","FEW COWS","NO COWS"
2230  DATA "OVERGRAZED","ERO","DONK","BULLS","DRY GRASS"
2240  DATA 10,10
2250  DATA "HELL","SCREW","UCK","BASTA","BITCH","SHIT","BALLS","FART"
2260  DATA "PISS","CRAP"
2270  DATA 9999,0
2280  PRINT 
2290  PRINT " THE ORIGINAL DATA WAS FOR ADELAIDE, AUSTRALIA."
2300  PRINT "THE RAINFALL AND TEMPERATURE PATTERNS AT THAT LOCATION ARE"
2310  PRINT "TYPICAL OF ANY OF THE FIVE AREAS OF 'MEDITERRANEAN' CLIMATE"
2320  PRINT "SCATTERED THROUGHOUT THE WORLD."
2330  PRINT 
2340  PRINT "I HAD FUN - HOPE YOU DID TOO.  GOOD BYE,";X$"."
2350  END 
