1  REM  **** HP TIME-SHARED BASIC PROGRAM LIBRARY *****************
2  REM
3  REM        CADA1M:  COMPUTER ASSISTED ARITHMETIC DRILL
4  REM     
5  REM          36205  REV A      3/72    PART 2 OF 3
6  REM
7  REM  ************** CONTRIBUTED PROGRAM ******************************
8  REM
9  REM
10  REM-----RECORD UPKEEP FOR CADA1F FILE-----
20  FILES CADA1F
30  DIM N$[25]
40  PRINT "1=UPDATE RECORD OF STUDENT, 2=OPEN STUDENT RECORD, 3=ERASE"
50  PRINT "STUDENT RECORD, 4=PRINT ONE STUDENT RECORD, 5=PRINT ALL"
60  PRINT "STUDENT RECORDS."
70  INPUT P
80  GOTO P OF 90,190,300,370,430
90  REM=====================UPDATE RECORD======================
100  PRINT "STUDENT # ";
110  INPUT R
120  READ #1,R;T,N$,A1,A2,A3,A4,S1,S2,S3,S4,M1,M2,M3,M4,D1,D2,D3,D4
130  GOSUB 530
140  READ #1,R
150  PRINT "HOW SHOULD THE FILE READ"
160  INPUT A1,A2,A3,A4,S1,S2,S3,S4,M1,M2,M3,M4,D1,D2,D3,D4
170  PRINT #1,R;T,N$,A1,A2,A3,A4,S1,S2,S3,S4,M1,M2,M3,M4,D1,D2,D3,D4
180  GOTO 660
190  REM---------------------OPEN RECORD-------------------------
200  FOR R=1 TO 25
210  READ #1,R;T
220  IF T=0 THEN 240
230  NEXT R
240  READ #1,R
250  PRINT "STUDENT NUMBER IS ";R;"  STUDENT NAME IS";
260  INPUT N$
270  A1=A2=A3=A4=S1=S2=S3=S4=M1=M2=M3=M4=D1=D2=D3=D4=0
280  PRINT #1,R;R,N$,A1,A2,A3,A4,S1,S2,S3,S4,M1,M2,M3,M4,D1,D2,D3,D4
290  GOTO 660
300  REM----------------------ERASE RECORD-----------------------
310  PRINT "ERASE RECORD # ";
320  INPUT R
330  N$="A"
340  A1=A2=A3=A4=S1=S2=S3=S4=M1=M2=M3=M4=D1=D2=D3=D4=0
350  PRINT #1,R;A1,N$,A1,A2,A3,A4,S1,S2,S3,S4,M1,M2,M3,M4,D1,D2,D3,D4
360  GOTO 660
370  REM-----------------------PRINT ONE RECORD-------------------
380  PRINT "WHAT IS STUDENT #";
390  INPUT R
400  READ #1,R;T,N$,A1,A2,A3,A4,S1,S2,S3,S4,M1,M2,M3,M4,D1,D2,D3,D4
410  GOSUB 530
420  GOTO 660
430  REM-----------------------PRINT ALL RECORDS------------------
440  FOR R=1 TO 25
450  READ #1,R;T,N$,A1,A2,A3,A4,S1,S2,S3,S4,M1,M2,M3,M4,D1,D2,D3,D4
460  IF T=0 THEN 510
470  GOSUB 530
480  PRINT 
490  PRINT 
500  PRINT 
510  NEXT R
520  GOTO 660
530  REM--------------------PRINT OUT RECORD---------------------
540  PRINT N$,T
550  PRINT 
560  PRINT "OPERATION","ATTEMPTED","1 ST TRY","2 ND TRY","INCORRECT"
570  PRINT 
580  PRINT "ADD.",A1,A2,A3,A4
590  PRINT "SUB.",S1,S2,S3,S4
600  PRINT "MULT.",M1,M2,M3,M4
610  PRINT "DIV.",D1,D2,D3,D4
620  PRINT 
630  PRINT 
640  PRINT 
650  RETURN 
660  PRINT "DO YOU WISH FURTHER MAINTANENCE";
670  DIM X$[5]
680  INPUT X$
690  IF X$="YES" THEN 70
700  END 
