1  REM ****  HP BASIC PROGRAM LIBRARY  ********************************
2  REM
3  REM       LOGIC:  LOGIC EXAMINATION PROGRAMS
4  REM       LOGIC1, PART 1 OF 5
5  REM       36251  rev B  --  10/73
6  REM
7  REM ****  CONTRIBUTED PROGRAM  *************************************
10  REM  *** AARDWOLF & COMPANY WRITING TEAM ***  PHILIP J. TUBB
20  REM  *** LOGIC1 *** 0847 WORDS *** VERSION 3 ***
30  DIM A$[72],B$[72],C$[72],D$[72]
40  O4=4
50  O1=O4/O4
60  N=C=O1-O1
70  O2=O1+O1
80  IF TYP(O1-O1)#O2 THEN 540
90  READ A$,B$
100  READ C$,D$
110  PRINT '10'10'10"IF "A$" THEN "C$"."'10
120  FOR A=O1 TO O4
130  B=INT(O4*RND(O1))+O1
140  FOR D=O1 TO A-O1
150  IF B=A[D] THEN 130
160  NEXT D
170  A[A]=B
180  PRINT '10"O.K.--"'13'10"NOW ASSUME ";
190  GOSUB ABS(6*(B/O2=INT(B/O2))-B) OF 460,480,500,520
200  PRINT "."'13'10"CAN WE CONCLUDE ";
210  GOSUB ABS(O4*(B#O4)-B) OF 460,480,500,520
220  INPUT X$[O1,O1]
230  IF X$="N" THEN 390
240  IF X$="Y" THEN 270
250  PRINT "WHAT";
260  GOTO 220
270  IF B>O2 THEN 330
280  PRINT "CORRECT."
290  C=C+O1
300  N=N+O1
310  NEXT A
320  GOTO 80
330  PRINT "WRONG, THE CONCLUSION IS INVALID."'13'10"YOU ";
340  IF B=O4 THEN 370
350  PRINT "DENIED THE ANTECEDENT."
360  GOTO 300
370  PRINT "AFFIRMED THE CONSEQUENT."
380  GOTO 300
390  IF B>O2 THEN 280
400  PRINT "WRONG, THE CONCLUSION IS VALID BY MODUS ";
410  IF B=O2 THEN 440
420  PRINT "PONENS."
430  GOTO 300
440  PRINT "TOLLENS."
450  GOTO 300
460  PRINT A$;
470  RETURN 
480  PRINT B$;
490  RETURN 
500  PRINT C$;
510  RETURN 
520  PRINT D$;
530  RETURN 
540  PRINT '10"YOU ANSWERED"C"OUT OF"N"QUESTIONS CORRECTLY FOR A"'13'10"FINAL SCORE OF"INT(C/N*100)"%."'10
550  DATA "PAUL PLAYS","PAUL DOES NOT PLAY","THE TEAM WINS","THE TEAM DOES NOT WIN"
560  DATA "ABCD IS A SQUARE","ABCD IS NOT A SQUARE","IT HAS FOUR RIGHT ANGLES","IT HASN'T FOUR RIGHT ANGLES"
570  DATA "JOE STUDIES","JOE DOESN'T STUDY","HE PASSES THE COURSE","HE FAILS THE COURSE"
580  DATA "A MAN IS PRESIDENT","A MAN IS NOT PRESIDENT","HE IS AT LEAST 40","HE IS YOUNGER THAN 40"
590  DATA "X AND Y ARE BOTH POSITIVE","X AND Y ARE NOT BOTH POSITIVE","X*Y>0","X*Y<=0"
600  DATA "THE WEATHER IS WINDY","THE WEATHER IS CALM","THE BOAT SINKS","THE BOAT FLOATS"
610  DATA "YOU RUN THIS PROGRAM","YOU DON'T RUN THIS PROGRAM","YOU LEARN SOMETHING","YOU LEARN NOTHING"
620  END 
