10  COM Z1,M4,N4,T1,S1,F1,S2,P8,P9,Q8,Y1
20  GOTO 50
30  CHAIN "$BINOM"
40  REM PROGRAM NAME = PASCL, PASCAL'S TRIANGLE
50  PRINT 
60  IF Z1=10 THEN 120
70  PRINT "THIS PROGRAM INVESTIGATES PASCAL'S TRIANGLE.  IT MAY THEN"
80  PRINT "BE USED IN THE EXPANSION OF BIOMIALS OF THE"
90  PRINT "FORM (A+B)^N."'10
100  B1=0
110  GOTO 140
120  C1=35
130  GOTO 150
140  C1=14
150  B1=N9=0
160  A1=N=1
170  DIM B$[30],A$[3],C$[50],E$[70]
180  DIM D$[70]
190  C$="1 5 10 10 5 1 6 15 20 15 6 1 7 21 35 35 21 7 1"
200  E$="A^5 + 5*A^4*B + 10*A^3*B^2 + 10*A^2*B^3 + 5*A*B^4 + B^5"
210  G2=2
220  DIM R[40],H[40]
230  Q=2
240  FOR K=1 TO 35
250  IF K>2 THEN 280
260  R[K]=1
270  GOTO 370
280  Q=Q+1
290  FOR M=1 TO Q
300  IF M=1 OR M=Q THEN 330
310  R[K]=R[K-Q]+R[K-Q+1]
320  GOTO 350
330  R[K]=1
340  IF M=Q THEN 360
350  K=K+1
360  NEXT M
370  NEXT K
380  IF Z1=10 THEN 630
390  FOR I=1 TO 4
400  PRINT 
410  PRINT 
420  PRINT 
430  IF I=1 THEN 460
440  PRINT I"COINS ARE TOSSED "'10
450  GOTO 470
460  PRINT I"COIN IS TOSSED "'10
470  FOR J=0 TO I
480  PRINT "HOW MANY WAYS CAN YOU GET "I-J"HEAD(S) AND"J"TAIL(S)";
490  INPUT H[N]
500  IF H[N]=R[N] THEN 580
510  PRINT "YOUR ANSWER IS NOT CORRECT.  DO YOU WANT TO TRY AGAIN";
520  INPUT A$
530  IF A$="YES" THEN 480
540  IF A$="NO" THEN 570
550  GOSUB 1840
560  GOTO 510
570  PRINT "THE CORRECT ANSWER IS "R[N]
580  N=N+1
590  NEXT J
600  NEXT I
610  PRINT 
620  PRINT "YOUR RESULTS COULD HAVE BEEN PRINTED IN THIS WAY."'10
630  J=35
640  PRINT 
650  K=3
660  IF Z1=10 THEN 700
670  PRINT " NUMBER OF"
680  PRINT "COINS TOSSED"
690  GOTO 720
700  PRINT "NUMBER OF TIMES"
710  PRINT "POLYHEDRON TOSSED"
720  FOR I=1 TO C1
730  IF I=1 THEN 770
740  IF I=3 OR I=6 OR I=10 OR I=15 OR I=21 OR I=28 THEN 760
750  GOTO 810
760  PRINT 
770  PRINT 
780  PRINT TAB(5);R[I+1];
790  J=J-K
800  PRINT TAB(J);
810  PRINT R[I];
820  NEXT I
830  PRINT 
840  PRINT 
850  IF Z1#10 THEN 870
860  GOTO 30
870  IF A1=5 THEN 1490
880  N9=N9+1
890  PRINT "CAN YOU SEE THE PATTERN FOR THE NEXT ROW OF NUMBERS";
900  INPUT A$
910  PRINT 
920  IF A$="YES" THEN 1070
930  IF A$="NO" THEN 960
940  GOSUB 1840
950  GOTO 890
960  PRINT "DO YOU WANT ANOTHER ROW PRINTED  ";
970  INPUT A$
980  A1=2
990  B1=B1+1
1000  IF A$="YES" THEN 1040
1010  IF A$="NO" THEN 1490
1020  GOSUB 1840
1030  GOTO 960
1040  GOTO B1 OF 1250,1280,1310
1050  PRINT "YOU BETTER GET HELP FROM YOUR TEACHER ON THE CORRECT PATTERN"'10
1060  GOTO 1490
1070  PRINT "INPUT THE NEXT ROW OF NUMBERS USING NO COMMAS AND LEAVING A"
1080  PRINT "SINGLE SPACE BETWEEN EACH NUMBER";
1090  INPUT B$
1100  PRINT 
1110  A1=1
1120  GOTO N9 OF 1130,1150,1170
1130  IF B$=C$[1,13] THEN 1250
1140  GOTO 1180
1150  IF B$=C$[13,28] THEN 1280
1160  GOTO 1180
1170  IF B$=C$[28,46] THEN 1310
1180  PRINT "YOU GOOFED!  DO YOU WANT TO TRY AGAIN";
1190  INPUT A$
1200  PRINT 
1210  IF A$="YES" THEN 1070
1220  IF A$="NO" THEN 960
1230  GOSUB 1840
1240  GOTO 1180
1250  C1=20
1260  IF A1=2 THEN 630
1270  GOTO 1330
1280  C1=27
1290  IF A1=2 THEN 630
1300  GOTO 1330
1310  C1=35
1320  IF A1=2 THEN 630
1330  PRINT "GREAT!  YOU HAVE DISCOVERED THE CORRECT PATTERN."
1340  PRINT "THIS ARRAY OF NUMBERS IS CALLED PASCAL'S TRIANGLE."
1350  PRINT "YOU HAVE PROBABLY NOTICED THAT EACH NUMBER WITHIN THE "
1360  PRINT "TRIANGLE IS FOUND BY ADDING THE PAIR OF NUMBERS DIRECTLY"
1370  PRINT "ABOVE IT."
1380  PRINT 
1390  PRINT 
1400  PRINT "DO YOU WANT THE FINAL ARRAY OF NUMBERS PRINTED";
1410  INPUT A$
1420  PRINT 
1430  A1=5
1440  IF A$="YES" THEN 630
1450  IF A$="NO" THEN 1490
1460  GOSUB 1840
1470  GOTO 1400
1480  GOTO 630
1490  PRINT 
1500  PRINT "THE ARRAY OF NUMBERS CALLED PASCAL'S TRIANGLE ALSO REPRESENTS"
1510  PRINT "THE COEFFICIENTS IN THE EXPANSION OF BINOMIALS OF THE FORM"
1520  PRINT "(A+B)^N.  FOR INSTANCE (A+B)^3 = A^3 + 3*A^2*B + 3*A*B^2 + B^3"
1530  PRINT "AND THE COEFFICIENTS 1,3,3,1 REPRESENT THE THIRD ROW OF"
1540  PRINT "PASCAL'S TRIANGLE. "
1550  PRINT 
1560  PRINT "WHAT ROW OF PASCAL'S TRIANGLE WOULD REPRESENT THE COEFFICIENTS"
1570  PRINT "IN THE EXPANSION OF (A+B)^4?  INPUT THE ROW NUMBER ";
1580  INPUT R6
1590  PRINT 
1600  IF R6=4 THEN 1630
1610  PRINT "THE ROW IS 4."
1620  PRINT 
1630  PRINT "THE EXPANSION FOR (A+B)^4 IS"
1640  PRINT TAB(15);" A^4 + 4*A^3*B + 6*A^2*B^2 + 4*A*B^3 + B^4"'10
1650  PRINT "NOTICE THAT THE EXPONENTS OF A DECREASE AND THOSE FOR B INCREASE."
1660  PRINT "NOW USING THE PATTERN DESCRIBED ABOVE EXPAND (A+B)^5."
1670  PRINT "WHEN TYPING YOUR EXPANSION ONLY USE SPACES BEFORE AND AFTER ";
1680  PRINT "THE PLUS SIGNS.  ALSO DON'T USE ANY PARENTHESIS OR BRACKETS."
1690  PRINT 
1700  PRINT "(A+B)^5 =";
1710  INPUT D$
1720  IF D$="A^5 + 5*A^4*B + 10*A^3*B^2 + 10*A^2*B^3 + 5*A*B^4 + B^5" THEN 1810
1730  PRINT 
1740  PRINT "YOU ARE NOT CORRECT.  DO YOU WANT TO TRY AGAIN ";
1750  INPUT C$
1760  PRINT 
1770  IF C$="YES" THEN 1700
1780  IF C$="NO" THEN 1870
1790  GOSUB 1840
1800  GOTO 1740
1810  PRINT 
1820  PRINT "CONGRATULATIONS!  YOU HAVE WRITTEN THE EXPANSION CORRECTLY."
1830  GOTO 1960
1840  PRINT 
1850  PRINT "YOU HAVE MADE A TYPING MISTAKE.  TRY AGAIN!"'10
1860  RETURN 
1870  PRINT "DO YOU WANT THE EXPANSION PRINTED ";
1880  INPUT C$
1890  PRINT 
1900  IF C$="YES" THEN 1940
1910  IF C$="NO" THEN 2020
1920  GOSUB 1840
1930  GOTO 1870
1940  PRINT "(A+B)^5 = "E$
1950  PRINT 
1960  PRINT "NOW, AS YOU EXPAND A BINOMIAL OF THE FOR (A-B)^N,"
1970  PRINT "CONSIDER THE FOLLOWING:"
1980  PRINT TAB(10);"1. DOES PASCAL'S TRIANGLE STILL APPLY?"
1990  PRINT TAB(19);"2. WHAT HAPPENS TO THE SIGNS OF THE TERMS?"
2000  PRINT "TRY EXPANDING (A-B)^3, AND (A-B)^4.  CHECK WITH"
2010  PRINT "YOUR TEACHER TO SEE IF YOUR ANSWERS ARE CORRECT."
2020  END 
