5  IF  ERROR  THEN 620
10  Z=15
20  DIM X$[72],S$[72],N$[72],M$[72]
21  IF TIM(1)>11 THEN 24
22  PRINT "GOOD MORNING, ";
23  GOTO 30
24  IF TIM(1)>15 THEN 27
25  PRINT "GOOD AFTERNOON, ";
26  GOTO 30
27  PRINT "GOOD EVENING, ";
30  PRINT "WHAT'S YOUR NAME:";
40  ENTER Z,U,M$
50  PRINT 
60  PRINT "TYPE IN AN EQUIVALENT FRACTION, "M$
70  A=INT(9*RND(1)+1)
80  B=INT(9*RND(1)+1)
90  R=0
100  IF A <= B THEN 140
110  T=A
120  A=B
130  B=T
140  GOSUB 430
150  PRINT "      ";
160  X$="RESET"
170  ENTER Z,U,X$
180  IF X$="STOP" THEN 600
190  L=LEN(X$)
200  FOR I=1 TO L
210  IF X$[I,I]="/" THEN 250
220  NEXT I
230  PRINT "         WHAT?"
240  GOTO 150
250  REM
260  N$=X$[1,I-1]
270  GOSUB 500
280  C=N
290  N$=X$[I+1,L]
300  GOSUB 500
310  D=N
320  IF A*D#B*C THEN 390
330  IF D#B THEN 360
340  PRINT "            CHICKEN"
350  GOTO 150
360  PRINT "C"
370  R=R+1
380  GOTO 400
390  PRINT "X"
400  IF R<4 THEN 150
410  PRINT "            GREAT, HERE'S ANOTHER:"
420  GOTO 70
430  REM SUBPROGRAM TO CONVERT NUMBER TO STRING AND PRINT
440  S$="0123456789"
450  A$=S$[A+1,A+1]
460  B$=S$[B+1,B+1]
470  PRINT 
480  PRINT A$;"/";B$
490  RETURN 
500  REM SUBPROGRAM TO CONVERT STRING TO TWO NUMBERS
510  N=0
520  L1=LEN(N$)
530  FOR K=1 TO L1
540  FOR P=1 TO 10
550  IF N$[K,K]=S$[P,P] THEN 570
560  NEXT P
570  N=(P-1)+N*10
580  NEXT K
590  RETURN 
600  PRINT 
610  PRINT "OK, SEE YOU LATER, "M$
620  CHAIN R,"*HELP"
630  SYSTEM X,"BYE"
640  END 
