10  REM:  "TAX" (REV.#1), WRITTEN 2/4/74 BY PETER BARNES
20  REM:  PRODUCED AT THE EDP RESOURCE CENTER, SAN FRANCISCO, CALIF.
30  REM:  DEBUGGED BY RONALD NG 5/20/76
40  REM:  'WHAT ITEMS ARE TAXABLE?'
50  REM
55  IF  ERROR  THEN 550
60  DIM A$[72],B$[72]
70  IF TIM(1)>11 THEN 100
80  PRINT "GOOD MORNING, ";
90  GOTO 140
100  IF TIM(1)>15 THEN 130
110  PRINT "GOOD AFTERNOON, ";
120  GOTO 140
130  PRINT "GOOD EVENING, ";
140  PRINT "NEED INSTRUCTIONS?";
150  ENTER 5,R,A$
160  REM
170  IF A$[1,1] <> "Y" THEN 230
180  PRINT 
190  PRINT "     SOME ITEMS YOU MUST PAY TAX ON --- SOME, YOU DON'T."
200  PRINT "GENERALLY, IF CAN'T EAT OR DRINK IT, THEN IT IS TAXABLE."
210  PRINT "IF YOU DON'T HAVE TO PAY TAX, JUST HIT THE RETURN KEY."
220  PRINT "IF YOU DO, TYPE 'T'."
230  PRINT 
240  X=C=N=O=0
250  IF TYP(0)=3 THEN 290
260  READ A$
270  N=N+1
280  GOTO 250
290  FOR I=1 TO 10
300  RESTORE 
310  FOR J=1 TO INT(N*RND(0))+1
320  READ A$
330  NEXT J
340  PRINT "   ";A$[2];"  ";
350  ENTER 30,R,B$
360  IF R<0 THEN 410
370  IF A$[1,1]=B$[1,1] THEN 440
380  PRINT '13"X"
390  X=X+1
400  GOTO 460
410  PRINT '13"O"
420  O=O+1
430  GOTO 460
440  PRINT '13"C"
450  C=C+1
460  NEXT I
470  PRINT 
480  PRINT "YOU GOT  "C"RIGHT OUT OF"C+X
490  PRINT 
500  PRINT "TRY AGAIN";
510  ENTER 5,R,A$
520  IF A$[1,1]="Y" THEN 230
530  PRINT 
540  PRINT "BETTER LUCK NEXT TIME."
550  CHAIN R,"*HELP"
555  SYSTEM X,"BYE"
560  DATA "TAMMONIA"," ASPARAGUS"," ARTICHOKES"
570  DATA " BABY CEREAL"," BABY FOOD"," BABY FORMULA"
580  DATA " BAKING CHIPS"," CANNED BEANS"," DRIED BEANS","TBEER"
590  DATA " BEETS","TBIRD FOOD","TBLEACHES","TBLUING"," BOUILLON CUBES"
600  DATA "TCHARCOAL"," BREAD","TBUBBLE BATH"," CAKE MIXES"
610  DATA "TCANDY","TCANNING SUPPLIES","TCAR POLISH"," CARROTS"
620  DATA "TCAT FOODS"," CATSUP"," CEREAL"
630  DATA " CHILI SAUCE"," CHINESE FOOD"," COCOA","TCIGARETTES"
640  DATA "TCIGARS","TCLEANING FLUIDS","TCLEANSERS","TCLOTHES PINS"
650  DATA " COCKTAIL SAUCE"," COCONUT"," COFFEE"," COOKIES"," CORN"
660  DATA " CORN MEAL"," CRACKERS"," CROUTONS","TDEODORIZERS"
670  DATA "TDETERGENT"," DIETETIC FOODS","TDISPOSABLE DIAPERS"
680  DATA "TDOG FOOD","TDRAIN OPENERS"," SALAD DRESSING"
690  DATA "TDRINKING STRAWS"," EXTRACTS","TFACIAL TISSUE"
700  DATA " FISH","TFLOOR POLISH"," FLOUR"," FOOD COLORS"
710  DATA " FROSTINGS"," CANNED FRUIT"," DRIED FRUIT"," FRUIT DRINKS"
720  DATA " GELATIN","TGLASS CLEANER"," GRAVY","TGUM"," HONEY"
730  DATA " HORSERADISH"," HOT SAUCES"," ICE CREAM"," ICE CREAM CONES"
740  DATA " ICE CREAM TOPPINGS","TINSECTICIDES"," JAMS/JELLIES"
750  DATA " FRUIT JUICES"," VEGETABLE JUICES"," KOOL-AID"
760  DATA "TLIGHTER FLUID","TLYE","TLIQUID CLEANERS"," MALT"
770  DATA " MALTED MILK"," MARSHMALLOWS"," MARSHMALLOW CREME"
780  DATA "TMATCHES"," MAYONNAISE"," CANNED MEAT"," MEAT SAUCES"
790  DATA " MEAT TENDERIZERS","TMETAL POLISH"," MEXICAN FOOD"
800  DATA " MILK PRODUCTS"," MINCEMEAT"," MINTS"
810  DATA "TMOTOR OIL"," MUSHROOMS"," MUSTARD","TNAPKIN HOLDERS"
820  DATA " NECTAR"," NUTS"," COOKING OIL"," OLIVES"," OLIVE OIL"
830  DATA "TOVEN CLEANER","TPAPER BAGS"," PASTA"," PEANUT BUTTER"
840  DATA " PICKLES"," PIMENTOS","TPINE OIL"," PIZZA MIX"," POP CORN"
850  DATA " POP TARTS"," POTATOES"," PREPARED DINNERS"," PREPARED FOODS"
860  DATA " PUDDINGS"," RICE"," RICE MIXES"," RYE KRISP"," CANNED SALADS"
870  DATA " SALAD DRESSINGS"," SALT","TSCOURING PADS","TSHOE POLISH"
880  DATA " SHORTENING","TSOAP"," SOUPS"," SPAGHETTI"
890  DATA " SPICES","TSPONGES","TSTARCH"," STUFFING"," SUGAR"
900  DATA " SYRUPS"," TAPICOA"," TEA","TTOBACCO"
910  DATA "TTOILET TISSUE"," TOMATOES","TTOOTH PICKS"," TOPPINGS"
920  DATA "TTOWELS"," CANNED VEGETABLES"," VINEGAR"," DISTILLED WATER"
930  DATA "TWATER SOFTENER","TWAX PAPER"," YEAST"," MILK"
940  DATA " BREAD","TWINE","TBOOKS"
950  END 
