10  COM R$[72],G$[72],S$[72],X$[72],Z
20  REM**CL2-1**BASIC C.A.I.**GEOGRAPHY**JUNE12, 1972**CHAIN TO CL2-2
25  REM CLIMAT, HP 36760A, 6/74
30  FILES SCRA
40  Z=0
50  PRINT 
60  PRINT 
70  PRINT "HI, MY NAME IS AUDREY, WHAT'S YOURS";
80  INPUT X$
90  PRINT 
100  PRINT "HI, ";X$;"! IN THE FOLLOWING CLIMATE DATA THE MONTHLY"
110  PRINT "AVERAGE TEMPERATURES AND THE MONTHLY AVERAGE RAINFALL"
120  PRINT "ARE GIVEN FOR A SPECIFIC STATION.  I WANT YOU TO FIGURE"
130  PRINT "OUT THE TYPE OF CLIMATE ACCORDING TO THE KOPPEN SYMBOLS"
140  PRINT "AND ALSO THE LOCATION OF THE STATION.  RESPOND BRIEFLY"
150  PRINT "(ONE LINE MAXIMUM) AND IN YOUR OWN WORDS."
170  PRINT 
180  PRINT "    AND YOU HAD BETTER WATCH YOUR STEP BECAUSE I'M VERY"
190  PRINT "IMPATIENT AND I'LL TOLERATE ONLY THREE MISTAKES; AFTER"
200  PRINT "THAT I'LL GIVE UP!!"
210  PRINT 
220  PRINT 
230  PRINT 
240  PRINT "                 TEMP. THEN RAIN BY MONTH"
250  PRINT " J.,  F.,  M.,  A.,  M.,  J.,  J.,  A.,  S.,  O.,  N.,  D"
260  PRINT 
270  PRINT " 24,  29,  41,  57,  68,  76,  79,  77,  68,  55,  39,  27"
280  PRINT " .1,  .2,  .2,  .6, 1.1, 2.9, 8.9, 6.1, 3.0,  .6,  .3,  .1"
290  PRINT 
300  PRINT 
310  PRINT "          YEARLY AVERAGE TEMP. 43.1 DEGREES F."
320  PRINT "          YEARLY RAINFALL TOTAL 35.6 INCHES"
330  PRINT 
340  PRINT 
350  PRINT "WHERE IS THIS STATION IN RELATION TO THE EQUATOR"
360  INPUT G$
370  PRINT 
380  J=10
390  GOSUB 1670
400  IF F <> 1 THEN 430
410  GOSUB 1930
420  PRINT 
430  J=9
440  GOSUB 1670
450  IF F=1 THEN 520
460  PRINT "NOTICE THAT JANUARY TEMPERATURES ARE WELL BELOW THOSE OF"
470  PRINT "JUNE AND JULY. IN THE SOUTHERN HEMISPHERE INSOLATION"
480  PRINT "(INCOMING ENERGY FROM THE SUN) REACHES ITS MAXIMUM IN"
490  PRINT "DECEMBER AND JANUARY. TRY AGAIN."
500  GOSUB 1470
510  GOTO 350
520  PRINT "FINE, ";X$;"! NOW WHAT CAN YOU TELL ME ABOUT THE RELATIVE"
530  PRINT "LATITUDE WITHIN THE NORTHERN HEMISPHERE"
540  INPUT G$
550  PRINT 
560  J=10
570  GOSUB 1670
580  IF F <> 1 THEN 600
590  GOSUB 1930
600  J=2
610  GOSUB 1670
620  IF F=1 THEN 860
630  J=3
640  GOSUB 1670
650  IF F=1 THEN 720
660  J=5
670  GOSUB 1670
680  IF F=1 THEN 790
690  PRINT "WHAT I REALLY WANT TO KNOW IS THIS. IS THE STATION IN"
700  PRINT "THE      POLAR, MID-LATITUDE OR EQUATORIAL REGION"
710  GOTO 540
720  PRINT "IN POLAR ENVIRONMENTS TEMPERATURES IN THE SUMMER MONTHS"
730  PRINT "DO NOT EXCEED AN AVERAGE OF 50 DEGREES F. FOR ANY"
740  PRINT "SIGNIFICANT PERIOD. TEMPERATURES ABOVE 50 COMBINED WITH"
750  PRINT "MODEST PRECIPITATION WOULD LEAD TO FOREST GROWTH."
760  GOSUB 1470
770  PRINT "TRY AGAIN--";
780  GOTO 540
790  PRINT "IF THE STATION WERE NEAR THE EQUATOR SUCH LOW TEMPERATURES"
800  PRINT "COULD ONLY BE REACHED HIGH IN THE MOUNTAINS. AT SUCH A"
810  PRINT "LOCATION THE TEMPERATURE RANGE (JANUARY-JULY) WOULD BE"
820  PRINT "VERY SMALL."
830  GOSUB 1470
840  PRINT "TRY AGAIN--";
850  GOTO 540
860  PRINT "THAT'S IT. NOW, WITHIN THIS MID-LATITUDE REGION IS THE"
870  PRINT "STATION CLOSER TO THE POLEWARD OR TO THE EQUATORIAL INFLUENCE"
880  INPUT G$
890  PRINT 
900  J=10
910  GOSUB 1670
920  IF F <> 1 THEN 940
930  GOSUB 1930
940  J=4
950  GOSUB 1670
960  IF F=1 THEN 1030
970  PRINT "LOOK AGAIN AT THE JANUARY AND JULY TEMPERATURES. DO"
980  PRINT "THESE SIMULATE WHAT YOU WOULD EXPECT IN SAVANNA,"
990  PRINT "GEORGIA OR CANTON, CHINA? THEY ARE A BIT LOW, HUH?"
1000  GOSUB 1470
1010  PRINT "TRY AGAIN--";
1020  GOTO 880
1030  PRINT "MAGNIFICENT--";X$;"--  NOW STATE YOUR PEACE ABOUT THE"
1040  PRINT "RELATIVE LOCATION ON THE CONTINENT OF OUR STATION"
1050  INPUT G$
1060  PRINT 
1070  J=10
1080  GOSUB 1670
1090  IF F <> 1 THEN 1110
1100  GOSUB 1930
1110  J=13
1120  GOSUB 1670
1130  IF F=1 THEN 1460
1140  J=14
1150  GOSUB 1670
1160  IF F=1 THEN 1400
1170  J=15
1180  GOSUB 1670
1190  IF F=1 THEN 1310
1200  J=16
1210  GOSUB 1670
1220  IF F=1 THEN 1270
1230  PRINT " YOUR ANSWER SHOULD TELL ME WHETHER THE STATION IS NEAR"
1240  PRINT "OCEANIC INFLUENCE OR IN THE INTERIOR OF THE LAND MASS"
1250  PRINT "AND, IF NEAR THE COAST, WHICH COAST-EAST OR WEST."
1260  GOTO 1050
1270  PRINT "TOUCHE - MARINE INFLUENCE IS INDICATED BY THE RAINFALL"
1280  PRINT "PATTERN.  HOWEVER, YOU FORGOT TO TELL ME WHICH COAST-"
1290  PRINT "EAST OR WEST?"
1300  GOTO 1050
1310  PRINT "GOOD GUESS - IN AN INTERIOR LOCATION TEMPERATURE RANGE"
1320  PRINT "IS GREAT AND RAINFALL IS CONCENTRATED IN SPRING. IN"
1330  PRINT "THIS CASE THE CONCENTRATION IS SO MARKED AS TO IMPLY"
1340  PRINT "A DIFFERENT CONCLUSION. THE VERY LOW JAN. AND HIGH JULY"
1350  PRINT "RAINFALL SUGGESTS A MONSOON SITUATION-THIS IN TURN"
1360  PRINT "SUGGESTS A LOCATION OTHER THAN A CONTINENTAL INTERIOR"
1370  GOSUB 1470
1380  PRINT "TRY AGAIN--";
1390  GOTO 1050
1400  PRINT "AT A WEST COAST LOCATION IN THE MID-LATITUDES THE"
1410  PRINT "RAINFALL ALMOST ALWAYS SHOWS A CONCENTRATION IN THE"
1420  PRINT "WINTER MONTHS.  IS THIS THE CASE WITH OUR STATION?"
1430  GOSUB 1470
1440  PRINT "TRY AGAIN--";
1450  GOTO 1050
1460  CHAIN "$CL2-2"
1470  REM MISTAKES
1480  PRINT 
1490  LET Z=Z+1
1500  IF Z=1 THEN 1640
1510  IF Z=2 THEN 1610
1520  IF Z=3 THEN 1570
1530  PRINT "SORRY, I GIVE UP.  THAT WAS YOUR FOURTH MISTAKE."
1540  PRINT "GO BACK AND REVIEW THE PREVIOUS LESSON."
1550  PRINT 
1560  STOP 
1570  PRINT "BETTER WATCH YOUR STEP! THAT WAS YOUR THIRD MISTAKE;"
1580  PRINT "ONE MORE AND I'LL GIVE UP!"
1590  PRINT 
1600  RETURN 
1610  PRINT "DANGER LURKS: THAT WAS YOUR SECOND MISTAKE."
1620  PRINT 
1630  RETURN 
1640  PRINT "I'M COUNTING - THAT WAS YOUR FIRST MISTAKE."
1650  PRINT 
1660  RETURN 
1670  RESTORE 
1680  READ R$
1690  IF R$#"DICTIONARY" THEN 1680
1700  READ T,N
1710  IF T=9999 THEN 1670
1720  READ #1,1
1730  FOR I=1 TO N
1740  READ R$
1750  IF T#J THEN 1770
1760  PRINT #1;R$, END 
1770  NEXT I
1780  IF T#J THEN 1700
1790  READ #1,1
1800  IF  END #1 THEN 1890
1810  READ #1;S$
1820  FOR L=1 TO LEN(G$)-LEN(S$)+1
1830  FOR K=1 TO LEN(S$)
1840  IF G$[L+K-1,L+K-1]#S$[K,K] THEN 1870
1850  NEXT K
1860  GOTO 1910
1870  NEXT L
1880  GOTO 1810
1890  F=0
1900  GOTO 1920
1910  F=1
1920  RETURN 
1930  PRINT 
1940  PRINT "   #$%$%%#'&!$#   GOODNESS - SHAME ON YOU !! !!! !"
1950  PRINT "PLEASE DON'T USE WORDS LIKE THAT - IT HURTS MY EGO!"
1960  PRINT 
1970  RETURN 
1980  DATA "DICTIONARY"
1990  DATA 1,10
2000  DATA "QUERY","ASK","WHAT DO","KNOW HOW","DON'T KNOW","DONT KNOW"
2010  DATA "HOW","DON'T UNDER","DONT UNDER","HELP"
2020  DATA 2,9
2030  DATA "MID-LAT","MIDLAT","MIDDLE","HALF WAY","MID WAY","MIDWAY"
2040  DATA "MID-WAY"
2050  DATA "CENTRA","FORTY"
2060  DATA 3,7
2070  DATA "POLAR","POLE","NORTH","ARCTIC","FIFTY","SIXTY","SEVENTY"
2080  DATA 4,5
2090  DATA "POLE","POLAR","POLWARD","NORTH","ARCTIC"
2100  DATA 5,5
2110  DATA "EQUAT","SOUTH","LOW","TWENTY","THIRTY"
2120  DATA 13,1
2130  DATA "EAST"
2140  DATA 14,1
2150  DATA "WEST"
2160  DATA 15,5
2170  DATA "INTERIOR","REMOTE","FAR","INLAND","CONTINENTAL"
2180  DATA 16,7
2190  DATA "COAST","SHORE","SEA","OCEAN","CURRENT","WATER","MARINE"
2200  DATA 17,3
2210  DATA "PEIKING","PEKING","PEIPING"
2220  DATA 18,1
2230  DATA "CHINA"
2240  DATA 19,3
2250  DATA "SHANGHAI","NANKING","WUHAN"
2260  DATA 20,4
2270  DATA "RUSSIA","SOVIET","USSR","U.S.S.R."
2280  DATA 10,12
2290  DATA "HELL","SCREW","UCK","BALLS","PISS","FART","CRAP","BITCH"
2300  DATA "GOD","DAMN","DAMM"
2310  DATA "SHIT"
2320  DATA 21,1
2330  DATA "JAPAN"
2340  DATA 22,1
2350  DATA "MONGOLIA"
2360  DATA 23,1
2370  DATA "HANKOW"
2380  DATA 24,6
2390  DATA "HARBIN","MUKDEN","FUSHUN","FUSHIN","ANSHAN","KIRIN"
2400  DATA 9,1
2410  DATA "NORTH"
2420  DATA 26,6
2430  DATA "TIENTSIN","DAIREN","PORT ARTHUR","LUTA","TALIEN","TAKU"
2440  DATA 12,6
2450  DATA "EAST","WEST","ORIENT","OCCIDENT","LAND","WATER"
2460  DATA 27,1
2470  DATA "KOREA"
2480  DATA 25,5
2490  DATA "ASIA","FAR EAST","ORIENTAL","CHINA","PACIFIC"
2500  DATA 28,2
2510  DATA "FORMOSA","TAIWAN"
2520  DATA 9999,0
2530  END 
