5  REM MLREG, HP 36661A, 6/74
110  REM THIS MULTIPLE REGRESSION PROGRAM WRITTEN BY WILLIAM LUCAS
120  REM  STARTING AT LINE 2000 TYPE IN THE NUMBER OF COLUMNS
130  REM  AND THE NUMBER OF ROWS AS DATA.  THEN TYPE IN DATA, READING
140  REM  DOWN EACH COLUMN IN TURN.  
1070  READ A1,A2
1080  MAT D=ZER[A1]
1090  MAT F=ZER[A1]
1100  MAT G=ZER[A1]
1130  MAT K=ZER[A1-1]
1140  MAT L=ZER[A1-1]
1150  MAT M=ZER[A1-1,A1-1]
1160  MAT B=ZER[A2,A1]
1170  MAT E=ZER[A2,A1]
1180  MAT Q=ZER[A1-1,A1-1]
1185  R1=R2=R3=0
1190  FOR X=1 TO A1
1200  FOR Y=1 TO A2
1205  READ B[Y,X]
1210  D[X]=D[X]+B[Y,X]/A2
1230  NEXT Y
1250  NEXT X
1260  PRINT "COLUMN","MEAN","CHI-SQUARE","STANDARD DEVIATION"
1270  FOR X=1 TO A1
1280  FOR Y=1 TO A2
1290  E[Y,X]=B[Y,X]-D[X]
1300  F[X]=F[X]+E[Y,X]^2
1310  G[X]=G[X]+((E[Y,X]^2)/D[X])
1320  NEXT Y
1330  H[X]=SQR(F[X]/(A2-1))
1340  PRINT X,D[X],G[X],H[X]
1350  NEXT X
1360  PRINT 
1370  FOR Z=1 TO A1
1374  R1=R1+F[Z]
1376  R2=R2+D[Z]/A1
1380  FOR X=1 TO A1
1390  A3=0
1400  FOR Y=1 TO A2
1410  A3=A3+E[Y,Z]*E[Y,X]
1420  NEXT Y
1430  J[X,Z]=A3
1440  NEXT X
1450  NEXT Z
1460  PRINT "PARTIAL CORRELATIONS";TAB(30);"STUDENT'S T AT "A2-1"D.F."
1470  FOR X=1 TO A1
1475  R3=R3+(D[X]-R2)^2
1480  FOR Y=1 TO A1
1490  IF Y <= X THEN 1510
1495  R5=J[Y,X]/SQR(J[X,X]*J[Y,Y])
1498  R6=(D[X]-D[Y])/(SQR(A2*(H[X]^2+H[Y]^2)/(2*A2-2))*SQR(2/A2))
1500  PRINT "R";X;Y;R5,TAB(35);ABS(R6)
1510  NEXT Y
1520  NEXT X
1530  FOR Y=2 TO A1
1540  L[Y-1]=J[Y,1]
1560  FOR X=2 TO A1
1580  M[Y-1,X-1]=J[Y,X]
1590  NEXT X
1600  NEXT Y
1610  MAT Q=INV(M)
1620  MAT K=Q*L
1625  PRINT 
1630  PRINT "THE BETA TEST"
1640  FOR X=2 TO A1
1650  PRINT X,K[X-1]*SQR(F[X]/A2)/SQR(F[1]/A2)
1660  NEXT X
1670  PRINT 
1680  A3=A5=A7=0
1690  FOR X=2 TO A1
1700  A5=A5+D[X]*K[X-1]
1710  NEXT X
1720  A6=D[1]-A5
1740  FOR X=1 TO A2
1750  FOR Y=2 TO A1
1760  A3=A3+B[X,Y]*K[Y-1]
1770  NEXT Y
1780  A7=A7+(B[X,1]-A3-A6)^2
1790  A3=0
1800  NEXT X
1810  PRINT "STANDARD ERROR OF THE ESTIMATE IS "SQR(A7/A2)
1830  PRINT "COEFFICIENT OF LINEAR MULTIPLE CORRELATION"SQR(1-A7/F[1])
1840  PRINT "COEFFICIENT OF MULTIPLE DETERMINATION IS"1-A7/F[1]
1845  PRINT 
1848  PRINT "THE F DISTRIBUTION","DEGREES OF FREEDOM","DENOMINATOR"
1850  R4=((A2*R3)/(A1-1))/(R1/(A1*(A2-1)))
1852  PRINT R4;TAB(30);A1-1;TAB(60);A1*(A2-1)
1855  PRINT 
1860  PRINT "THE REGRESSION EQUATION IS"
1865  PRINT "X1 = "A6
1870  FOR X=2 TO A1
1875  PRINT "            + "K[X-1]"X"X
1880  NEXT X
2000  DATA 3,12
2010  DATA 64,71,53,67,55,58,77,57,56,51,76,68
2020  DATA 57,59,49,62,51,50,55,48,52,42,61,57
2030  DATA 8,10,6,11,8,7,10,9,10,6,12,9
3000  END 
