10  REM SMOG, FROM DEC
20  DIM A$[5]
30  PRINT "DO YOU WANT INSTRUCTIONS (YES OR NO)";
40  INPUT A$
50  IF A$[1,1]="N" THEN 320
60  PRINT 
70  PRINT "THIS PROGRAM REPRESENTS A MODEL OF A CITY WITH A CERTAIN"
80  PRINT "CONDITIONS WHICH YOU MAY SPECIFY.  THE PROGRAM WILL THEN"
90  PRINT "PRINT OUT THE RESULTING SMOG PATTERNS BY HOUR OF THE DAY."
100  PRINT 
110  PRINT "CARS PER MILE OF ROAD"
120  PRINT "EXAMPLES:  LOS ANGELES   200 CARS PER MILE"
130  PRINT "           DETROIT       100"
140  PRINT "           TULSA          25"
150  PRINT 
160  PRINT "SMOG GENERATION CONSTANT"
170  PRINT "EXAMPLES:  1950 AUTO   .005"
180  PRINT "           1972 AUTO   .001"
190  PRINT "           BUS         .010"
200  PRINT 
210  PRINT "DAYTIME SMOG BREAKDOWN RATE (% PER HOUR)"
220  PRINT "EXAMPLES:  CLEAR   0.02"
230  PRINT "           CLOUDY  0.01"
240  PRINT 
250  PRINT "NIGHTTIME SMOG BREAKDOWN RATE (% PER HOUR)"
270  PRINT "           COOL  0.10"
280  PRINT 
290  PRINT "SMOG DISPERSION FROM WEATHER (% PER HOUR)"
300  PRINT "EXAMPLES:  HIGH WIND AND RAIN   1.00"
310  PRINT "           NO WIND AND DRY      0.01"
320  T=7
330  S=1
340  PRINT '10'10'10"HOW MANY CARS PER ROAD MILE IN SMOG CITY";
350  INPUT C
360  PRINT "WHAT IS THE AVERAGE SMOG GENERATION CONSTANT";
370  INPUT L1
380  PRINT "WHAT IS THE DAYTIME SMOG BREAKDOWN RATE";
390  INPUT R1
400  PRINT "WHAT IS THE NIGHTTIME SMOG BREAKDOWN RATE";
410  INPUT R2
420  PRINT "WHAT IS THE SMOG DISPERSION RATE FROM WEATHER";
430  INPUT R3
440  PRINT "HOW MANY HOURS TO PLOT";
450  INPUT Z
460  PRINT '10'10'10'10
470  PRINT "HOUR","SMOG LEVEL"
480  PRINT 
490  FOR Q=1 TO Z
500  R=R1
510  K1=L1
520  T1=INT((T-6)/12)
530  IF T1/2=INT(T1/2) THEN 560
540  K1=0
550  R=R2
560  S=S+K1*C*10-R*S-R3*S
570  IF S>0 THEN 590
580  S=0
590  T=T+1
600  T3=INT(T/12)
610  T2=T-T3*12+1
620  IF T3/2=INT(T3/2) THEN 650
630  PRINT T2" PM",S,TAB(32+2*S);"X"
640  GOTO 660
650  PRINT T2" AM",S,TAB(32+2*S);"X"
660  NEXT Q
670  END 
