10  REM ****  HP TIME-SHARED BASIC PROGRAM LIBRARY  ********************
20  REM
30  REM               NEWTN2:  NEWTON'S 2ND LAW
40  REM
50  REM               36316 (A833)  REV A -- 10/71
60  REM
70  REM ****  CONTRIBUTED PROGRAM  *************************************
80  REM A.C. CAGGIANO; PATCHOGUE H.S.; DEC.4,68 
90  REM NEWTN2-COPYRIGHT 1970, POLYTECHNIC INSTITUTE OF BROOKLYN
100  REM  REVISED BY C.LOSIK  8-18-70 
110  REM  X AND Y COORDINATES ARE USED WITH 1-TYPE VARIABLES IN 
120  REM  X DIRECTION  AND 2-TYPE VARIABLES IN THE Y DIRECTION
130  REM  IT IS BEST TO CHECK THE EQUATIONS BELOW 
140  REM THIS IS A PHYSICS PROGRAM WHICH ATTEMPTS TO DEVELOP A 
150  REM    'FEEL' FO THE F=MA RELATIONSHIP
155  IF  ERROR  THEN 1090
160  LET T=V1=0
170  PRINT "HINT: GRAPH PAPER IS HELPFUL IN RUNNING THIS PROGRAM."
180  LET X=0
190  LET Y=0
200  LET V2=0
210  PRINT 
220  LET Q=0
230  PRINT " "," ";"F'  MA  SPEED,..."
240  PRINT " "," ";"-----------------"
250  PRINT 
260  PRINT "YOU'RE TRYING TO ESCAPE FROM DEVIL'S ISLAND ON A SMALL BOAT."
270  PRINT "DEVIL'S ISLAND IS LOCATED AT COORDINATES (0,0)."
280  PRINT "TO SUCCEED, YOU MUST REACH A CHANNEL 50 METERS WIDE AND"
290  PRINT "10000 METERS DUE EAST, AT ABOUT (10000,0)."
300  PRINT 
310  PRINT "IN ADDITION, YOU MUST GET THERE IN FIVE MINUTES OR LESS OR"
320  PRINT "SUFFER RECAPTURE ---  (HEH,HEH,HEH--)"
330  PRINT 
340  PRINT "WHAT DO YOU WEIGH (IN POUNDS)";
350  INPUT W
360  LET P1=RND(X)*8
370  LET P=20*INT(P1+.5)
380  LET M=INT(W/2.2+100.5)
390  LET T1=0
400  LET T=30
410  PRINT 
420  PRINT "YOUR SITUATION IS AS FOLLOWS:"
430  PRINT 
440  PRINT "THE WIND IS BLOWING FROM THE NORTHEAST (45 DEGREES) EXERTING"
450  PRINT "A FORCE OF"P"NEWTONS ON YOUR BOAT. YOU MAY PADDLE WITH"
460  PRINT "ANY FORCE IN THE EASTWARD DIRECTION (ZERO DEGREES IS EAST)"
470  PRINT "TO ACCELERATE YOUR BOAT ACROSS THE BAY AND THUS"
480  PRINT "REACH THE OPPOSITE SHORE (AND FREEDOM)."
490  PRINT "(NOTE: THE MASS OF THE BOAT WITH YOU ABOARD IS"M"KILOGRAMS)."
500  PRINT 
510  PRINT "WITH WHAT FORCE (IN NEWTONS) AND DIRECTION (IN DEGREES) WILL"
520  PRINT "YOU PADDLE";
530  INPUT F,A
540  IF ABS(F-100)<100 THEN 620
550  LET Q=Q+1
560  IF Q>2 THEN 1090
570  IF Q>1 THEN 600
580  PRINT "YOU MUST THINK YOU'RE SUPERMAN. BE PRACTICAL."
590  GOTO 500
600  PRINT "IF YOU'RE THAT STRONG, JUMP THE CHANNEL---"
610  GOTO 500
620  IF ABS(A)<90 THEN 650
630  PRINT "YOU'RE HEADING THE WRONG WAY. TRY AGAIN."
640  GOTO 500
650  LET A0=.0175*A
660  LET A1=(F*COS(A0)-.717*P)/M
670  LET A2=(F*SIN(A0)-.717*P)/M
680  LET X=A1*T*T/2+V1*T+X
690  LET Y=A2*T*T/2+V2*T+Y
700  LET V1=A1*T+V1
710  LET V2=A2*T+V2
720  LET T1=T1+.5
730  PRINT "T="T1,"X="INT(X+.5),"Y="INT(Y+.5),"V(X)="INT(V1+.5),
740  PRINT "V(Y)="INT(V2+.5)
750  IF X>0 THEN 780
760  PRINT "NO HELP THAT WAY. YOU'RE GOING BACKWARDS."
770  GOTO 500
780  IF X>10000 THEN 860
790  IF T1>5 THEN 1010
800  PRINT 
810  PRINT "WANT TO CHANGE FORCE OR DIRECTION (1=YES, 0=NO) : ";
820  INPUT R
830  IF R=1 THEN 500
840  IF R=0 THEN 660
850  GOTO 810
860  PRINT "YOU HAVE REACHED THE OPPOSITE SHORE,"
870  IF ABS(Y)<200 THEN 920
880  PRINT "BUT ARE"INT(Y+.5)"METERS OFF COURSE."
890  PRINT "ALL THAT WORK FOR NOTHING!"
900  PRINT "YOU'RE LOST IN THE SWAMPS FOREVER;  GOODBYE."
910  GOTO 1070
920  IF ABS(Y)<100 THEN 950
930  PRINT "AND YOU MIGHT MAKE IT, THOUGH YOU ARE OFF COURSE."
940  GOTO 1070
950  IF ABS(Y)<25 THEN 980
960  PRINT "BUT YOU'RE CLOSE ENOUGH TO GET AWAY.  GOOD LUCK!"
970  GOTO 1070
980  PRINT "AND HAVE REACHED THE CHANNEL."
990  PRINT "HOW SWEET SUCCESS IS !!!"
1000  GOTO 1070
1010  PRINT "YOUR TIME IS UP."
1020  IF X <= 10000 THEN 860
1030  PRINT "YOU HAVE NOT REACHED THE CHANNEL, AND ARE ONLY"
1040  PRINT INT(SQR(X*X+Y*Y)+.5)"METERS FROM WHERE YOU STARTED."
1050  PRINT "YOU MUST SUFFER RECAPTURE."
1060  PRINT "SORRY, CHUM, BUT THAT'S PHYSICS."
1070  PRINT 
1080  PRINT "SEE IF YOU CAN IMPROVE YOUR ABILITY LATER."
1090  CHAIN R,"*HELP"
1100  SYSTEM X,"BYE"
1110  END 
