1  REM NEWC1 COMPUTER PROGRAM TO ACCOMPANY NEWFOOD(C) PARTII 7/24/73
2  REM DEV A RISK PROFILE BASED ON TRIAL AND REPEAT INFO
3  REM CASE2, HP 36841A, 2/74 (NEWC1, PART 6 OF 8)
10  LET N=200
20  LET Z1=2.6
30  DIM S[20]
40  FOR I=1 TO 20
50  LET S[I]=0
60  NEXT I
70  X=0
80  LET E=0
90  LET V=0
100  PRINT "POPULATION SIZE";
110  INPUT C1
120  PRINT "MIN, MOST LIKELY, MAX TRIAL RATE";
130  INPUT A[1],M[1],B[1]
140  PRINT "MIN,MOST LIKELY, MAX REPEAT RATE";
150  INPUT A[2],M[2],B[2]
160  PRINT "MIN, MOST LIKELY, MAX REP UNITS PER REPEATER";
170  INPUT A[3],M[3],B[3]
180  PRINT "AVE UNITS ON TRIAL";
190  INPUT R
200  PRINT "PRICE,MARGIN PER UNIT,TOTAL FIXED COST";
210  INPUT S,M,F1
220  PRINT 
230  FOR Z=1 TO 3
240  LET K[Z]=(M[Z]-A[Z])/(B[Z]-A[Z])
250  LET H[Z]=Z1*1.414/(B[Z]-A[Z])
260  LET Y[Z]=M[Z]+(2/SQR(3.1416))*(1-2*K[Z])/H[Z]
270  NEXT Z
280  PRINT "EXPECTED TRIAL RATE";Y[1]
290  PRINT "EXPECTED REPEAT RATE=",Y[2]
300  PRINT "EXPECTED REP VOL PER REPEATER=",Y[3]
310  PRINT 
320  D1=C1*Y[1]*(R+Y[2]*Y[3])
330  LET D3=D1*M
340  LET D4=D1*M-F1
350  PRINT "EXPECTED VALUE P/L"
360  PRINT 
370  PRINT "UNIT SALES",INT(D1)
380  PRINT "$ SALES",INT(D1*S)
390  PRINT "NET REV",INT(D4)
400  PRINT 
410  FOR J=1 TO N
420  FOR Z=1 TO 3
430  LET X=RND(X)
440  IF X<K[Z] THEN 470
450  LET P=.5*(1-X)/(1-K[Z])
460  GOTO 480
470  LET P=.5*X/K[Z]
480  LET T=SQR(LOG(1/P^2))
490  LET T=T-(2.30753+.27061*T)/(1+.99229*T+.04481*T^2)
500  IF X<K[Z] THEN 530
510  LET Y[Z]=M[Z]+1.414*((1-K[Z])/H[Z])*T
520  GOTO 540
530  LET Y[Z]=M[Z]-1.414*(K[Z]/H[Z])*T
540  NEXT Z
550  Y=C1*Y[1]*(R+Y[2]*Y[3])
560  C8=C1*B[1]*(R+B[2]*B[3])
570  C9=C1*A[1]*(R+A[2]*A[3])
580  I=INT((20*(Y-C9)/(C8-C9))+.5)
590  IF I<1 THEN 640
600  IF I>20 THEN 620
610  GOTO 650
620  LET I=20
630  GOTO 650
640  I=1
650  LET S[I]=S[I]+1
660  IF J/50 <> INT(J/50) THEN 680
670  PRINT "SIM IS";J/N;"COMPLETED"
680  NEXT J
690  PRINT 
700  PRINT "UNIT SALES","$ SALES","NET REV","CUM PROB"
710  FOR I=1 TO 20
720  Y=C9+(C8-C9)*I/20
730  LET E=Y*S[I]/N+E
740  LET V=S[I]/N+V
750  Y=INT((Y+(C8-C9)/40)+.5)
760  PRINT Y,Y*S,Y*M-F1,V
770  IF V>.9999 THEN 790
780  NEXT I
790  END 
