1  REM  ****   HP BASIC PROGRAM LIBRARY   *****************************
2  REM  
3  REM         METRIC:    CONVERTS ENGLISH TO METRIC, METRIC TO ENGLISH
4  REM   
5  REM         36635 REV   A    6/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM   ***********************************
8  REM  <<REVISED BY RODERIC LANCE HOM>>
9  REM  400  MANSELL STREET  SAN FRAN  CALIF (415) 239-6460
10  DATA 25.4,.3048,.9144,1.609,6.4516,.0929,.836,.405,16.387
20  DATA .0283,.765,.946,3.784,28.35,.454,4.448,6.895,.746,1.055
30  DIM A$[72],B$[72],C$[72]
35  IF  ERROR  THEN 560
40  PRINT LIN(1)"INSTRUCTIONS";
50  INPUT A$
60  IF A$[1,1]="N" THEN 260
70  DATA "INCHES","MILLIMETERS","FEET","METERS","YARDS","METERS","MILES"
80  DATA "KILOMETERS","SQUARE INCHES","SQUARE CENTIMETERS","SQUARE FEET"
90  DATA "SQUARE METERS","SQUARE YARDS","SQUARE METERS","ACRES","HECTARES"
100  DATA "CUBIC INCHES","MILLILITERS","CUBIC FEET","CUBIC METERS"
110  DATA "CUBIC YARDS","CUBIC METERS","QUARTS","LITERS","GALLONS"
120  DATA "LITERS","OUNCES","GRAMS","POUNDS (MASS)","KILOGRAMS"
130  DATA "POUNDS (FORCE)","NEWTONS","P.S.I.","KILOPASCALS"
140  DATA "HORSEPOWER","KILOWATTS","RTU","KILOJOULE"
150  PRINT LIN(1)"+ TO CONVERT FROM"TAB(35)"TO"
160  PRINT "- TO CONVERT TO"TAB(35)"FROM"
170  PRINT 
180  RESTORE 70
190  FOR A=1 TO 19
200  READ A$,B$
210  PRINT  USING 220;A
220  IMAGE  #,DDXX9X
230  PRINT A$;TAB(35);B$
240  NEXT A
250  PRINT "20           END THE PROGRAM"
260  PRINT LIN(1)"YOUR CHOICE";
270  INPUT A
280  IF A=20 OR A=-20 THEN 560
290  IF A=0 OR A>19 OR A<-19 THEN 260
300  RESTORE 10
310  FOR B=1 TO ABS(A)
320  READ C
330  NEXT B
340  RESTORE 70
350  FOR B=1 TO ABS(A)
360  READ A$,B$
370  NEXT B
380  IF A<0 THEN 490
390  PRINT LIN(1)"ENTER THE VALUE IN "A$" ";
400  INPUT D
410  E=D*C
420  PRINT 
430  PRINT  USING 440;D
440  IMAGE  #,6D.4DX
450  PRINT A$" = ";
460  PRINT  USING 440;E
470  PRINT B$
480  GOTO 260
490  C$=A$
500  A$=B$
510  B$=C$
520  PRINT LIN(1)"ENTER THE VALUE IN "A$" ";
530  INPUT D
540  E=D/C
550  GOTO 420
560  CHAIN R,"*HELP"
570  SYSTEM X,"BYE"
580  END 
