1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        LOGIC:  LOGIC EXAMINATION PROGRAMS
4  REM        LOGIC5, PART 5 OF 5
5  REM        36251  REV B  --  10/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  *************************************
8  REM
10  REM  *** AARDWOLF & COMPANY WRITING TEAM ***  JOHN C. RIDGES
20  REM  *** LOGIC5 *** 0846 WORDS *** VERSION 2 ***
30  I1=1
40  I2=I1+I1
50  C=N=Z= NOT I1
60  DIM A$[72],B$[72],C$[72],D$[72],E$[72],F$[72]
70  IF TYP( NOT I1)=I1+I2 THEN 510
80  READ A$,B$,C$,D$,E$,F$
90  PRINT '10'10'10"IF "E$" THEN "C$" AND,"'13'10"IF "C$" THEN "A$"."'13'10'10'10'10"CAN WE CONCLUDE---"'10
100  MAT A=ZER[I2]
110  FOR K=I1 TO I2*I2
120  FOR M=I1 TO I2
130  A[M]=INT(RND(I1)*6)+I1
140  IF M=I1 AND A[I1]=Z OR M=I2 AND (A[I1]=A[I2] OR (A[I1]-A[I2])/I2#INT((A[I1]-A[I2])/I2)) OR A[M]=I1+I2 THEN 130
150  NEXT M
160  PRINT "     IF ";
170  GOSUB 220
180  M=M+I1
190  PRINT " THEN ";
200  GOSUB 220
210  GOTO 330
220  GOTO A[M-I2] OF 230,250,640,270,290,310
230  PRINT A$;
240  RETURN 
250  PRINT B$;
260  RETURN 
270  PRINT D$;
280  RETURN 
290  PRINT E$;
300  RETURN 
310  PRINT F$;
320  RETURN 
330  Z$="Y"
340  Y$="N"
350  INPUT X$[I1,I1]
360  IF A[I1]>A[I2] THEN 390
370  Z$="N"
380  Y$="Y"
390  IF X$=Z$ THEN 450
400  IF X$=Y$ THEN 430
410  PRINT "WHAT";
420  GOTO 330
430  PRINT "WRONG---STUDY CONTRAPOSITIVE AND HYPOTHETICAL SYLLOGISM."
440  GOTO 470
450  PRINT "CORRECT."
460  C=C+I1
470  Z=A[I1]
480  N=N+I1
490  NEXT K
500  GOTO 70
510  PRINT '10"YOU ANSWERED"C"OUT OF"N"QUESTIONS CORRECTLY FOR A"'13'10"FINAL SCORE OF"INT(C/N*100)"%."'10
520  DATA "I LIVE IN THE U.S.","I DON'T LIVE IN DENVER"
530  DATA "I LIVE IN COLORADO","I DON'T LIVE IN COLORADO"
540  DATA "I LIVE IN DENVER","I DON'T LIVE IN THE U.S."
550  DATA "ABCD IS A PARALLELOGRAM","ABCD IS NOT A SQUARE"
560  DATA "ABCD IS A RECTANGLE","ABCD IS NOT A RECTANGLE"
570  DATA "ABCD IS A SQUARE","ABCD IS NOT A PARALLELOGRAM"
580  DATA "UNEMPLOYMENT RISES","SUPPLY DOES NOT EXCEED DEMAND"
590  DATA "PRODUCTION DROPS","PRODUCTION DOES NOT DROP"
600  DATA "SUPPLY EXCEEDS DEMAND","UNEMPLOYMENT DOES NOT RISE"
610  DATA "IT HAS ONE SHORT LEG","A ZERK DOES NOT HAVE 3 HEADS"
620  DATA "IT LIVES IN COLORADO","IT DOES NOT L"'9"IVE IN COLORADO"
630  DATA "A ZERK HAS 3 HEADS","IT HAS LEGS OF EQUAL LENGTH"
640  END 
