10  REM COPYRIGHT DAVID SHAYER 1978
20  REM NO REPRODUCTION OF ANY SORT WITHOUT EXPRESSED PERMISSION
30  REM **********PROGRAM DIRECTORY**********
40  REM 400 -1000 INSTRUCTIONS
50  REM 1000-1500 INITIALIZATION
60  REM 1500-2000 TIE FIGHTER ADDITION AND MOVEMENT
70  REM 2000-2500 COMMAND INPUT
80  REM 2500-3000 FIRE CONTROL
90  REM 3000-3500 SHIELD CONTROL
100  REM 3500-4000 MANEUVER CONTROL
110  REM 4000-4500 STAR SCAN
120  REM 4500-5000 STATUS REPORT
130  REM 5000-5500 ENEMY FIRING ROUTINE
140  REM 5500-6000 END
150  DATA 2,19,2,20,2,21,2,22,2,23,2,24,3,18,3,19,3,20,3,21,3,22,3,23,3,24,3,25
160  DATA 4,17,4,18,4,19,4,20,4,21,4,22,4,23,4,24,4,25,4,26
170  DATA 5,16,5,17,5,18,5,19,5,20,5,21,5,22,5,23,5,24,5,25,5,26,5,27
180  DATA 6,16,6,17,6,18,6,19,6,20,6,21,6,22,6,23,6,24,6,25,6,26,6,27
190  DATA 7,16,7,17,7,18,7,19,7,20,7,21,7,22,7,23,7,24,7,25,7,26,7,27
200  DATA 8,17,8,18,8,19,8,20,8,21,8,22,8,23,8,24,8,25,8,26
210  DATA 9,18,9,19,9,20,9,21,9,22,9,23,9,24,9,25
220  DATA 10,19,10,20,10,21,10,22,10,23,10,24
230  PRINT LIN(6)
260  PRINT "                          STAR  WARS  "
270  PRINT LIN(4)
280  DIM B$[10]
290  PRINT "DO YOU WANT INSTRUCTOINS";
300  INPUT B$
310  IF B$="N" THEN 1000
320  IF B$="NO" THEN 1000
330  IF B$="Y" THEN 400
340  IF B$="YES" THEN 400
350  GOTO 290
400  PRINT LIN(2)
405  PRINT "              WELCOME TO THE GAME OF STAR WARS "
410  PRINT 
415  PRINT "THE OBJECT OF STAR WARS IS TO DESTROY THE DEATH STAR"
420  PRINT "YOU CAN SHOOT AT THE DEATH STAR, BUT IT'S GONNA SHOOT BACK!"
425  PRINT "THE DEATH STAR ALSO SENDS OUT TIE FIGHTERS, WHICH WILL "
430  PRINT "ATTACK YOU. BUT THEY ARE SUICIDAL, AND THEY WILL TRY TO "
435  PRINT "RAM YOU. IF ONE OF THEM RAMS YOU, IT WILL DESTROY YOU. "
440  PRINT LIN(3)
445  PRINT "COMMAND 1 (FIRE CONTROL) "
450  PRINT TAB(6)"YOU HAVE PROTON GUNS, WHICH CAN DESTROY A TIE FIGHTER"
455  PRINT TAB(6)"WITH ONE WELL PLACED SHOT. HINT: TIE FIGHTERS MOVE TOWARDS"
460  PRINT TAB(6)"YOU, AND SO YOU MUST AIM FOR WERE THEY ARE GOING TO BE. "
465  PRINT TAB(6)"YOUR GUNS CAN ALSO DESTROY THE DEATH STAR, BUT ONLY IN "
470  PRINT TAB(6)"SMALL PEICES. YOU MUST SHOOT AT THE DEATH STAR UNTIL "
475  PRINT TAB(6)"ALL THE PIECES ARE GONE. YOU ENTER THE COORDINATES HORIZONTAL "
480  PRINT TAB(6)"(1-10) FIRST, THEN A COMMA, THEN VERTICAL(1-30)."
485  PRINT 
490  PRINT "COMMAND 2 (SHIELD CONTROL) "
495  PRINT TAB(6)"WHEN YOU START, PUT UP YOUR SHIELDS IMMEDIATLY, OR THE "
500  PRINT TAB(6)"TIE FIGHTERS WILL DESTROY YOU. REPEATED ATTACKS WILL DRAIN "
505  PRINT TAB(6)"YOUR SHIELDS, SO YOU MUST ADD ENERGY TO THEM OCCASIONALY. "
510  PRINT TAB(6)"THE SHIELDS WON'T PROTECT YOU FROM BEING RAMMED BY "
515  PRINT TAB(6)"TIE FIGHTERS. YOU WILL BE NOTIFIED WHEN YOUR SHIELDS BECOME "
520  PRINT TAB(6)"LOW, BUT YOU MUST RESUPPLY THEM IMMEDIATLY. "
525  PRINT 
530  PRINT "COMMAND 3 (MANUEVER CONTROL) "
535  PRINT TAB(6)"YOU ENTER YOUR COORDINATES THE SAME WAY YOU ENTER FIRING"
540  PRINT TAB(6)"COORDINATES. ENTER THE HORIZONTAL(1-10), THEN A COMMA, "
545  PRINT TAB(6)"THEN THE VERTICAL(1-30). DON'T WORRY ABOUT CRASHING INTO THINGS, "
550  PRINT TAB(6)"YOUR IN HYPERSPACE WHILE YOUR'E MOVING, BUT WHEN YOU COME"
555  PRINT TAB(6)"OUT, YOU HAD BETTER BE IN OPEN SPACE."
560  PRINT 
565  PRINT "COMMAND 4 (STAR SCAN) "
570  PRINT TAB(6)"YOUR SCANNERS WILL PRINT OUT A PICTURE FOR YOU. THE BIG BALL"
575  PRINT TAB(6)"IS THE DEATH STAR. THE '+' REPRESENT TIE FIGHTERS, AND YOU"
580  PRINT TAB(6)"ARE THE 'M' (MULENIUM FALCON). AS YOU DESTROY THE DEATH STAR,"
585  PRINT TAB(6)"LESS AND LESS WILL BE SHOWN ON THE SCAN. THE POSITION OF THE"
590  PRINT TAB(6)"TIE FIGHTER IS WHERE THEY WERE WHEN THE SCAN WAS TAKEN. THEY"
595  PRINT TAB(6)"WILL HAVE PROABLY MOVED TOWARDS YOU BY THE TIME YOU SHOOT AT"
600  PRINT TAB(6)"THEM, ONE SPACE FOR EVERY TURN. "
605  PRINT 
610  PRINT "COMMAND 5 (STATUS REPORT) "
615  PRINT TAB(6)"A STATUS REPORT WILL TELL YOU HOW MUCH ENERGY YOU HAVE, HOW MUCH"
620  PRINT TAB(6)"IS IN YOUR SHIELDS, HOW MANY PIECES OF THE DEATH STAR ARE LEFT,"
625  PRINT TAB(6)"HOW MANY TIE FIGHTERS THERE ARE, HOW MANY TURNS YOU'VE USED,"
630  PRINT TAB(6)"HOW MANY DIRECT HITS YOU'VE SCORED(AGAINST TIE FIGHTERS AND"
635  PRINT TAB(6)"THE DEATH STAR), AND GIVE YOU YOUR PRESENT EFFICIENCY"
640  PRINT TAB(6)"RATING. IT USES ONE TURN."
645  PRINT LIN(2)
650  PRINT TAB(6)"HINT:PUT ALL YOUR ENERGY INTO YOUR SHIELDS WHEN YOU START "
655  PRINT "                     G O O D   L U C K ! "
1000  PRINT LIN(2)
1005  PRINT "HOW GOOD ARE YOU:"
1010  PRINT "1-BEGINNER"
1015  PRINT "2-PRETTY GOOD"
1020  PRINT "3-EXPERT"
1025  INPUT A
1030  GOTO A OF 1045,1070,1085
1035  IF R>10 THEN 2000
1040  GOTO 1000
1045  A3=700
1050  A4=1
1055  PRINT "A NEW GUY, HUH?"
1060  PRINT "WELL WELCOME TO THE GAME OF STAR WARS AND GOOD LUCK!!"
1065  GOTO 1110
1070  A3=800
1075  A4=2
1080  GOTO 1110
1085  A3=1100
1090  A4=3
1095  PRINT "SO YOU CALL YOUR SELF AN EXPERT HUH?"
1100  PRINT "WE'LL SEE."
1105  PRINT "(IF YOU CHICKEN OUT, THE 'BREAK' KEY IS ON THE RIGHT SIDE OF THE KEYBOARD)"
1110  PRINT 
1115  S=0
1120  E=5000-A3
1125  S=0
1130  DIM Z[10,30]
1135  MAT Z=ZER
1140  DIM A$[99]
1145  T=84
1150  FOR X=1 TO 84
1155  READ Q,W
1160  Z[Q,W]=1
1165  NEXT X
1170  Z[3,5]=3
1175  T1=3
1180  T2=5
1185  N=0
1190  D=0
1195  H=0
1200  REM E--ENERGY
1205  REM S--SHIELDS
1210  REM Z--ARRAY
1215  REM A$-SCAN INTERMEDIATE
1220  REM T--REPRESENTS THE NUMBER OF PIECES OF THE DEATH STAR LEFT
1225  REM T1-HORIZONTAL(1-10)COORDINATES OF MULENIUM FALCON
1230  REM T2-VERTICAL(10-30)COORDINATES OF MULENIUM FALCON
1235  REM N--NUMBER OF TIE FIGHTERS IN GRID
1240  REM D--NUMBER OF TURNS USED
1245  REM H--NUMBER OF DIRECT HITS
1250  REM A3-SHEILD ADDITION
1255  REM A4-MAXIMUM NUMBER OF TIE SHIPS TO BE LET ON THE GRID
1260  REM A,B,Q,W--DUMMY VARIABLES
1265  REM 0-SPACE
1270  REM 1-DEATH STAR
1275  REM 2-TIE SHIP
1280  REM 3-MULENIUM FALCON
1285  PRINT LIN(8)
1290  PRINT "             A LONG TIME AGO, IN A GALAXY FAR, FAR AWAY..."
1295  PRINT LIN(5)
1300  PRINT "                        S T A R   W A R S "
1305  PRINT LIN(4)
1500  E=E+A3
1510  IF S>900 THEN 1530
1520  PRINT "YOUR SHIELDS ARE DANGEROUSLY LOW."S" UNITS OF ENERGY"
1530  IF E>100 THEN 1550
1540  PRINT "YOU ARE LOW ON ENERGY"E"UNITS"
1550  FOR A=1 TO 10
1560  FOR B=1 TO 30
1570  IF Z[A,B]=2 THEN 1590
1580  GOTO 1870
1590  IF B>T2 THEN 1610
1600  IF B<T2 THEN 1660
1605  GOTO 1710
1610  IF Z[A,B-1]=0 THEN 1630
1615  IF Z[A,B-1]=3 THEN 1840
1620  GOTO 1870
1630  Z[A,B]=0
1640  Z[A,B-1]=2
1650  GOTO 1870
1660  IF Z[A,B+1]=0 THEN 1680
1665  IF Z[A,B+1]=3 THEN 1840
1670  GOTO 1870
1680  Z[A,B]=0
1690  Z[A,B+1]=2
1700  GOTO 1870
1710  IF A>T1 THEN 1740
1720  IF A<T1 THEN 1790
1730  STOP 
1740  IF Z[A-1,B]=0 THEN 1760
1745  IF Z[A-1,B]=3 THEN 1840
1750  GOTO 1870
1760  Z[A,B]=0
1770  Z[A-1,B]=2
1780  GOTO 1870
1790  IF Z[A+1,B]=0 THEN 1810
1795  IF Z[A+1,B]=3 THEN 1840
1800  GOTO 1870
1810  Z[A,B]=0
1820  Z[A+1,B]=2
1830  GOTO 1870
1840  PRINT "YOU GOT RAMMED BY A TIE FIGHTER"
1850  PRINT "***"'7'7'7"YOU LOSE***"'7'7'7
1860  GOTO 5500
1870  NEXT B
1880  NEXT A
1885  IF N>A4*(T/15) THEN 2000
1890  R=INT(((RND(0))*10)+1)
1900  FOR X=1 TO A4
1905  IF Z[R,15]=0 THEN 1910
1906  GOTO 1940
1910  Z[R,15]=2
1920  N=N+1
1930  R=R+1
1935  IF R>10 THEN 2000
1940  NEXT X
2000  PRINT 
2010  PRINT "COMMAND";
2020  INPUT B
2030  GOTO B OF 2500,3000,3500,4000,4500
2040  PRINT 
2050  PRINT "1-FIRE"
2060  PRINT "2-SHIELDS"
2070  PRINT "3-MANEUVER"
2080  PRINT "4-STAR SCAN"
2090  PRINT "5-STATUS REPORT"
2100  GOTO 2000
2500  IF E>49 THEN 2530
2510  PRINT "YOU DON'T HAVE ENOUGH ENERGY TO FIRE"
2520  GOTO 2000
2530  PRINT "FIRE COORDINATES";
2540  INPUT A,B
2550  GOTO Z[A,B]+1 OF 2560,2580,2600,2680
2560  PRINT "YOU MISSED"
2570  GOTO 2700
2580  PRINT "DIRECT HIT ON THE DEATH STAR"
2581  Z[A,B]=0
2582  H=H+1
2583  T=T-1
2590  GOTO 2700
2600  PRINT "DIRECT HIT ON A TIE FIGHTER"
2601  PRINT "***"'7'7'7"DESTROYED***"'7'7'7
2620  Z[A,B]=0
2650  N=N-1
2660  H=H+1
2670  GOTO 2700
2680  PRINT "YOU HIT YOURSELF.YOU ARE DESTROYED"
2690  GOTO 5500
2700  E=E-50
2710  GOTO 5000
3000  PRINT "SHIELD CONTROL.YOU HAVE "S"UNITS IN YOUR SHIELDS"
3010  PRINT E"UNITS AVALIBLE.ADD HOW MANY";
3020  INPUT W
3030  IF W>E THEN 3010
3040  IF W*(-1)>S THEN 3000
3050  S=S+W
3060  E=E-W
3070  PRINT "YOU NOW HAVE"S"UNITS IN YOUR SHIELDS"
3080  GOTO 5000
3500  PRINT "MANEUVER CONTROL"
3530  PRINT "MOVE TO   :";
3540  INPUT A,B
3570  GOTO Z[A,B]+1 OF 3580,3610,3630,3660
3580  Z[T1,T2]=0
3590  Z[A,B]=3
3595  T1=A
3596  T2=B
3600  GOTO 3660
3610  PRINT "YOU CRASHED INTO THE DEATH STAR.TOO BAD"
3620  GOTO 5500
3630  PRINT "YOU CRASHED INTO A TIE FIGHTER.YOU DSTROYED IT,"
3640  PRINT "BUT YOU DESTROYED YOURSELF TOO."
3650  GOTO 5500
3660  GOTO 5000
4000  PRINT "STAR SCAN"
4010  PRINT "            111111111122222222223"
4020  PRINT "   123456789012345678901234567890"
4030  FOR Q=1 TO 10
4040  FOR W=1 TO 30
4050  GOTO Z[Q,W]+1 OF 4060,4080,4100,4120
4060  A$[W]="."
4070  GOTO 4130
4080  A$[W]="@"
4090  GOTO 4130
4100  A$[W]="+"
4110  GOTO 4130
4120  A$[W]="M"
4130  NEXT W
4140  PRINT Q;LIN(0);
4150  PRINT TAB(3);A$
4160  NEXT Q
4170  PRINT 
4180  GOTO 5000
4500  PRINT "STATUS REPORT"
4510  PRINT E"UNITS OF ENERGY"
4520  PRINT S"UNITS IN SHIELDS"
4530  PRINT T"PIECES OF THE DEATH STAR ON SCAN"
4550  PRINT N"TIE SHIPS ON SCAN"
4560  PRINT D"TURNS USED"
4570  PRINT H"DIRECT HITS SCORED"
4580  IF D=0 THEN 4610
4590  PRINT H/D*100"PERCENT EFFICIENCY RATING"
4600  GOTO 5000
4610  PRINT 0"PERCENT EFFICIENY RATING"
5000  PRINT 
5005  A=INT(((RND(0))*N)+1)
5010  FOR X=1 TO A
5020  R=INT(((RND(0))*100)+50)
5030  PRINT "TIE FIGHTER ATTACK"R"UNITS",
5040  S=S-R
5050  IF S<1 THEN 5200
5060  PRINT S"UNITS LEFT"
5070  NEXT X
5080  R=INT(((RND(0))*(T/15))+1)
5090  FOR X=1 TO R
5100  A=INT(((RND(0))*100)+50)
5110  PRINT "DEATH  STAR ATTACK"A"UNITS",
5120  S=S-A
5130  IF S<1 THEN 5200
5140  PRINT S"UNITS LEFT"
5150  NEXT X
5160  D=D+1
5170  IF T>0 THEN 1500
5180  IF N>0 THEN 1500
5190  GOTO 5500
5200  PRINT LIN(3)
5210  PRINT "YOUR DEAD SUCKER!!!"'7'7'7'7'7
5220  PRINT "THAT LAST ATTACK DRAINED YOUR SHIELDS AND YOU WERW BLOWN UP"
5500  PRINT LIN(2)
5510  IF D=0 THEN 5540
5520  PRINT "EFFICIENCY RATING"H/D*100"PERCENT"
5530  GOTO 5560
5540  PRINT "FIRST TIME ON THE GRID,HUH? TOO BAD."
5550  PRINT "YOU SHOULD HAVE PUT UP YOUR SHIELDS FIRST THING"
5560  PRINT "WELL MAYBE NEXT TIME."
5570  END 
