1  REM *** HP BASIC PROGRAM LIBRARY *******************************
2  REM
3  REM     TALK:  COMMUNICATIONS WITHIN A TIME-SHARING SYSTEM
4  REM
5  REM      36222  REV A
6  REM
7  REM *** CONTRIBUTED PROGRAM ************************************
8  REM
9  REM
10  PRINT " 'TALK' HAS BEEN MADE AVAILABLE SO THAT ACCOMP USERS CAN REPORT"
20  PRINT "PROBLEMS, MAKE SUGGESTIONS, AND GENERALLY COMMUNICATE MORE EASILY"
30  PRINT "WITHIN OUR TIME-SHARING SYSTEM.  THE MESSAGE YOU ENTER IS RECORDED"
40  PRINT "ON A FILE WHICH IS READ FROM TIME TO TIME BY ACCOMP PERSONNEL.  WE'LL"
50  PRINT "TAKE WHATEVER ACTION WE CAN TO MAKE ACCOMP COMPUTING MORE EASY FOR YOU."
60  PRINT 
70  PRINT "TO USE 'TALK' PLEASE TYPE:"'10'10'13"HELLO-B123,ACCOMP"'10'13"GET-TALK"'10'13"RUN"'10
110  PRINT '10"ENTER YOUR MESSAGE AFTER THE QUESTION MARK.  WHEN FINISHED"
120  PRINT "TYPE 'END' AFTER THE QUESTION MARK.  PLEASE INCLUDE YOUR NAME, ALSO"
130  PRINT "PHONE NUMBER OR ADDRESS IF YOU EXPECT AN ANSWER."'10
140  FILES TLKFIL
150  DIM A$[72]
160  PRINT "YOUR MESSAGE:"'10
170  FOR I=1 TO 1000
180  READ #1;A$
190  IF A$="@" THEN 210
200  NEXT I
210  READ #1,1
220  FOR U=1 TO I-1
230  READ #1;A$
240  NEXT U
250  FOR N=1 TO 500
260  INPUT A$
270  PRINT #1;A$
280  IF A$="END" THEN 300
290  NEXT N
300  PRINT '10'10"THANK YOU!"
310  STOP 
320  REM:  MESSAGE PRINTOUT SECTION
330  FOR L=1 TO 1000
340  IF  END #1 THEN 390
350  READ #1;A$
360  IF A$="@" THEN 390
370  PRINT A$
380  NEXT L
390  PRINT #1,1
400  FOR I=1 TO 1000
410  IF  END #1 THEN 440
420  PRINT #1;"@"
430  NEXT I
440  END 
