10  COM I,Z1,B[10],I$[10],I2
20  REM PROGRAM NAME = ACF-6, OF CIRMO, THE DATA TABLE
30  REM JEFFERSON COUNTY WRITING TEAM, LAKEWOOD, COLORADO
40  REM 9 AUGUST 1973
50  GOTO 70
60  CHAIN "$ACF-2"
70  IF I2=I AND Z1=3 THEN 120
80  PRINT 
90  PRINT "THERE ARE THREE ORBITS PLOTTED, EACH WITH A DIFFERENT SYMBOL."
100  PRINT 
110  PRINT "----- DATA TABLE FOR THE PLOT:"
120  DIM D$[10],B$[6]
130  D$="123456789"
140  N4=N5=Q=I-I
150  D=E=20
160  FOR N=I TO 6
170  FOR N1=I TO 9
180  IF I$[N,N]="0" THEN 250
190  IF I$[N,N]=D$[N1,N1] THEN 210
200  NEXT N1
210  Q=N1
220  N4=N4+I
230  IF N4=2 THEN 260
240  N5=Q
250  NEXT N
260  N5=Q
270  IF B[10]#I THEN 300
280  PRINT "INPUT YOUR CALCULATION FOR THE ACCELERATION.  THE CORRECT VALUE"
290  PRINT "WILL BE PRINTED FOR COMPARISON."
300  PRINT '10"RADIUS     SPEED       ACCELERATION         PERCENT DEVIATION"
310  K=1800*N5
320  FOR N6=I TO 3
330  R=B[N6]*N5
340  V=INT(10*SQR(K/R))/10
350  IF B[10]#I THEN 410
360  PRINT R;TAB(11);V;TAB(23);
370  ENTER D,E,A1
380  A2=INT((100*K)/(R^2)+.5)/100
390  PRINT TAB(31);A2;TAB(48);((A1-A2)/A2)*100
400  GOTO 420
410  PRINT R;TAB(11);V
420  NEXT N6
430  IF B[10]=I THEN 470
440  PRINT "CALCULATE THE ACCELERATION FOR THE ORBITTING MASS IN EACH"
450  PRINT "OF THESE ORBITS.  YOU CAN CHECK YOUR ANSWERS BY RUNNING CIRMO AGAIN."
460  GOTO 600
470  PRINT '10"DO YOU THINK THE DEVIATION BETWEEN ANSWERS IS REASONABLE";
480  INPUT B$
490  IF B$="YES" THEN 600
500  IF B$#"NO" THEN 470
510  PRINT "PERHAPS YOU MADE AN ERROR IN YOUR CALCULATIONS."
520  PRINT "YOU SHOULD HAVE USED THIS RELATIONSHIP:"
530  PRINT "     ACCELERATION = (SPEED)^2/RADIUS"
540  PRINT 
550  PRINT "DO YOU WANT TO TRY ANOTHER PROBLEM?  ";
560  ENTER 240,D,B$
570  PRINT '13
580  IF B$="YES" THEN 60
590  IF B$#"NO" THEN 550
600  END 
