1  IF  ERROR  THEN 1630
10  REM ***TO BE-DRILLS IN THE FORMS OF 'TO BE'***
20  REM      REVISED:TIMM BENTLEY  12/11/76;(2000F)
30  REM D2=NUMBER OF PREDICATE/ADJECTIVES DATA
40  D2=16
50  REM  D3=NUMBER OF PREDICATE/ADJECTIVES DATA
60  D3=40
70  REM  DATA FOR SUBJECT/PRESENT/PAST TENSE
80  DATA "I","AM","WAS","YOU","ARE","WERE","HE","IS","WAS"
90  DATA "SHE","IS","WAS","IT","IS","WAS","ONE","IS","WAS"
100  DATA "EACH","IS","WAS","EVERYTHING","IS","WAS","EVERYONE","IS","WAS"
110  DATA "WE","ARE","WERE","THEY","ARE","WERE","SOME","ARE","WERE"
120  DATA "FEW","ARE","WERE","ALL","ARE","WERE","SOMEBODY","IS","WAS"
130  DATA "SOMEONE","IS","WAS"
140  REM  DATA FOR PREDICATE/ADJECTIVES
150  DATA "KIND.","HAPPY.","GLAD.","SAD.","UPSET.","CALM.","UNHAPPY."
160  DATA "TIRED.","ENERGETIC.","LIKEABLE.","SOULFUL.","CRYING."
170  DATA "LAUGHING.","SMILING.","FROWNING.","LISTENING.","NOISY."
180  DATA "PEACEFUL.","LOVING.","CREATIVE.","POWERFUL.","GENEROUS."
190  DATA "DIGNIFIED.","AFFECTIONATE.","PROUD.","JEALOUS.","GREEDY."
200  DATA "ARROGANT.","OVERBEARING.","DOMANEERING.","ADAPTABLE."
210  DATA "GULLIBLE.","SENSITIVE.","EMOTIONAL.","PATIENT.","MOODY."
220  DATA "DOUBTFUL.","SUSPICIOUS.","THOUGHTFUL.","RUDE.","IMPATIENT."
230  DATA "DOGMATIC.","INTUITIVE.","ANXIOUS.","COMPASSIONATE."
240  DIM A$[15],B$[5],C$[15],E$[20],N$[36]
250  DIM Q$[40]
260  PRINT "DRILL IN FORMS OF 'TO BE'"
270  REM IDEA BY JUDY SOKOL
280  REM ADAPTED BY RANDY WONG  03/27/73
290  PRINT 
300  IF TIM(1)>11 THEN 330
310  PRINT "GOOD MORNING, ";
320  GOTO 370
330  IF TIM(1)>15 THEN 360
340  PRINT "GOOD AFTERNOON, ";
350  GOTO 370
360  PRINT "GOOD EVENING, ";
370  PRINT "NEED DIRECTIONS (YES/NO)";
380  INPUT E$
390  IF E$[1,1]="N" THEN 620
400  PRINT 
410  PRINT "DIRECTIONS:"'10
420  PRINT "THIS IS A DRILL ON PRESENT AND PAST TENSE FORMS"
430  PRINT "OF THE VERB 'TO BE'."'10
440  PRINT "THE OBJECT OF THE DRILL IS TO SEE HOW WELL YOU CAN USE"
450  PRINT "THESE COMMON VERB FORMS IN SIMPLE SENTENCES."'10
460  PRINT "THIS SKILL WILL PROVE VERY VALUABLE IN IMPROVING YOUR"
470  PRINT "ENGLISH GRAMMAR."'10
480  PRINT "EXAMPLE:   (PRESENT TENSE)"
490  PRINT "    EVERYTHING  ???  LOVELY";TAB(30);"*"
500  PRINT 
510  PRINT "YOU TYPE IN THE CORRECT PRESENT TENSE OF 'TO BE'"
520  PRINT "    EVERYTHING  ???  LOVELY";TAB(30);"*IS"
530  PRINT '10'10"    IF:           THE COMPUTER WILL TYPE:"
540  PRINT "    ---           -----------------------"
550  PRINT '10"  CORRECT   =     C"
560  PRINT '10"  WRONG     =     X (AND THE CORRECT ANSWER WILL BE TYPED)"
570  PRINT '10"  TIME OUT  =     T"
580  PRINT 
590  PRINT "REMEMBER TO HIT THE 'RETURN KEY'"
600  PRINT '10"YOU MAY GIVE YOURSELF UP TO TWENTY SECONDS PER PROBLEM."
610  PRINT '10"YOU ALSO HAVE A CHOICE BETWEEN PRESENT AND PAST TENSE DRILLS."
620  N$="XXX"
630  PRINT 
640  PRINT "TIME PER PROBLEM (1-20 SEC.)";
650  INPUT E1
660  IF ABS(E1-10)>10 THEN 640
670  PRINT 
680  PRINT "DO YOU WANT TO WORK WITH PAST OR PRESENT TENSE";
690  INPUT E$
700  P=1
710  IF E$[1,2]="PR" THEN 770
720  P=P+1
730  IF E$[1,2]="PA" THEN 770
740  PRINT "SORRY, SOMETHING WAS LOST IN THE TRANSLATION."
750  PRINT "DID YOU WANT A DRILL IN PAST OR PRESENT TENSE";
760  GOTO 690
770  PRINT 
780  IF N$ <> "XXX" THEN 1070
790  PRINT "DO YOU KNOW THESE VERB FORMS (YES/NO)";
800  INPUT Q$
810  IF Q$[1,1]="Y" THEN 1000
820  PRINT '10'10"                                'TO BE'"
830  PRINT "                             PRESENT TENSE"
840  PRINT "                             -------------"
850  PRINT "                "'25'25"SINGULAR                     PLURAL"
860  PRINT "                --------                     ------"
870  PRINT " 1ST PERSON   I         AM                WE         ARE"
880  PRINT " 2ND PERSON   HE,SHE    IS                THEY       ARE "
890  PRINT "              IT,ETC."
900  PRINT " 3RD PERSON   YOU       ARE               YOU        ARE"
910  PRINT '10'10"                                'TO BE'"
920  PRINT "                              PAST TENSE"
930  PRINT "                              -----------"
940  PRINT '10"                    SINGULAR               PLURAL"
950  PRINT "                    --------               ------"
960  PRINT " 1ST PERSON       I          WAS        WE        WERE"
970  PRINT " 2ND PERSON       HE,SHE     WAS        THEY      WERE"
980  PRINT "                  IT,ETC"
990  PRINT " 3RD PERSON       YOU        WERE       YOU       WERE"
1000  PRINT '10"VERY WELL...OH YES!! WHAT'S YOUR NAME";
1010  INPUT N$
1020  FOR I=1 TO LEN(N$)
1030  IF N$[I,I] <> " " THEN 1060
1040  N$=N$[1,I-1]
1050  GOTO 1070
1060  NEXT I
1070  PRINT "OK, "N$" HERE WE GO...."
1080  GOTO P OF 1090,1110
1090  PRINT "(PRESENT TENSE DRILL)"
1100  GOTO 1120
1110  PRINT "(PAST TENSE DRILL)"
1120  PRINT 
1130  PRINT "    PROBLEM";TAB(31);"YOUR ANSWER"
1140  ENTER #E
1150  DEF FNA()=1+INT(*RND(E))
1160  R=W=B=T=T1=T2=0
1170  FOR Z2=1 TO 25
1180  T1=T1+1
1190  E$="XXX"
1200  RESTORE 70
1210  FOR I=1 TO FNA(D2)
1220  READ A$,B$,C$
1230  NEXT I
1240  IF P=1 THEN 1260
1250  B$=C$
1260  RESTORE 140
1270  FOR I=1 TO FNA(D3)
1280  READ C$
1290  NEXT I
1300  PRINT "    "A$"  ???  "C$;TAB(29);" *";
1310  ENTER E1,E2,E$
1320  IF E$=B$ THEN 1410
1330  IF E2<0 THEN 1370
1340  PRINT '13"X";TAB(38);A$" ";B$" ";C$
1350  W=W+1
1360  GOTO 1430
1370  PRINT '13"T";TAB(38);A$" ";B$" ";C$
1380  T2=T2+1
1390  E2=E1
1400  GOTO 1430
1410  PRINT '13"C"
1420  R=R+1
1430  T=T+E2
1440  NEXT Z2
1450  PRINT 
1460  PRINT "RESULTS..."
1470  PRINT "BATTING FOR THE HOME TEAM: "N$
1480  PRINT "TIMES AT BAT:"T1
1490  PRINT "HITS:"R
1500  PRINT "MISSES:"W
1510  PRINT "FOULS:"T2
1520  O=INT(R/25*100)
1530  PRINT  USING 1540;O
1540  IMAGE "BATTING AVERAGE:",DDD.D,"% CORRECT"
1550  PRINT 
1560  PRINT "WANT ANOTHER INNING (YES/NO)";
1570  INPUT E$
1580  IF E$[1,1]="Y" THEN 630
1590  PRINT 
1600  PRINT "GOODBYE, "N$
1610  PRINT 
1620  PRINT 
1630  CHAIN R,"*HELP"
1640  SYSTEM X,"BYE"
1650  END 
