1  IF  ERROR  THEN 455
10  REM  AVOGA:  COMPUTES AVOGADRO'S NUMBER, BY THE HUNTINGTON COMPUTER
20  REM  PROJECT.  REVISED BY MR. WILLIAM CHAR, OCTOBER 8, 1974.
30  REM
40  DIM A$[3]
50  REM G=PROTON MASS, H=NEUTRON MASS
60  G=1.602E-19/95810.
70  H=1.0086*G/1.0072
80  IF TIM(1)>11 THEN 110
90  PRINT "GOOD MORNING, ";
100  GOTO 150
110  IF TIM(1)>15 THEN 140
120  PRINT "GOOD AFTERNOON, ";
130  GOTO 150
140  PRINT "GOOD EVENING, ";
150  PRINT "NEED INSTRUCTIONS";
160  INPUT A$
170  IF A$[1,1]="N" THEN 240
180  PRINT 
190  PRINT "     THIS PROGRAM WILL CALCULATE AVOGADRO'S NUMBER BY"
200  PRINT "USING ANY PURE GASEOUS ELEMENT OR BINARY COMPOUND.  THIS"
210  PRINT "VALUE WILL BE CALCULATED BY USING THE MASS IN GRAMS OF THE"
220  PRINT "NUETRON WHICH IS"H"AND THE MASS OF THE PROTON WHICH"
230  PRINT "IS"G
240  MAT N=ZER
250  PRINT "====="
260  PRINT 
270  PRINT "FIRST ELEMENT:"
280  I=1
290  GOSUB 470
300  PRINT "SECOND ELEMENT:"
310  PRINT "SECOND ELEMENT"
320  I=4
330  GOSUB 470
340  J=N[3]*N[2]+N[6]*N[5]
350  K=(N[3]*N[1]+N[6]*N[4])*G+(N[3]*(N[2]-N[1])+N[6]*(N[5]-N[4]))*H
360  PRINT 
370  PRINT "THE NUMBER OF PARTICLES PER MOLE OF THIS GAS IS"J/K
380  PRINT 
390  PRINT "ANOTHER RUN";
400  INPUT A$
410  IF A$[1,1]="Y" THEN 240
420  PRINT 
430  PRINT "     CAN YOU EXPLAIN WHY THESE VALUES ARE DIFFERENT FROM"
440  PRINT "THE VALUE 6.02E+23?  HINT:  WHAT IS 'FISHY' ABOUT THE"
450  PRINT "VALUE FOR THE ATOMIC WEIGHT USED?"
455  CHAIN R,"*HELP"
457  SYSTEM X,"BYE"
460  STOP 
470  PRINT "  NUMBER OF ATOMS IN FORMULA";
480  INPUT N[I+2]
490  IF N[I+2]=0 THEN 540
500  PRINT "   ATOMIC NUMBER";
510  INPUT N[I]
520  PRINT "   ATOMIC WEIGHT";
530  INPUT N[I+1]
540  RETURN 
550  END 
