1000  REM   FACT, PROGRAMED BY ALEX ATHAS, EDP RESOURCE CENTER
1010  REM   400 MANSELL ST. SAN FRANCISCO (HP-2000F)
1020  REM
1030  DIM B$[72],C$[7],D$[4]
1040  REM
1050  REM   A$= ANSWER ("T","F" OR "N").
1060  REM   B$= SOLUTION (IF HUMANOID GIVES WRONG ANSWER 2 TIMES
1070  REM                 B$ WILL BE PRINTED).
1080  REM   C$= FACT (FACT THAT IS PUT TO HUMANOID).
1090  REM   D$= CONCLUSION (CONCLUSION THAT TESTS HUMANOID).
1100  REM   E$= HUMANOIDS ANSWER ("T","F" OR "N").
1110  REM
1115  IF  ERROR  THEN 1800
1120  PRINT "THIS PROGRAM WILL TEST YOU ON MATHEMATICAL SYMBOLS."
1130  PRINT '10"ANSWER QUESTIONS WITH:"
1140  PRINT '10"   T, IF CONCLUSION IS TRUE."
1150  PRINT "   F, IF CONCLUSION IS FALSE."
1160  PRINT "   N, IF CONCLUSION IS NOT DETERMINABLE."
1170  PRINT "=========="'10
1180  LET N=1
1190  LET W=0
1200  READ A$,B$,C$,D$
1210  FOR I=1 TO 2
1220  PRINT "#"N;
1230  PRINT "FACT: "C$",   CONCLUSION IS "D$
1240  PRINT "CONCLUSION IS (T,F OR N)";
1250  INPUT E$[1,1]
1260  IF E$=A$ THEN 1340
1270  IF I=2 THEN 1300
1280  PRINT "WRONG, TRY AGAIN."'13'10
1290  NEXT I
1300  PRINT '10"WRONG, THE ANSWER IS "A$", BECAUSE"'13'10"IF "B$'10'10
1310  IF N=10 THEN 1370
1320  LET N=N+1
1330  GOTO 1200
1340  PRINT "RIGHT."'13'10
1350  LET W=W+1
1360  GOTO 1310
1370  PRINT '10'10"IN THIS TEST YOU GAVE"W"RIGHT ANSWERS OUT OF 10, WHICH IS"W*10"%."
1380  PRINT '10'10'10
1390  GOTO 1800
1400  REM ==[#1]==
1410  DATA "F"
1420  DATA "X=Y=Z, THE CONCLUSION IS TRUE,"'15'14"BUT IF Y=4 AND Z=2 IT'S FALSE."
1430  DATA "X=Y>=Z","Z>=X"
1440  REM ==[#2]==
1450  DATA "N"
1460  DATA "X=2, Y=4 AND Z=3, IT'S TRUE,"'15'14"IF X=2,Y=4, AND Z=1 IT'S FALSE."
1470  DATA "X<Y>=Z","Z<X"
1480  REM ==[#3]==
1490  DATA "T"
1500  DATA "Y IS ANY VALUE, Z IS GREATER THAN Y, BUT X IS NOT."
1510  DATA "X<=Y<Z","Z>X"
1520  REM ==[#4]==
1530  DATA "N"
1540  DATA "X=Y=4 AND Z=2 IT'S TRUE,"'15'14"IT'S FALSE IF X=Y=Z."
1550  DATA "X=Y>=Z","Z<>X"
1560  REM ==[#5]==
1570  DATA "N"
1580  DATA "X=2,Y=4 AND Z=3 IT'S TRUE,"'15'14"THE CONCLUSION IS FALSE IF X=3,Y=4,Z=2."
1590  DATA "X<=Y>Z","Z>=X"
1600  REM ==[#6]==
1610  DATA "T"
1620  DATA "Z MUST BE <Y, THEN X CANNOT BE."
1630  DATA "X>=Y>Z","Z<X"
1640  REM ==[#7]==
1650  DATA "F"
1660  DATA "Z MUST ALWAYS BE <X, THE CONCLUSION IS FALSE"
1670  DATA "X>Y>=Z","Z<=X"
1680  REM ==[#8]==
1690  DATA "N"
1700  DATA "X=Y=Z IT'S TRUE, BUT IF X=4,Y=3 AND Z=2 THE CONCLUSION IS FALSE."
1710  DATA "X>=Y>=Z","Z=X"
1720  REM ==[#9]==
1730  DATA "T"
1740  DATA "Y IS LESS THAN X, AND Z=Y THEN IT'S TRUE."
1750  DATA "X>Y=Z","Z<X"
1760  REM ==[#10]==
1770  DATA "N"
1780  DATA "X=2,Y=4 AND Z=3 IT'S TRUE"'15'14"BUT IT'S FALSE IF X=3,Y=4 AND Z=2."
1790  DATA "X>=Y<=Z","Z>X"
1800  CHAIN R,"*HELP"
1810  SYSTEM X,"BYE"
1820  END 
