10  COM I,A[37,61],B,E[3],P,P4,A$[10],D[19,2],R1
20  REM PROGRAM NAME = KEP2, TIME PLOT OF ORBIT
30  REM JEFFERSON COUNTY WRITING TEAM, LAKEWOOD, COLORADO
40  REM 9 AUGUST 1973
50  GOTO 70
60  CHAIN "$ORB2"
70  DIM C$[6],B$[10]
80  Z=240
90  IF A$="3" THEN 480
100  MAT A=ZER
110  I=P=N=1
120  P4=I+I
130  PRINT "THIS PROGRAM SIMULATES A MASS MOVING IN AN ELLIPTICAL ORBIT."
140  PRINT "THE TIME BETWEEN THE PLOTTED POINTS IS EQUAL."
150  PRINT "FROM THE PLOT YOU MAY LOCATE THE CENTRAL MASS, CALCULATE "
160  PRINT "THE ECCENTRICITY OF THE ORBIT, AND OR COMPARE THE AREAS SWEPT BY"
170  PRINT "THE ORBITTING MASS."
180  PRINT "(THERE IS ABOUT A ONE MINUTE PAUSE IN THE PRINT-OUT FOR CALCULATIONS)"
190  R1=INT(100*RND(0))
200  IF  NOT R1 THEN 190
210  A=30
220  E[I]=E=INT(10*RND(0))/10
230  IF E<.3 OR E>.8 THEN 220
240  B=SQR(A^2*(I-E^2))
250  R2=A*(I+E)
260  C=A*E
270  V=SQR(1.67*1.99/1.5)*10^4
280  A5=A7=A8=A9=A2=I-I
290  GOTO 390
300  A8=R2^2*(.00872665)/2
310  A9=A8+A9
320  A7=A7+A8
330  A2=A2+.00872665
340  IF A9 >= 3.14159*A*B THEN 470
350  A5=A5+(A9 >= 3.14159)
360  IF A7 >= 3.14159*A*B/18 THEN 390
370  R2=(A^2-C^2)/(A-C*COS(A2))
380  GOTO 300
390  X=31+INT(R2*COS(A2)-C+.5)
400  Y=19-INT(3/5*R2*SIN(A2)+.5)
410  A[Y,X]=I
420  D[N,I]=D[N+((N=I)*18),I]=R2*R1/A
430  D[N,2]=D[N+((N=I)*18),2]=V*SQR((2*A/R2-I)/R1)
440  A7=A8=A5=I-I
450  N=N+I
460  GOTO 370
470  GOTO 60
480  PRINT "DO YOU WANT QUANTITATIVE DATA ABOUT THE ORBIT?  ";
490  ENTER Z,D,B$
500  PRINT '13
510  IF B$="NO" THEN 660
520  IF B$#"YES" THEN 480
530  PRINT TAB(6)'10"MEAN SEPARATION (A.U.) ----- "R1
540  V=INT(100*SQR(1.67*1.99/R1/1.5)+.5)*100
550  PRINT TAB(6)"MEAN ORBITAL SPEED (M/SEC) - "V
560  T=2*3.14159*R1*1.5E+11/V
570  PRINT TAB(6)"PERIOD OF REVOLUTION (SEC) - "T
580  PRINT TAB(6)"                     (YR)  - "T/3.15569E+07
590  PRINT TAB(6)"PERIHELION DISTANCE (A.U.) - "R1*(I-E[I])
600  PRINT TAB(6)"APHELION DISTANCE (A.U.)   - "R1*(I+E[I])
610  PRINT '10'10"SEPARATION"TAB(18)"ORBITAL SPEED"'10'13"(A.U.)"TAB(18)"(M/SEC)"
620  FOR N=I TO 19
630  PRINT D[N,I];TAB(18);D[N,2]
640  NEXT N
650  PRINT 
660  PRINT "USING THE PLOT:"
670  PRINT "  1) LOCATE THE FOCI (THE CENTRAL MASS IS AT ONE OF THESE),"
680  PRINT "  2) CACULATE THE ECCENTRICITY OF THE ORBIT, AND"
690  PRINT "  3) COMPARE THE AREAS SWEPT BY THE ORBITING MASS IN EQUAL"
700  PRINT "     TIME INTERVALS."
710  PRINT "  4) YOU MIGHT TRY SKETCHING THE ORBIT OF THIS MASS AS IT WOULD"
720  PRINT "     APPEAR FROM ANOTHER MASS ORBITTING THE SAME CENTRAL MASS."
730  END 
