10  REM  TYPIT:  A TYPING QUIZ ON BUSINESS LETTERS.  PROGRAMMED BY
20  REM  MR. WILLIAM K. CHAR, NOVEMBER 20, 1974
30  REM
35  IF  ERROR  THEN 560
40  DIM A$[72],B$[72],N$[20],A[100]
50  REM
60  IF TIM(1)>11 THEN 90
70  PRINT "GOOD MORNING, ";
80  GOTO 130
90  IF TIM(1)>13 THEN 120
100  PRINT "GOOD AFTERNOON, ";
110  GOTO 130
120  PRINT "GOOD EVENING, ";
130  PRINT "WHAT IS YOU FIRST NAME";
140  INPUT N$
150  PRINT "DO YOU NEED THE INSTRUCTIONS, "N$;
160  INPUT A$
170  IF A$[1,1]="N" THEN 240
180  PRINT 
190  PRINT "     $TYPIT IS A QUIZ ABOUT BUSINESS LETTERS.  ANSWER"
200  PRINT "EACH QUESTION WITH AN 'A', 'B', 'C', 'D', OR 'E'."
210  PRINT "QUESTIONS ANSWERED INCORRECTLY WILL BE REPEATED."
220  PRINT 
230  PRINT "====="
240  N=0
250  READ B$
260  IF B$[1,1] <> "$" THEN 250
270  IF B$="$END" THEN 300
280  N=N+1
290  GOTO 250
300  PRINT 
310  PRINT "     THERE ARE  "N"QUESTIONS IN THIS TYPING EXAM."
320  MAT A=ZER
330  E=0
340  REM  ===== BEGIN QUESTION SEARCH =====
350  REM  (ADVANCE MISTAKE COUNTERS)
360  FOR I=1 TO N
370  IF A[I]=0 OR A[I]=100 THEN 390
380  A[I]=A[I]+1
390  NEXT I
400  REM  (CHECK FOR REPEATS)
410  FOR I=1 TO N
420  IF A[I]>3 AND A[I]<100 THEN 610
430  NEXT I
440  REM  (CHECK IF ANY QUESTIONS REMAIN)
450  FOR I=1 TO N
460  IF A[I]=0 THEN 580
470  NEXT I
480  REM  (CHECK IF ANY MISTAKES OUTSTANDING)"
490  FOR I=1 TO N
500  IF A[I]>0 AND A[I]<100 THEN 360
510  NEXT I
520  PRINT 
530  PRINT "     THANK YOU, "N$".  YOU HAVE COMPLETED THIS EXAM WITH ";
540  PRINT  USING "DD";E
550  PRINT "ERRORS.  TRY IT AGAIN, SOMETIME."
560  CHAIN R,"*HELP"
565  SYSTEM X,"BYE"
570  REM  (RANDOMLY SELECT QUESTION)
580  I=INT(N*RND(0)+1)
590  IF A[I] THEN 580
600  REM  ===== READ AND PRINT QUESTION =====
610  RESTORE 
620  FOR J=1 TO I
630  READ B$
640  IF B$[1,1] <> "$" THEN 630
650  NEXT J
660  PRINT 
670  PRINT B$[2]
680  READ B$
690  IF B$[1,1]="?" THEN 720
700  PRINT B$
710  GOTO 680
720  PRINT " ";
730  INPUT A$
740  IF A$[1,1]=B$[2,2] THEN 790
750  PRINT " WRONG; THE ANSWER IS '"B$[2,2]"'"
760  A[I]=1
770  E=E+1
780  GOTO 360
790  PRINT " RIGHT!"
800  A[I]=100
810  GOTO 360
1000  DATA "$THE SALUTATION IN A BUSINESS LETTER"
1010  DATA " A.  COMES BEFORE THE INSIDE ADDRESS;"
1020  DATA " B.  COMES AFTER THE INSIDE ADDRESS;"
1030  DATA " C.  COMES AFTER THE COMPLIMENTARY CLOSE;"
1040  DATA " D.  NONE OF THE ABOVE."
1050  DATA "?B"
1060  DATA "$AN EXAMPLE OF A COMPLIMENTARY CLOSE IS:"
1070  DATA " A.  DEAR SIR"
1080  DATA " B.  MR. JOHN H. HAMMOND"
1090  DATA " C.  YOURS TRULY,"
1100  DATA " D.  JOHN SMITH, PRESIDENT"
1110  DATA "?C"
1120  DATA "$HOW MANY BLANK LINES SHOULD BE ALLOWED BETWEEN THE"
1130  DATA "COMPLIMENTARY CLOSE AND THE TYPED SIGNATURE LINE?"
1140  DATA " A.  ONE;  B.  TWO;  C.  THREE;  D.  FOUR."
1150  DATA "?C"
1160  DATA "$ON AN ENVELOPE, HOW MANY BLANK SPACES SHOULD BE LEFT"
1170  DATA "BETWEEN THE STATE ABBREVIATION AND THE ZIP CODE?"
1180  DATA " A.  ONE;  B.  TWO;  C.  THREE;  D.  FOUR."
1190  DATA "?B"
1200  DATA "$IN A MANUSCIPT FOOTNOTES SHOULD BE"
1210  DATA " A.  DOUBLE SPACED;  B.  READ CAREFULLY;"
1220  DATA " C.  SINGLE SPACED;  D.  LEFT OUT."
1230  DATA "?C"
1240  DATA "$IF A LETTER CONTAINS 150 WORDS, IT SHOULD BE CLASSIFIED AS"
1250  DATA " A.  LONG;     B.  SHORT;"
1260  DATA " C.  AVERAGE;  D.  TWO-PAGE."
1270  DATA "?C"
1280  DATA "$WHEN BACKSPACING TO CENTER, BACKSPACE"
1290  DATA " A.  ONE FOR EVERY TWO SPACES;"
1300  DATA " B.  ONE FOR EVERY SPACE;"
1310  DATA " C.  ONE FOR EVERY THREE SPACES;"
1320  DATA " D.  NONE OF THE ABOVE."
1330  DATA "?A"
1340  DATA "$WHEN TYPING AN ENVELOPE"
1350  DATA " A.  BACKSPACE FIVE TO LEFT OF THE CENTER OF THE MACHINE;"
1360  DATA " B.  BACKSPACE FIVE TO LEFT OF THE CENTER OF THE ENVELOPE;"
1370  DATA " C.  START TYPING AT THE CENTER;"
1380  DATA " D.  NONE OF THE ABOVE."
1390  DATA "?B"
1400  DATA "$NAMES AND ADDRESSES ON ENVELOPES SHOULD BE"
1410  DATA " A.  SINGLE SPACED;  B.  DOUBLE SPACED;"
1420  DATA " C.  TRIPLE SPACED;  D.  NONE OF THE ABOVE."
1430  DATA "?A"
1440  DATA "$HORIZONTAL MEANS"
1450  DATA " A.  UP AND DOWN;  B.  ACROSS FROM LEFT TO RIGHT;"
1460  DATA " C.  UP AND DOWN OR ACROSS;  D.  NONE OF THE ABOVE."
1465  DATA "?B"
1470  DATA "$YOU SHOULD ALWAYS BEGIN A BUSINESS LETTER WITH"
1480  DATA " A.  THE LETTER ADDRESS;  B.  THE CURRENT DATE;"
1490  DATA " C.  YOUR NAME;           D.  YOUR ADDRESS;"
1500  DATA " E.  THE COMPLIMENTARY CLOSE."
1505  DATA "?B"
1510  DATA "$THE FOLLOWING TYPIST'S INITIALS HAVE BEEN TYPED CORRECTLY:"
1520  DATA " A.  M.G.   B.  M. G."
1530  DATA " C.  MG     D.  NONE OF THESE"
1540  DATA "?C"
1550  DATA "$MODIFIED BLOCK LETTER STYLE MEANS THAT"
1560  DATA " A.  THE DATE AND CLOSING LINES BEGIN AT THE LEFT MARGIN;"
1570  DATA " B.  THE DATE BEGINS AT THE LEFT MARGIN BUT THE CLOSING"
1580  DATA "     LINES BEGIN AT THE CENTER;"
1590  DATA " C.  THE DATE BEGINS AT THE CENTER BUT THE CLOSING LINES"
1600  DATA "     BEGIN AT THE LEFT MARGIN;"
1610  DATA " D.  THE DATE AND CLOSING LINES BEGIN AT THE CENTER."
1620  DATA "?D"
1630  DATA "$HOW MANY TIMES SHOULD YOU SPACE DOWN AFTER TYPING THE DATE?"
1640  DATA " A.  ALWAYS FOUR TIMES;  B.  ALWAYS THREE TIMES;"
1650  DATA " C.  ALWAYS TOW TIMES;   D.  ALWAYS ONE TIME;"
1660  DATA " E.  NONE OF THE ABOVE."
1670  DATA "?A"
1680  DATA "$OPEN PUNCTUATION MEANS TO"
1690  DATA " A.  OMIT THE COLON AFTER THE SALUTATION AND THE COMMA AFTER"
1700  DATA "     THE COMPLIMENTARY CLOSE;"
1710  DATA " B.  TYPE THE COLON AFTER THE SALUTATION AND TYPE THE COMMA"
1720  DATA "     AFTER THE COMPLIMENTARY CLOSE;"
1730  DATA " C.  OMIT THE COLON AFTER THE SALUTATION BUT TYPE THE COMMA"
1740  DATA "     AFTER THE COMPLIMENTARY CLOSE;"
1750  DATA " D.  TYPE THE COLON AFTER THE SALUTATION BUT OMIT THE COMMA"
1760  DATA "     AFTER THE COMPLIMENTARY CLOSE;"
1770  DATA " E.  NONE OF THE ABOVE."
1775  DATA "?A"
1780  DATA "$MIXED PUNCTUATION MEANS TO"
1790  DATA " A.  OMIT THE COLON AFTER THE SALUTATION AND THE COMMA AFTER"
1800  DATA "     THE COMPLIMENTARY CLOSE;"
1810  DATA " B.  TYPE TIE COLON AFTER THE SALUTATION AND TYPE THE COMMA"
1820  DATA "     AFTER THE COMPLIMENTRY CLOSE;"
1830  DATA " C.  OMIT THE COLON AFTER THE SALUTATION BUT TYPE THE COMMA"
1840  DATA "     AFTER THE COMPLIMENTARY CLOSE;"
1850  DATA " D.  TYPE THE COLON AFTER THE SALUTATION BUT OMIT THE COMMA"
1860  DATA "     AFTER THE COMPLIMENTARY CLOSE;"
1870  DATA " E.  NONE OF THE ABOVE."
1875  DATA "?B"
1880  DATA "$THE WORD 'ENCLOSURE' TYPED AT THE BOTTOM OF A LETTER MEANS"
1890  DATA "THAT"
1900  DATA " A.  THE ENVELOPE SHOULD BE SEALED;"
1910  DATA " B.  SOMETHING IS BEING SENT WITH THE LETTER;"
1920  DATA " C.  THE BOSS TYPED THE LETTER;"
1930  DATA " D.  ANOTHER LETTER WILL FOLLOW THIS ONE;"
1940  DATA " E.  NONE OF THE ABOVE."
1945  DATA "?B"
1950  DATA "$WHEN TYPING PARAGRAPHS OF A LETTER, YOU SHOULD ALWAYS"
1960  DATA " A.  SINGLE SPACE WITHIN THE PARAGRAPH BUT DOUBLE SPACE"
1970  DATA "     BETWEEN PARAGRAPHS;"
1980  DATA " B.  DOUBLE SPACE ALL THE TIME;"
1990  DATA " C.  TRIPLE SPACE BETWEEN PARAGRAPHS;"
2000  DATA " D.  INDENT PARAGRAPHS;"
2010  DATA " E.  SINGLE SPACE EVERYTHING."
2020  DATA "?A"
2030  DATA "$HOW MANY TIMES SHOULD YOU ALWAYS SPACE DOWN AFTER TYPING"
2040  DATA "THE COMPLIMENTARY CLOSE?"
2050  DATA " A.  ALWAYS 4 TIMES;  B.  ALWAYS 3 TIMES;"
2060  DATA " C.  ALWAYS 2 TIMES;  D.  ALWAYS 1 TIME;"
2070  DATA " E.  YOU DON'T HAVE TO SPACE DOWN BECAUSE THE COMPLIMENTARY"
2080  DATA "     CLOSE IS THE LAST ITEM TYPED IN A BUSINESS LETTER."
2095  DATA "?A"
2100  DATA "$END"
9999  END 
