10  REM    : VISUAL SPEED AND ACCURACY TESTS
20  REM    : WRITTEN BY JOHN J. STEFANI
30  REM    : REWRITTEN BY ALEX ATHAS 1/20/77
40  REM    : FOR EDP RESOURCE CENTER
50  DIM A$[72],B$[72],C$[72],D$[72],E$[72],F$[72],G$[72],H$[3]
60  DIM I$[72]
70  FILES *
80  DEF FNR()=INT(*RND(TIM(4)))+1
90  LET C=W=0
100  IF TIM(1)>11 THEN 130
110  PRINT "GOOD MORNING, ";
120  GOTO 170
130  IF TIM(1)>15 THEN 140
140  PRINT "GOOD AFTERNOON, ";
150  GOTO 170
160  PRINT "GOOD EVENING, ";
170  PRINT "THIS IS A PROGRAM TO DEVELOP YOUR SIGHT CHECKING SKILL."
180  PRINT "MANY EMPLOYERS GIVE SIMILAR VISUAL SPEED AND ACCURACY TESTS."
190  PRINT ""
200  PRINT "WHAT IS YOUR NAME";
210  INPUT I$
220  PRINT "WHICH CATEGORY DO YOU WANT TO BE TESTED IN, "I$":"
230  PRINT ""
240  PRINT "  1.  INDIVIDUAL'S NAMES"
250  PRINT "  2.  COMPANY NAMES"
260  PRINT "  3.  NUMBERS"
270  PRINT "  4.  STREET ADDRESSES"
280  PRINT "  5.  NAMES AND ADDRESSES COMBINED"
290  PRINT 
300  PRINT "TYPE THE NUMBER OF YOUR CHOICE AND PRESS RETURN KEY (1-5)";
310  INPUT A
320  PRINT 
340  PRINT "YOU CAN RACE AGAINS THE CLOCK--HOW MANY SECONDS WOULD YOU LIKE"
350  PRINT "FOR EACH PROBLEM--TYPE ANY NUMBER BETWEEN 1 AND 12";
360  INPUT H$
370  PRINT 
380  IF H$#"U" THEN 410
390  LET B=60
400  GOTO 430
410  CONVERT H$ TO B,1520
420  IF B<0 OR B>12 THEN 350
430  PRINT "TYPE AN 'S' IF THE TWO ITEMS RIGHT NEXT TO EACH OTHER ARE"
440  PRINT "THE SAME AND A 'D' IF THEY ARE DIFFERENT."
450  PRINT 
460  PRINT "****************HERE WE GO*****************"
470  PRINT ""
480  RESTORE 
490  DATA "$ZSAME1","1 -- INDIVIDUAL'S NAMES"
500  DATA "$ZSAME2","2 -- COMPANY NAMES"
510  DATA "$ZSAME3","3 -- NUMBERS"
520  DATA "$ZSAME4","4 -- STREET ADDRESSES"
530  DATA "$ZSAME5","5 -- NAMES AND ADDRESSES COMBINED"
540  FOR I=1 TO A
550  IF TYP(0)=3 THEN 590
560  READ A$,B$
570  NEXT I
580  PRINT "  "B$
590  PRINT 
600  ASSIGN A$,1,R
610  LET C=D=A1=0
620  READ #1,1
630  IF  END #1 THEN 670
640  READ #1;A$
650  LET A1=A1+1
660  GOTO 640
670  FOR H1=1 TO 10
680  READ #1,1
690  FOR H=1 TO FNR(A1)
700  READ #1;A$
710  NEXT H
720  FOR I=1 TO LEN(A$)
730  IF A$[I,I]=" " THEN 760
740  NEXT I
750  STOP 
760  IF A$[I+1,I+1]#" " THEN 740
770  FOR J=1 TO 33-I
780  PRINT " ";
790  NEXT J
800  FOR J=1 TO I-1
810  PRINT A$[J,J];
820  NEXT J
830  PRINT "    ";
840  FOR J=I+2 TO LEN(A$)
850  PRINT A$[J,J];
860  NEXT J
870  PRINT "?";
880  ENTER B,A,C$
890  IF A>0 THEN 920
900  PRINT '13"T"
910  GOTO 1010
920  IF A$[1,I-1]=A$[I+2,LEN(A$)] THEN 950
930  LET X$="D"
940  GOTO 960
950  LET X$="S"
960  IF C$=X$ THEN 990
970  PRINT "X"
980  GOTO 1010
990  LET C=C+1
1000  PRINT "C"
1010  NEXT H1
1020  PRINT '13'10'10"YOU GOT"C"RIGHT OUT OF 10."
1030  PRINT 
1040  PRINT "DO YOU WANT ANOTHER TEST, "I$;
1050  INPUT H$
1060  IF H$[1,1]="N" THEN 1230
1070  IF H$[1,1]="Y" THEN 1100
1080  PRINT "YES OR NO ONLY, "I$"!"
1090  GOTO 1030
1100  PRINT '15'14"HOW MANY SECONDS";
1110  INPUT H$
1120  IF H$#"U" THEN 1150
1130  LET B=60
1140  GOTO 1170
1150  CONVERT H$ TO B,2217
1160  IF B<0 OR B>12 THEN 1100
1170  PRINT '15'14
1180  PRINT "WHICH CATEGORY DO YOU WANT TO BE TESTED IN (1-5)";
1190  INPUT H$
1200  CONVERT H$ TO A,2270
1210  IF A<1 OR A>5 THEN 1180
1220  GOTO 450
1230  PRINT "'TILL NEXT TIME, "I$", ANYTIME..."'7'7'7'7'7'7'7'7'7
1240  END 
