10  COM N$[72],F$[72],I,Q,P,C5,W,Q1,T[20],D[20],C[20],V[20]
20  GOTO 70
30  CHAIN "$BLINKP"
40  CHAIN "$BLINK3"
50  REM PROGRAM NAME = BLINK2, SPEED PROGRAM
60  REM CHAINED TO BLINKY,BLINKD,BLINKM,BLINKP,BLINK3,BLINK5,BLINK6
70  DIM U$[3],B$[72],A[72]
80  DIM L$[10]
90  L$="1234567890"
100  K2=240
110  G1=1
120  MAT A=CON
130  PRINT '10"-------- UNIFORM SPEED PROGRAM : RUN "L$[G1,G1]":"
140  G1=G1+1
150  PRINT 
160  PRINT "INPUT THE SPEED (M/SEC) OF THE OBJECT?  ";
170  ENTER 200,K3,C
180  PRINT '13
190  IF K3<0 THEN 160
200  IF C>0 AND C<101 THEN 260
210  IF C>100 THEN 240
220  PRINT "     YOU MUST USE A SPEED GREATER THAN 0."
230  GOTO 160
240  PRINT "     YOU MUST USE A SPEED LESS THAN 100 M/S."
250  GOTO 160
260  PRINT 
270  PRINT "TIME (WITH RETURN KEY):";
280  ENTER K2,K3,K$
290  IF K3>0 THEN 320
300  PRINT '13
310  GOTO 260
320  ENTER K2,K3,K$
330  IF K3<0 THEN 300
340  IF ABS(K3)<10 THEN 390
350  PRINT 
360  PRINT "     TRAVELING OVER 9 SECONDS PUTS THE PHOTOGRAPH OFF SCALE,"
370  PRINT "     SO THE PHOTOGRAPH WILL ONLY SHOW TRAVEL FOR 9 SECONDS."
380  LET K3=9
390  PRINT 
400  LET K3=ABS(K3)
410  PRINT "THE OBJECT TRAVELED FOR"ABS(K3)"SECOND(S) AT "C"M/SEC"
420  PRINT '10"-----SIMULATED PHOTOGRAPH:"'10
430  PRINT "0     ";
440  LET D=INT(C*K3+.5)
450  LET A=INT(.2*D*100)/100
460  FOR N=A TO (5*A) STEP A
470  PRINT  USING 480;N
480  IMAGE#,DDDD.D4X
490  NEXT N
500  PRINT "    (METERS)";
510  PRINT '10'13;
520  LET B$="0123456789012345678901234567890123456789"
530  MAT A=CON
540  LET T=0
550  LET G=D/50
560  LET Y=C*T
570  LET S=INT((Y/G)+.5)+1
580  IF S>51 THEN 680
590  FOR X=1 TO 51
600  IF X#S THEN 660
610  LET A[X]=2
620  LET T=T+1
630  LET T[T]=T-1
640  LET D[T]=Y
650  V[T]=C*(T-1)
660  NEXT X
670  GOTO 560
680  LET R=0
690  PRINT "I'''''''''I'''''''''I'''''''''I'''''''''I'''''''''I"
700  IMAGE 12X,DD
710  PRINT '13;
720  LET N2=1
730  FOR Y=1 TO 51
740  GOTO A[Y] OF 750,800
750  IF R=1 THEN 780
760  PRINT " ";
770  GOTO 850
780  PRINT " ";
790  GOTO 850
800  IF R=1 THEN 830
810  PRINT "*";
820  GOTO 850
830  PRINT B$[N2,N2];
840  LET N2=N2+1
850  NEXT Y
860  IF R=1 THEN 900
870  LET R=1
880  PRINT 
890  GOTO 720
900  PRINT "         (SECONDS)"
910  PRINT 
920  PRINT "-----DATA TABLE:"'10
930  PRINT "TOTAL TIME","DISTANCE","SPEED"
940  PRINT "SECONDS","METERS","METERS/SECOND"
950  FOR W=1 TO T
960  LET V[W]=C
970  LET C[W]=0
980  PRINT T[W],D[W],V[W]
990  NEXT W
1000  PRINT '10"-------------------------------------------------------------------"
1010  PRINT '10'10
1020  PRINT '10"DO YOU WANT TO RUN THIS SPEED PROGRAM AGAIN?  ";
1030  ENTER 100,K3,U$
1040  PRINT '13
1050  IF K3<0 THEN 1020
1060  IF U$="YES" THEN 130
1070  PRINT "DO YOU WANT TO GRAPH THE DATA IN THE DATA TABLE?  ";
1080  ENTER 200,K3,U$
1090  PRINT '13
1100  IF K3<0 THEN 1070
1110  IF U$="NO" THEN 1130
1120  GOTO 30
1130  PRINT "DO YOU WANT TO RUN THE ACCELERATION PROGRAM?  ";
1140  ENTER 100,K3,U$
1150  PRINT '13
1160  IF K3<0 THEN 1130
1170  IF U$="NO" THEN 1200
1180  PRINT '10
1190  GOTO 40
1200  END 
