100  REM *** STARS *** STARS *** STARS *** STARS *** STARS ***
110  REM *** COPYRIGHT 1974 BY PCC, P.O. BOX 310, MENLO PARK CA
120  PRINT "WELCOME TO MY GALAXY. I'M IN CHARGE OF THE STARS HERE."
130  PRINT "PLAY MY GAME *STARS* AND GET SOME STARS FOR YOURSELF!"
140  PRINT 
150  PRINT "WANT TO KNOW HOW TO PLAY";
160  INPUT Z$[1,1]
170  IF Z$ <> "Y" THEN 280
180  REM *** HERE IS HOW TO PLAY
190  PRINT 
200  PRINT "I WILL THINK OF A WHOLE NUMBER FROM 1 TO 100."
210  PRINT "TRY TO GUESS MY NUMBER. AFTER YOU GUESS, I"
220  PRINT "WILL TYPE ONE OR MORE STARS (*"'7"). THE CLOSER"
230  PRINT "YOU ARE TO MY NUMBER, THE MORE STARS WILL I TYPE."
240  PRINT "ONE STAR (*"'7") MEANS YOU ARE FAR AWAY FROM MY"
250  PRINT "NUMBER. SEVEN STARS (*"'7"*"'7"*"'7"*"'7"*"'7"*"'7"*"'7") MEANS YOU ARE VERY,"
260  PRINT "VERY, VERY CLOSE TO MY NUMBER!!!"'7'7'7'7'7'7'7
270  REM *** COMPUTER 'THINKS' OF A NUMBER FROM 1 TO 100
280  LET X=INT(100*RND(0))+1
290  PRINT 
300  PRINT "OK, STARSEEKER, I AM THINKING OF A NUMBER. START GUESSING."
310  REM *** GUESSING BEGINS
320  LET N=1
330  PRINT 
340  PRINT "WHAT IS YOUR GUESS";
350  INPUT G
360  IF G=X THEN 550
370  LET D=ABS(G-X)
380  IF D >= 64 THEN 500
390  IF D >= 32 THEN 490
400  IF D >= 16 THEN 480
410  IF D >= 8 THEN 470
420  IF D >= 4 THEN 460
430  IF D >= 2 THEN 450
440  PRINT " *"'7;
450  PRINT " *"'7;
460  PRINT " *"'7;
470  PRINT " *"'7;
480  PRINT " *"'7;
490  PRINT " *"'7;
500  PRINT " *"'7;
510  PRINT 
520  LET N=N+1
530  GOTO 330
540  REM *** PLAYER HAS GUESSED THE GALACTIC NUMBER
550  FOR K=1 TO 18
560  PRINT " **"'7;
570  NEXT K
580  PRINT "!!!"'7'7'7'7'7'7'7'7'7'7'7'7'7'7'7
590  PRINT "THAT'S IT!!!"'7'7'7'7'7" YOU GUESSED MY COSMIC NUMBER IN";N;"GUESSES."
600  PRINT 
610  PRINT "WANT TO PLAY AGAIN";
620  INPUT Z$[1,1]
630  IF Z$="Y" THEN 280
640  PRINT "OK, GOODBYE FOR NOW. PLAY WITH ME AGAIN SOMEWHEN."
650  END 
