1  REM  CASE1, 36790 REV A, 2/74, PLAN - PART 4 OF 5
2  REM  DATA SEQUENCE IN DATA STATEMENTS IS "NAME",AND THEN
3  REM  FOR EACH OF THE PAST FIVE YEARS: TOTAL MARKET,MARKET
4  REM  SHARE,PRICE,GROSS C MARG,OVERHEAD,ADV.,PROMOTION
5  IMAGE 13A,8D,8D,8D,8D,8D
6  IMAGE 13A,4D.3D,4D.3D,4D.3D,4D.3D,4D.3D
8  IMAGE 13A,3D,8D,8D,8D,8D,8D
9  IMAGE 13A,3D,4D.3D,4D.3D,4D.3D,4D.3D,4D.3D
10  DIM A[4,5],H[10,5],S[8,5],T[5],V[12,5],W[4,5],Z[5],J$[72],K$[70]
11  DIM D$[2],E$[3],F$[5],G$[11],H$[9],I$[12]
12  DIM A$[5],B$[11],M[10,5]
13  DIM Q$[25]
14  LET N=0
15  READ D$,E$,F$,G$,H$
20  DATA "NO","YES","PRICE","ADVERTISING","PROMOTION"
25  FOR I=1 TO 8
30  READ J$[(I-1)*9+1,I*9]
35  NEXT I
40  DATA "SALES VOL","SALES $  ","GR C MARG","OVERHEAD"
45  DATA "GR MARGIN","ADVERT.  ","PROMOTION","NET OP PR"
50  FOR I=1 TO 10
55  READ K$[(I-1)*7+1,I*7]
60  NEXT I
65  DATA "MARKET ","SHARE  ","PRICE  ","GR C MG"
70  DATA "OVHD/UN","OV CONS","ADV/UN "
75  DATA "AD CST ","PROM/UN","PROM CT"
76  READ A$
77  PRINT 
78  PRINT "WHICH PRODUCT DO YOU WANT TO CONSIDER?";
79  PRINT "(0=TACOS,1=MATZO BALLS)"
81  INPUT B1
82  IF B1=1 THEN 87
83  PRINT 
84  PRINT A$
85  PRINT 
86  GOTO 95
87  FOR I=1 TO 7
88  FOR J=1 TO 5
89  READ M[I,J]
90  NEXT J
91  NEXT I
92  READ B$
93  PRINT 
94  PRINT B$
95  PRINT 
96  FOR I=1 TO 7
97  FOR J=1 TO 5
98  READ H[I,J]
100  NEXT J
105  NEXT I
107  RESTORE 
110  FOR J=1 TO 5
115  LET S[1,J]=H[1,J]*H[2,J]
120  LET S[2,J]=S[1,J]*H[3,J]
125  LET S[3,J]=S[1,J]*H[4,J]
130  LET S[4,J]=H[5,J]
135  LET S[5,J]=S[3,J]-S[4,J]
140  LET S[6,J]=H[6,J]
145  LET S[7,J]=H[7,J]
150  LET S[8,J]=S[5,J]-S[6,J]-S[7,J]
155  NEXT J
174  PRINT 
175  PRINT "HISTORICAL FILE"
176  LET Q$=" "
180  PRINT  USING 5;Q$,1969,1970,1971,1972,1973
185  PRINT 
186  LET Q$="MARKET"
190  PRINT  USING 5;Q$,H[1,1],H[1,2],H[1,3],H[1,4],H[1,5]
191  LET Q$="SHARE"
195  PRINT  USING 6;Q$,H[2,1],H[2,2],H[2,3],H[2,4],H[2,5]
196  LET Q$="PRICE"
200  PRINT  USING 6;Q$,H[3,1],H[3,2],H[3,3],H[3,4],H[3,5]
201  LET Q$="GROSS C MARG"
205  PRINT  USING 6;Q$,H[4,1],H[4,2],H[4,3],H[4,4],H[4,5]
210  PRINT 
215  GOSUB 935
220  FOR J=1 TO 5
225  LET H[8,J]=H[6,J]
230  LET H[6,J]=H[5,J]
235  LET H[10,J]=H[7,J]
240  LET H[5,J]=H[7,J]=H[9,J]=0
245  NEXT J
250  FOR X=1 TO 10
255  LET R=0
260  FOR Y=1 TO 5
265  LET R=R+H[X,Y]
270  NEXT Y
275  FOR Y=1 TO 5
280  LET V[X,Y]=.2*R+.1*(Y+2)*(-2*H[X,1]-H[X,2]+H[X,4]+2*H[X,5])
285  NEXT Y
290  NEXT X
295  PRINT 
300  PRINT "BASE PLAN INPUT PROJECTIONS"
305  PRINT "           LINE #   1974    1975    1976    1977    1978"
310  PRINT 
315  FOR I=1 TO 10
320  FOR J=1 TO 5
325  LET Z[J]=INT(1000*V[I,J]+.5)/1000
330  NEXT J
335  GOTO I OF 340,350,350,350,350,340,350,340,350,340
340  PRINT  USING 8;K$[(I-1)*7+1,I*7],I,Z[1],Z[2],Z[3],Z[4],Z[5]
345  GOTO 355
350  PRINT  USING 9;K$[(I-1)*7+1,I*7],I,Z[1],Z[2],Z[3],Z[4],Z[5]
355  NEXT I
356  PRINT 
357  PRINT "DO YOU WANT AN EXPLANATION OF THE INPUTS?(0=NO,1=YES)"
359  INPUT B2
360  IF B2=0 THEN 372
361  PRINT 
362  PRINT "'MARKET' IS TOTAL INDUSTRY MARKET"
363  PRINT "'SHARE' IS CONCORN'S SHARE OF THE TOTAL INDUSTRY MARKET"
364  PRINT "'GR C MG' IS GROSS CONTRIBUTION MARGIN"
365  PRINT "'OVHD/UN' IS OVERHEAD PER UNIT (VARIABLE OVERHEAD COST)"
366  PRINT "'OV/CONS' IS OVERHEAD CONSTANT (FIXED OVERHEAD COST)"
367  PRINT "'ADV/UN' IS ADVERTISING PER UNIT"
368  PRINT "'AD CST' IS ADVERTISING CONSTANT"
369  PRINT "'PROM/UN' IS PROMOTION PER UNIT"
370  PRINT "'PROM CT' IS PROMOTION CONSTANT"
371  PRINT "'NET OP PR' IS NET OPERATING PROFIT"
372  PRINT 
373  PRINT "DO YOU WISH TO OVERRIDE ANY PROJECTIONS?(0=NO,1=YES)"
374  INPUT B3
375  IF B3=0 THEN 430
380  PRINT "WHICH LINE";
385  INPUT Y
390  PRINT "NEW VALUES";
395  INPUT V[Y,1],V[Y,2],V[Y,3],V[Y,4],V[Y,5]
400  PRINT 
405  PRINT "ANY OTHERS?(0=NO,1=YES)"
410  INPUT B4
415  PRINT 
420  IF B4=0 THEN 430
425  GOTO 380
430  FOR Y=1 TO 5
435  LET W[1,Y]=V[3,Y]
440  NEXT Y
445  GOSUB 860
450  PRINT 
455  PRINT 
460  LET N=1
465  PRINT "PLANNING BASE P/L"
470  GOSUB 925
475  FOR X=1 TO 5
480  LET T[X]=S[1,X]
485  FOR Y=2 TO 3
490  LET W[Y,X]=S[Y+4,X]
495  LET V[Y+9,X]=W[Y,X]
500  NEXT Y
505  LET V[7,X]=V[9,X]=0
510  LET V[8,X]=W[2,X]
515  LET V[10,X]=W[3,X]
520  NEXT X
525  PRINT "SPECIFY RESPONSE COEF TO BE USED FOR EACH OF 5 YRS"
530  PRINT 
535  PRINT F$,
540  INPUT A[1,1],A[1,2],A[1,3],A[1,4],A[1,5]
545  PRINT G$,
550  INPUT A[2,1],A[2,2],A[2,3],A[2,4],A[2,5]
555  PRINT H$,
560  INPUT A[3,1],A[3,2],A[3,3],A[3,4],A[3,5]
575  PRINT 
580  PRINT "WHICH MARKETING VARIABLE DO YOU WANT TO CHANGE"
581  PRINT "PRICE=1,ADVERTISING=2,PROMOTION=3"
585  GOSUB 630
590  PRINT "SPECIFY NEW LEVELS BY YEAR";
595  INPUT W[Y,1],W[Y,2],W[Y,3],W[Y,4],W[Y,5]
600  PRINT 
605  PRINT "ANY OTHERS?(0=NO,1=YES)"
610  INPUT C9
615  PRINT 
620  IF B9=0 THEN 690
625  GOTO 580
630  INPUT B9
635  LET Y=1
640  IF B9 <> 1 THEN 650
645  RETURN 
650  LET Y=2
655  IF B9=2 THEN 645
660  LET Y=3
665  IF B9=3 THEN 645
670  LET Y=4
675  IF B9=4 THEN 645
680  PRINT "BAD FORMAT RETYPE IT",
685  GOTO 630
690  FOR X=1 TO 5
695  LET R[X]=1
700  LET R[X]=R[X]*(W[1,X]/V[3,X])^A[1,X]
705  LET R[X]=R[X]*(W[2,X]/V[11,X])^A[2,X]
710  LET R[X]=R[X]*(W[3,X]/V[12,X])^A[3,X]
715  NEXT X
725  FOR X=1 TO 5
730  LET S[1,X]=T[X]*R[X]
735  NEXT X
740  FOR X=1 TO 5
745  LET V[8,X]=W[2,X]
750  LET V[10,X]=W[3,X]
755  NEXT X
760  GOSUB 860
765  GOSUB 920
770  PRINT "DO YOU WISH TO TRY ANOTHER PLAN?";
771  PRINT "(0=NO,1=YES)"
775  INPUT B5
780  PRINT 
785  IF B5=1 THEN 580
790  PRINT "DO YOU WISH TO CHANGE A RESPONSE COEFFICIENT?";
791  PRINT "(0=NO,1=YES)"
795  INPUT B6
800  PRINT 
805  IF B6=0 THEN 976
810  PRINT "WHICH ONE?"
811  PRINT "(1=PRICE,2=ADVERTISING,3=PROMOTION)"
815  GOSUB 630
820  PRINT "NEW VALUES";
825  INPUT A[Y,1],A[Y,2],A[Y,3],A[Y,4],A[Y,5]
830  PRINT 
835  PRINT "ANY OTHERS?(0=OO,1=YES)"
840  INPUT B7
845  IF B7=1 THEN 810
855  GOTO 690
860  FOR X=1 TO 5
865  IF N <> 0 THEN 875
870  LET S[1,X]=V[1,X]*V[2,X]
875  LET S[2,X]=S[1,X]*W[1,X]
880  LET S[3,X]=S[1,X]*(V[4,X]+W[1,X]-V[3,X])
885  LET S[4,X]=S[1,X]*V[5,X]+V[6,X]
890  LET S[5,X]=S[3,X]-S[4,X]
895  LET S[6,X]=S[1,X]*V[7,X]+V[8,X]
900  LET S[7,X]=S[1,X]*V[9,X]+V[10,X]
905  LET S[8,X]=S[5,X]-S[6,X]-S[7,X]
910  NEXT X
915  RETURN 
920  PRINT 
925  LET Q$=" "
926  PRINT  USING 5;Q$,1974,1975,1976,1977,1978
930  PRINT 
935  FOR I=1 TO 8
940  FOR J=1 TO 5
945  LET Z[J]=INT(S[I,J]+.5)
950  NEXT J
955  PRINT  USING 5;J$[(I-1)*9+1,I*9],Z[1],Z[2],Z[3],Z[4],Z[5]
960  NEXT I
962  PRINT 
975  RETURN 
976  PRINT "DO YOU WISH TO CONSIDER ANOTHER PRODUCT?";
977  PRINT "(0=NO,1=YES)"
980  INPUT B8
982  IF B8=1 THEN 14
984  GOTO 9999
1000  DATA "TACOS"
1001  DATA 39000.,40000.,40600.,40800.,40800.
1002  DATA .192,.185,.16,.165,.157
1003  DATA 5.25,5.25,5.25,5.25,5.25
1004  DATA 1.9,1.87,1.84,1.81,1.79
1005  DATA 2160,2100,2050,2020,2000
1006  DATA 2114,2105,1561,1610,1500
1007  DATA 5028,5032,5101,5500,5783
1010  DATA "MATZO BALLS"
1011  DATA 21000,24500,28900,32700,36500.
1012  DATA .09,.105,.105,.1,.1
1013  DATA 4.6,4.6,4.1,4.1,4.1
1014  DATA 2.6,2.6,2.2,2.2,2.2
1015  DATA 1440,1480,1510,1530,1540
1016  DATA 2000,2000,2000,2000,2000
1017  DATA 1420,1700,3030,3200,3600
9999  END 
