1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        STAT14:   ANALYSIS OF VARIANCE AND F-RATIOS
4  REM                  (RANDOMIZED COMPLETE BLOCK DESIGN)
5  REM        36730 REV  A   10/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ************************************
9000  REM  STAT14--ANALYSIS OF VARIANCE, RANDOMIZED COMPLETE BLOCK
9002  PRINT "ANALYSIS OF VARIANCE TABLE"
9004  PRINT 
9006  PRINT "ITEM","SUM-SQR","DEG. FREE.","MEAN-SQR"
9008  PRINT 
9010  READ T,B
9012  LET A3=0
9014  LET U=0
9016  FOR I=1 TO B
9018  FOR J=1 TO T
9020  READ X[I,J]
9022  LET A3=A3+X[I,J]^2
9024  LET U=U+X[I,J]
9026  LET S[J]=0
9028  NEXT J
9030  LET G[I]=0
9032  NEXT I
9034  FOR I=1 TO B
9036  FOR J=1 TO T
9038  LET G[I]=G[I]+X[I,J]
9040  NEXT J
9042  NEXT I
9044  FOR J=1 TO T
9046  FOR I=1 TO B
9048  LET S[J]=S[J]+X[I,J]
9050  NEXT I
9052  NEXT J
9054  LET C=(U^2)/B/T
9056  LET W=0
9058  FOR J=1 TO T
9060  LET W=W+S[J]^2
9062  NEXT J
9064  LET A=W/B-C
9066  LET W1=0
9068  FOR I=1 TO B
9070  LET W1=W1+G[I]^2
9072  NEXT I
9074  LET A1=W1/T-C
9076  LET A2=A3-A1-A-C
9078  LET D=(B-1)*(T-1)
9080  PRINT "GRAND TOTAL",A3,B*T
9082  PRINT "GRAND MEAN",C," 1"
9084  PRINT "TREATMENTS",A,T-1,A/(T-1)
9086  PRINT "BLOCKS",A1,B-1,A1/(B-1)
9088  PRINT "ERROR",A2,D,A2/D
9090  PRINT 
9092  PRINT 
9094  LET F=A/(T-1)/(A2/D)
9096  LET F1=A1/(B-1)/(A2/D)
9098  PRINT "F-RATIO FOR TREATMENTS ="F", ON"T-1"AND"D"DEGREES OF FREEDOM."
9100  PRINT "F-RATIO FOR BLOCKS ="F1", ON"B-1"AND"D"DEGREES OF FREEDOM."
9900  DATA 4,4
9901  DATA 4,1,-1,0
9902  DATA 1,1,-1,-2
9903  DATA 0,0,-3,-2
9904  DATA 0,-5,-4,-4
9999  END 
