10  COM Z,X$[72]
20  REM**CL3-1**BASIC C.A.I.**GEOGRAPHY**JUNE 13, 1972**CHAIN TO CL3-2
25  REM CLIMAT, HP 36760A, 6/74
30  Z=0
40  FILES SCRA
50  DIM R$[72],S$[72],G$[72]
60  PRINT "HI, GOOD LOOKING, MY NAME IS DAPHNE, WHAT'S YOURS";
70  INPUT X$
80  PRINT 
90  PRINT "HELLO, ";X$;", WELCOME BACK TO COMPUTER ASSISTED INSTRUCTION."
100  PRINT "ONCE AGAIN THE MONTHLY AVERAGE TEMPERATURES AND THE MONTHLY"
110  PRINT "AVERAGE RAINFALL DATA FOR A REAL STATION ARE GIVEN.  I WOULD"
120  PRINT "LIKE YOU TO FIGURE OUT THE TYPE OF CLIMATE ACCORDING TO THE "
130  PRINT "KOPPEN SYMBOLS AND ALSO LOCATE THE STATION WITH GREAT PRECISION"
140  PRINT "     IF YOU NEED HELP JUST LET ME KNOW."
150  PRINT 
160  PRINT "I SHOULD WARN YOU THAT I'M IMPATIENT AND WILL DROP YOU IN FAVOR"
170  PRINT "OF SOMEBODY ELSE WHEN YOU MAKE YOUR FOURTH MISTAKE."
180  PRINT 
190  PRINT 
200  PRINT "            TEMPERATURE THEN RAINFALL BY MONTHS"
210  PRINT "J.,  F.,  M.,  A.,  M.,  J.,  J.,  A.,  S.,  O.,  N.,  D."
220  PRINT 
230  PRINT "39,  40,  43,  48,  53,  57,  60,  61,  56,  50,  45,  41"
240  PRINT "4.5, 3.2, 2.5, 1.6, 1.2,  .9,  .4,  .6, 1.8, 2.5, 5.7, 5.8"
250  PRINT 
260  PRINT 
270  PRINT "             YEARLY AVERAGE TEMP.  49.4 DEGREES F."
280  PRINT "             YEARLY RAINFALL  TOTAL  30.7 INCHES"
290  PRINT 
300  PRINT "STUDY CAREFULLY THE TEMP. RANGE - NOTE THE MONTH OF"
310  PRINT "MAXIMUM TEMP.  LOOK CLOSELY AT THE SEASONAL DISTRIBUTION OF"
320  PRINT "RAINFALL. YES,THERE IS SUCH A PLACE - IT'S NEAR SEA-LEVEL"
330  PRINT 
340  PRINT 
350  PRINT "IN WHICH HEMISPHERE IS THE STATION LOCATED";
360  INPUT G$
370  PRINT 
380  J=10
390  GOSUB 2040
400  IF F#1 THEN 420
410  GOSUB 2300
420  J=9
430  GOSUB 2040
440  IF F=1 THEN 560
450  PRINT "NOTICE THAT JANUARY TEMPERATURES ARE WELL BELOW THOSE OF JUNE"
460  PRINT "AND JULY.  IN THE SOUTHERN HEMISPHERE INSOLATION (INCOMING"
470  PRINT "ENERGY FROM THE SUN) REACHES ITS MAXIMUM IN DECEMBER AND "
480  PRINT "JANUARY. THIS WOULD RESULT IN MAXIMUM TEMPS. IN THOSE MONTHS"
490  J=1
500  GOSUB 2040
510  IF F=1 THEN 540
520  GOSUB 1840
530  GOTO 360
540  PRINT "TRY AGAIN--"
550  GOTO 360
560  PRINT " GOOD, YOU KNEW BECAUSE OF THE WARMEST TEMPERATURES IN JULY"
570  PRINT "AND AUGUST.  NOW TELL ME ABOUT THE RELATIVE LOCATION WITHIN"
580  PRINT "THE NORTHERN HEMISPHERE."
590  INPUT G$
600  PRINT 
610  J=10
620  GOSUB 2040
630  IF F#1 THEN 650
640  GOSUB 2300
650  FOR J=2 TO 5
660  IF J=4 THEN 700
670  GOSUB 2040
680  IF F#1 THEN 700
690  GOTO J-1 OF 860,740,800,800
700  NEXT J
710  PRINT "WHAT I REALLY WANT IS AN ANSWER TO THIS QUESTION.  IS OUR"
720  PRINT "    STATION IN THE   POLAR,  MID-LATITUDE  OR EQUATORIAL AREA"
730  GOTO 590
740  PRINT "IN POLAR ENVIRONMENTS TEMPERATURES IN THE SUMMER MONTHS"
750  PRINT "DO NOT EXCEED AN AVERAGE OF 50 DEGREES F. FOR ANY"
760  PRINT "SIGNIFICANT PERIOD. TEMPERATURES HIGHER THAN THIS ALONG"
770  PRINT "WITH MODEST RAINFALL LEAD TO FOREST GROWTH AS AT OUR STATION"
780  GOSUB 1840
790  GOTO 590
800  PRINT "IF THE STATION WERE NEAR THE EQUATOR, SUCH LOW TEMPS."
810  PRINT "COULD BE REACHED ONLY HIGH IN THE MOUNTAINS.  AT SUCH A"
820  PRINT "LOCATION THE TEMPERATURE RANGE WOULD BE CONSIDERABLY"
830  PRINT "LESS THAN THE 22 DEGREES SHOWN HERE"
840  GOSUB 1840
850  GOTO 590
860  PRINT "FIRST RATE, ";X$;"! NOW, WITHIN THIS MID-LATITUDE REGION"
870  PRINT "IS THE STATION CLOSER TO THE POLEWARD OR TO THE EQUATORIAL"
880  PRINT "MARGIN";
890  INPUT G$
900  PRINT 
910  J=10
920  GOSUB 2040
930  IF F#1 THEN 950
940  GOSUB 2300
950  J=4
960  GOSUB 2040
970  IF F=1 THEN 1060
980  PRINT "LOOK AGAIN AT THE JANUARY AND JULY TEMPS.  DO THESE SIMULATE"
990  PRINT "WHAT YOU WOULD EXPECT IN  SAVANNA,GEORGIA; HOUSTON, TEXAS;"
1000  PRINT "OR SAN DIEGO,CALIF.?  A BIT LOW, HUH?"
1010  J=1
1020  GOSUB 2040
1030  IF F=1 THEN 870
1040  GOSUB 1840
1050  GOTO 870
1060  PRINT "GREAT - NOW TO REVIEW;  OUR STATION IS:"
1070  PRINT "          NORTHERN HEMISPHERE"
1080  PRINT "          UPPER MID-LATITUDES"
1090  PRINT 
1100  PRINT "REFERRING TO YOUR MAP, YOU KNOW THAT A LARGE CONTINENT IS"
1110  PRINT "INVOLVED.  PLEASE COMMENT ON THE RELATIVE LOCATION OF THE"
1120  PRINT "STATION ON THAT CONTINENT."
1130  INPUT G$
1140  PRINT 
1150  GOSUB 2040
1160  J=10
1170  GOSUB 2040
1180  IF F#1 THEN 1200
1190  GOSUB 2300
1200  FOR J=13 TO 16
1210  GOSUB 2040
1220  IF F#1 THEN 1240
1230  GOTO J-12 OF 1440,1490,1390,1320
1240  NEXT J
1250  J=30
1260  GOSUB 2040
1270  IF F=1 THEN 1350
1280  PRINT "YOUR ANSWER SHOULD TELL ME WHETHER THE STATION IS IN THE"
1290  PRINT "INTERIOR OF THE LAND MASS OR NEAR OCEANIC INFLUENCE AND"
1300  PRINT "IF NEAR THE COAST, WHICH COAST."
1310  GOTO 1130
1320  PRINT "YOU ALMOST ONE-UPPED ME, ";X$;".  MARINE INFLUENCE IS INDICATED"
1330  PRINT "BY THE DATA - BUT - WHICH COAST"
1340  GOTO 1130
1350  PRINT "HOW CAN YOU POSSIBLY GET ";G$;" FROM THE DATA PRESENTED."
1360  PRINT "STUDY THE RAINFALL PATTERN AND TRY AGAIN."
1370  GOSUB 1840
1380  GOTO 1130
1390  PRINT "IN A CONTINENTAL INTERIOR THE TEMP. RANGE WOULD BE GREATER"
1400  PRINT "(MINNEAPOLIS = 60 RANGE FRON JAN. TO JULY) AND RAINFALL WOULD"
1410  PRINT "NOT BE GREATEST IN THE WINTER MONTHS - MORE LIKELY IN SUMMER"
1420  GOSUB 1840
1430  GOTO 1130
1440  PRINT "HOLD IT!  REMEMBER IN STATION #1 WE LEARNED THAT THE EAST"
1450  PRINT "COAST IS CHARACTERIZED BY QUITE EVEN DISTRIBUTION OF RAINFALL"
1460  PRINT "FROM SEASON TO SEASON.  SUCH IS NOT THE CASE AT THIS STATION"
1470  GOSUB 1840
1480  GOTO 1130
1490  PRINT "AT A WEST COAST LOCATION IN THE MID-LATITUDES THE RAINFALL"
1500  PRINT "USUALLY SHOWS A MARKED CONCENTRATION IN THE WINTER MONTHS."
1510  PRINT "WEST COAST IS CORRECT - GOOD GOING, ";X$;"."
1520  PRINT 
1530  PRINT "NOW YOU KNOW THE STATION IS:"
1540  PRINT "      NORTHERN HEMISPHERE"
1550  PRINT "      UPPER MID-LATITUDES"
1560  PRINT "      CLOSE TO THE WEST COAST"
1570  PRINT 
1580  PRINT "MY MAP SAYS THAT THE ONLY PLACES SATISFYING THESE CONDITIONS"
1590  PRINT "ARE TO BE FOUND IN EUROPE OR NORTH AMERICA. WHICH OF THESE"
1600  PRINT "CHOICES DO YOU FEEL IS CORRECT"
1610  INPUT G$
1620  PRINT 
1630  GOSUB 2040
1640  J=10
1650  GOSUB 2040
1660  IF F#1 THEN 1680
1670  GOSUB 2300
1680  J=25
1690  GOSUB 2040
1700  IF F=1 THEN 1790
1710  PRINT X$;", IN COASTAL W. EUROPE THE RAINFALL MAX. IS NORMALLY"
1720  PRINT "IN OCTOBER AND THE DRYEST PERIOD IS IN EARLY SPRING"
1730  PRINT "TRY AGAIN--";
1740  J=1
1750  GOSUB 2040
1760  IF F=1 THEN 1610
1770  GOSUB 1840
1780  GOTO 1610
1790  PRINT "FABULOUS - I HOPE YOU CHOSE NORTH AMERICA BECAUSE THE PACIFIC"
1800  PRINT "RAINFALL PATTERN HAS A NOV.-DEC. MAX. AND HAS DRYER SUMMERS"
1810  PRINT "THAN DOES N.W.EUROPE.  OUR STATION MATCHES THE PACIFIC MODEL"
1820  PRINT 
1830  CHAIN "$CL3-2"
1840  REM MISTAKES
1850  PRINT 
1860  LET Z=Z+1
1870  IF Z=1 THEN 2010
1880  IF Z=2 THEN 1980
1890  IF Z=3 THEN 1940
1900  PRINT "SORRY, I GIVE UP.  THAT WAS YOUR FOURTH MISTAKE"
1910  PRINT "GO BACK AND REVIEW THE PREVIOUS LESSON."
1920  PRINT 
1930  STOP 
1940  PRINT "BETTER WATCH YOUR STEP! THAT WAS YOUR THIRD MISTAKE;"
1950  PRINT "ONE MORE AND I'LL GIVE UP!"
1960  PRINT 
1970  RETURN 
1980  PRINT "DANGER LURKS: THAT WAS YOUR SECOND MISTAKE--"
1990  PRINT 
2000  RETURN 
2010  PRINT "I'M COUNTING - THAT WAS YOUR FIRST MISTAKE."
2020  PRINT 
2030  RETURN 
2040  RESTORE 
2050  READ R$
2060  IF R$#"DICTIONARY" THEN 2050
2070  READ T,N
2080  IF T=9999 THEN 2040
2090  READ #1,1
2100  FOR I=1 TO N
2110  READ R$
2120  IF T#J THEN 2140
2130  PRINT #1;R$, END 
2140  NEXT I
2150  IF T#J THEN 2070
2160  READ #1,1
2170  IF  END #1 THEN 2260
2180  READ #1;S$
2190  FOR L=1 TO LEN(G$)-LEN(S$)+1
2200  FOR K=1 TO LEN(S$)
2210  IF G$[L+K-1,L+K-1]#S$[K,K] THEN 2240
2220  NEXT K
2230  GOTO 2280
2240  NEXT L
2250  GOTO 2180
2260  F=0
2270  GOTO 2290
2280  F=1
2290  RETURN 
2300  PRINT 
2310  PRINT "    #$%$%%#'$!$#    GOODNESS - SHAME ON YOU !! !!! !"
2320  PRINT "PLEASE DON'T USE WORDS LIKE THAT - IT HURTS MY EGO!"
2330  PRINT 
2340  RETURN 
2350  DATA "DICTIONARY"
2360  DATA 2,10
2370  DATA "MID-LAT","MIDLAT","MIDDLE","HALF WAY","MID WAY","MIDWAY"
2380  DATA "MID-WAY"
2390  DATA "CENTRA","FORTY","FIFTY"
2400  DATA 1,3
2410  DATA "DONT UNDER"
2420  DATA "DON'T UNDER","HELP"
2430  DATA 3,7
2440  DATA "POLAR","POLE","NORTH","ARTIC","ARCTIC","SIXTY","SEVENTY"
2450  DATA 4,4
2460  DATA "POLE","NORTH","ARCTIC","POLEWARD"
2470  DATA 5,5
2480  DATA "EQUAT","SOUTH","LOW","TWENTY","THIRTY"
2490  DATA 13,1
2500  DATA "EAST"
2510  DATA 14,1
2520  DATA "WEST"
2530  DATA 15,5
2540  DATA "INTERIOR","REMOTE","FAR","INLAND","CONTINENTAL"
2550  DATA 16,7
2560  DATA "COAST","SHORE","SEA","OCEAN","CURRENT","MARINE","WATER"
2570  DATA 10,12
2580  DATA "HELL","SCREW","UCK","ALLS","SHIT","PISS","FART","CRAP"
2590  DATA "BITCH","GOD","DAMM","DAMN"
2600  DATA 9,1
2610  DATA "NORTH"
2620  DATA 12,6
2630  DATA "EAST","WEST","ORIENT","OCCIDENTAL","LAND","WATER"
2640  DATA 17,4
2650  DATA "VICTORIA","VIC","VICTOR","VICTORA"
2660  DATA 18,4
2670  DATA "SEATTLE","TACOMA","EVERET","OLYMPIA"
2680  DATA 19,2
2690  DATA "VANCOUVER","BELLING"
2700  DATA 20,3
2710  DATA "SITKA","JUNEAU","KETCH"
2720  DATA 25,6
2730  DATA "NORTH AMERICA","AMERICA","AMERI","N.A.","N. A.","N. AMERICA"
2740  DATA 30,2
2750  DATA "SOUTH","NORTH"
2760  DATA 31,3
2770  DATA "PORTLAND","SALEM","EUGENE"
2780  DATA 9999,0
2790  END 
