10  COM N$[72],F$[72],I,Q,P,C5,W,Q1,T[20],D[20],C[20],V[20]
20  GOTO 80
30  CHAIN "$BLINKD"
40  CHAIN "$BLINKP"
50  REM PROGRAM NAME = BLINK3, ACCELERATION PROGRAM
60  REM CHAINED TO BLINKY,BLINKD,BLINKM,BLINKP,BLINK2,BLINK5,BLINK6
70  REM CHAINED TO BPLOT
80  DIM U$[3],B$[72],A[72]
90  DIM L$[10]
100  L$="1234567890"
110  G1=1
120  MAT A=CON
130  PRINT '10"-------- UNIFORM ACCELERATION PROGRAM - RUN "L$[G1,G1]":"
140  G1=G1+1
150  PRINT 
160  PRINT "INPUT THE ACCELERATION (M/SEC/SEC) OF THE OBJECT?  ";
170  ENTER 100,K3,C
180  PRINT '13
190  IF K3<0 THEN 160
200  IF C>0 AND C<101 THEN 260
210  IF C>100 THEN 240
220  PRINT "YOU MUST USE AN ACCELERATION GREATER THAN ZERO.  TRY AGAIN   ";
230  GOTO 170
240  PRINT "YOU MUST USE AN ACCELERATION LESS THAN 100.  TRY AGAIN   ";
250  GOTO 170
260  PRINT 
270  PRINT "TIME (WITH RETURN KEY):";
280  LET K2=250
290  ENTER K2,K3,K$
300  IF K3>0 THEN 330
310  PRINT '13
320  GOTO 270
330  ENTER K2,K3,K$
340  IF K3<0 THEN 310
350  IF ABS(K3)<10 THEN 400
360  PRINT 
370  PRINT "     TRAVELING OVER 9 SECONDS PUTS THE PHOTOGRAPH OFF SCALE,"
380  PRINT "     SO THE PHOTOGRAPH WILL ONLY SHOW TRAVEL FOR 9 SECONDS."
390  LET K3=9
400  PRINT '10"THE OBJECT ACCELERATED FOR"ABS(K3)"SECOND(S) AT"C"M/SEC/SEC"
410  PRINT '10"-----SIMULATED PHOTOGRAPH:"'10
420  PRINT "0     ";
430  LET D=INT(.5*C*K3^2+.5)
440  LET A=INT(.2*D*100)/100
450  FOR N=A TO (5*A)+5 STEP A
460  PRINT  USING 470;N
470  IMAGE#,DDDD.D4X
480  NEXT N
490  PRINT "    (METERS)";
500  PRINT '10'13;
510  LET B$="0123456789012345678901234567890123456789"
520  MAT A=CON
530  LET T=0
540  LET G=D/50
550  LET Y=.5*C*T^2
560  LET S=INT((Y/G)+.5)+1
570  IF S>51 THEN 670
580  FOR X=1 TO 51
590  IF X#S THEN 650
600  LET A[X]=2
610  LET T=T+1
620  LET T[T]=T-1
630  LET D[T]=Y
640  V[T]=C*(T-1)
650  NEXT X
660  GOTO 550
670  LET R=0
680  PRINT "I'''''''''I'''''''''I'''''''''I'''''''''I'''''''''I"
690  IMAGE 12X,DD
700  PRINT '13;
710  LET N2=1
720  FOR Y=1 TO 51
730  GOTO A[Y] OF 740,790
740  IF R=1 THEN 770
750  PRINT " ";
760  GOTO 850
770  PRINT " ";
780  GOTO 850
790  IF R=1 THEN 820
800  PRINT "*";
810  GOTO 850
820  PRINT B$[N2,N2];
830  LET N2=N2+1
840  GOTO 850
850  NEXT Y
860  IF R=1 THEN 900
870  LET R=1
880  PRINT 
890  GOTO 710
900  PRINT "         (SECONDS)"
910  PRINT 
920  PRINT "-----DATA TABLE:"'10
930  PRINT "ACCELERATION","TOTAL TIME","DISTANCE","FINAL SPEED"
940  FOR W=1 TO T
950  LET C[W]=C
960  PRINT C,T[W],D[W],V[W]
970  NEXT W
980  PRINT '10"------------------------------------------------------------------"'10
990  PRINT '10"DO YOU WANT TO RUN THIS ACCELERATION PROGRAM AGAIN?  ";
1000  ENTER 200,K4,U$
1010  PRINT '13
1020  IF K4<0 THEN 990
1030  IF U$="YES" THEN 130
1040  IF U$#"NO" THEN 990
1050  PRINT "DO YOU WANT TO GRAPH THE DATA IN THE DATA TABLE?  ";
1060  ENTER 200,K4,U$
1070  PRINT '13
1080  IF K4<0 THEN 1050
1090  IF U$="NO" THEN 1120
1100  IF U$#"YES" THEN 1050
1110  GOTO 40
1120  PRINT 
1130  PRINT "DO YOU WANT TO TRY SOME MOTION PROBLEMS?  ";
1140  ENTER 200,K4,U$
1150  PRINT '13
1160  IF K4<0 THEN 1130
1170  IF U$="NO" THEN 1220
1180  IF U$#"YES" THEN 1130
1190  W=0
1200  P=3
1210  GOTO 30
1220  END 
