1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        ATWT:   CALCULATES ATOMIC WEIGHT
4  REM
5  REM        36613 REV  A   6/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ************************************
50  REM ATWT - COPYRIGHT 1971, POLYTECHNIC INSTITUTE OF BROOKLYN
100  REM  HARRY DORFMAN  7-15-69
105  REM  REVISED BY C.LOSIK  8-12-70 
106  REM  B(I) ARE THE MASS NOS., C(I) ARE THE PERCENTS 
110  PRINT " THIS PROGRAM WILL CALCULATE THE ATOMIC WEIGHT (ATOMIC MASS)"
120  PRINT " FROM THE PERCENT ABUNDANCE OF EACH ISOTOPE.  PERCENT"
130  PRINT " ABUNDANCES MAY BE FOUND IN THE CHEMISTRY HANDBOOK."
140  PRINT 
150  PRINT " HOW MANY ISOTOPES DOES THE ELEMENT HAVE ";
160  INPUT A
163  IF ABS(A-INT(A))>.0001 THEN 150
166  PRINT 
170  PRINT " INPUT THE MASS NUMBER AND THE PERCENT ABUNDANCE FOR"
180  PRINT " EACH OF THE"A"ISOTOPES."
185  PRINT 
190  DIM B[20],C[20]
193  LET D=0
196  LET E=0
200  FOR I=1 TO A
205  PRINT " ISOTOPE NO."I" ";
210  INPUT B[I],C[I]
213  LET D=D+B[I]*C[I]
216  LET E=E+C[I]
220  NEXT I
235  PRINT 
245  PRINT 
300  IF ABS(E-100)<.2 THEN 309
302  PRINT 
304  PRINT " THE PERCENT ABUNDANCE DOES NOT TOTAL 100."
305  PRINT " CHECK PERCENTAGES AND REENTER DATA."
306  GOTO 185
309  LET D=D/100
310  PRINT " ATOMIC WEIGHT (ATOMIC MASS) IS";D
315  PRINT 
320  PRINT " ANOTHER RUN (1=YES, 0=NO) ";
330  INPUT A
335  PRINT 
340  IF A=1 THEN 140
350  IF A <> 0 THEN 320
360  END 
