1  REM ***  JOB-O; BY ARTHUR CUTLER, FRANCIS FERRY, ROBERT KAUK,
2  REM ***   AND ROBERT ROBINETTE * C. 1972 CFKR
3  REM ***  TIME SHARE VERSION BY TOM KRUCKEWITT, DEC. 1972
4  DIM N$[25],J$[72],F[119],E$[18],O$[9],W$[10],R[9]
5  FILES *
6  ASSIGN "$JOBS",1,R
7  O$="123456789"
8  PRINT 
9  PRINT 
10  PRINT "HI THERE!!!  THIS IS JOB-O SPEAKING."
11  PRINT 
12  PRINT "ARE YOU A COUNSELOR (TYPE IN YES OR NO)";
13  INPUT W$
14  IF W$="YES" THEN 138
15  IF W$="NO" THEN 18
16  PRINT "SORRY, I DIDN'T UNDERSTAND THAT."
17  GOTO 12
18  PRINT 
19  PRINT "I'M HERE TO HELP YOU IN SELECTING A CAREER THAT FITS YOU."
20  PRINT 
21  PRINT "THE DIRECTIONS ARE SIMPLE..."
22  PRINT "   JUST READ THE QUESTIONS I ASK YOU AND TYPE IN YOUR ANSWER."
23  PRINT "   WAIT FOR ME TO GIVE YOU A LIST OF CAREERS,"
24  PRINT "   THEN FROM THE LIST OF CAREERS PICK YOUR FAVORITE(S) AND"
25  PRINT "FIND OUT MORE ABOUT THEM FROM YOUR CAREER CENTER."
26  PRINT 
27  PRINT "OK, YOU KNOW MY NAME... WHAT'S YOURS";
28  INPUT N$
29  PRINT 
30  PRINT "ALL RIGHT "N$;", LET'S GET GOING!"
31  PRINT 
32  PRINT 
33  PRINT "HOW LONG DO YOU WANT TO STAY IN SCHOOL "N$;"?"
34  PRINT "DO YOU WANT TO..."
35  PRINT 
36  PRINT "1) COMPLETE HIGH SCHOOL"
37  PRINT "2) COMPLETE APPRENTICESHIP, TECHNICAL OR SPECIAL TRAINING"
38  PRINT "3) COMPLETE A TWO YEAR COLLEGE PROGRAM"
39  PRINT "4) COMPLETE A FOUR YEAR COLLEGE PROGRAM"
40  PRINT "5) COMPLETE FIVE OR MORE YEARS OF COLLEGE"
41  PRINT 
42  PRINT "(PICK THE NUMBER OF THE ONE THAT FITS YOU)"
43  PRINT 
44  L=5
45  Q=1
46  GOSUB 205
47  PRINT 
48  PRINT 
49  PRINT "WHAT WOULD YOU LIKE TO DO "N$;"?"
50  PRINT 
51  PRINT "1) ARTISTIC - LITERARY (ART, DRAMA, MUSIC, DESIGNING,"
52  PRINT "     PHOTOGRAPHY, TV, RADIO, NEWS REPORTING, LAW, WRITING,"
53  PRINT "     LIBRARY WORK, DRAFTING, ETC."
54  PRINT 
55  PRINT "2) BUSINESS, CLERICAL, SALES (DATA PROCESSING, ACCOUNTING,"
56  PRINT "     TYPING, OFFICE WORK, SELLING, MANAGEMENT, ETC."
57  PRINT 
58  PRINT "3) SOCIAL - PERSONAL SERVICE (SOCIAL WORK, TEACHING, NURSING,"
59  PRINT "     POLICE, PROBATION, RECREATION, COSMETOLOGY, STEWARDESS,"
60  PRINT "     CHEF, ETC.)"
61  PRINT 
62  PRINT "4) AGRICULTURE - CONSERVATION (WILDLIFE, FORESTRY, FARMING-"
63  PRINT "     RANCHING, ECOLOGY, MINING, LOGGING, ETC.)"
64  PRINT 
65  PRINT "5) MECHANICAL (CONSTRUCTION, REPAIRING, OPERATING EQUIPMENT,"
66  PRINT "     AVIATION, TRANSPORTATION, ASSEMBLING, ETC.)"
67  PRINT 
68  PRINT "6) SCIENTIFIC (MEDICINE, ENGINEERING, MATHEMATICS, ELECTRONICS,"
69  PRINT "     ETC.)"
70  PRINT 
71  PRINT "(TYPE IN THE NUMBER OF THE GROUP OF ACTIVITIES WHICH YOU"
72  PRINT "WOULD REALLY ENJOY DOING AND WOULD MAKE YOU HAPPY)"
73  PRINT 
74  L=6
75  Q=2
76  GOSUB 205
77  PRINT 
78  PRINT 
79  PRINT "HOW DO YOU SEE YOURSELF "N$;"?"
80  PRINT 
81  PRINT "THE CHOICES FOR THE NEXT SEVEN QUESTIONS ARE GIVEN AS FOLLOWS:"
82  PRINT 
83  PRINT "      1) ALWAYS       3) SOMETIMES      5) RARELY"
84  PRINT "      2) OFTEN        4) OCCASIONALLY   6) NEVER"
85  PRINT 
86  PRINT "PICK THE ONE THAT FITS YOU BEST IN THE FOLLOWING STATEMENTS."
87  PRINT "(BE HONEST WITH YOURSELF)"
88  FOR Q=3 TO 9
89  READ J$
90  PRINT  USING 91;LIN(1),Q
91  IMAGE #,D,") I WOULD LIKE A JOB IN WHICH I "
92  IF LEN(J$)>37 THEN 95
93  PRINT J$
94  GOTO 99
95  FOR X=37 TO 1 STEP -1
96  IF J$[X,X]=" " THEN 98
97  NEXT X
98  PRINT J$[1,X-1];LIN(1);TAB(3);J$[X+1]
99  PRINT 
100  GOSUB 205
101  NEXT Q
102  DATA "WORK WITH PEOPLE.","TELL PEOPLE WHAT TO DO."
103  DATA "WOULD BE CLOSE AND FRIENDLY WITH PEOPLE."
104  DATA "WOULD BE PHYSICALLY ACTIVE.","WORK WITH MY HANDS."
105  DATA "WORK WITH FACTS AND FIGURES AND APPLY THEM TO MY JOB."
106  DATA "COULD BE CREATIVE AND WORK WITH IDEAS."
107  PRINT 
108  PRINT 
109  PRINT "OK, I'LL CHECK YOUR RESPONSES AGAINST WHAT I HAVE IN MY FILES."
110  PRINT "THE MORE RESPONSE MATCHES YOU HAVE, THE BETTER THE JOB LOOKS."
111  PRINT "I'LL SEE WHAT I CAN DIG UP FOR YOU."
112  PRINT "STICK AROUND "N$;", THIS WILL TAKE A FEW MINUTES."
113  PRINT 
114  PRINT 
115  GOSUB 164
116  PRINT 
117  PRINT "TAKE THE LIST I'VE SUPPLIED AND DISCUSS THE RESULTS WITH A"
118  PRINT "MEMBER OF THE CAREER CENTER STAFF."
119  PRINT 
120  PRINT "AFTER YOUR CONFERENCE, CONSIDER THE RECOMMENDATIONS IN TERMS OF:"
121  PRINT 
122  PRINT "   EMPLOYMENT OUTLOOK"
123  PRINT "   PROBABLE EARNINGS, FRINGE BENEFITS, ETC."
124  PRINT "   CHANCES FOR ADVANCEMENT"
125  PRINT "   CHANCES FOR SUCCESS"
126  PRINT "   WORKING CONDITIONS"
127  PRINT "   CHANCES FOR PRESTIGE AND RECOGNITION"
128  PRINT 
129  PRINT 
130  PRINT "FOR ADDITIONAL INFORMATION, CONSULT THE CAREER RESOURCE CENTER,"
131  PRINT "YOUR FRIENDS, LIBRARY, TEACHERS AND COUNSELORS."
132  PRINT 
133  PRINT "REMEMBER:  CAREER DAY IS EVERY DAY...NOT JUST ONCE A SEMESTER!!!"
134  PRINT 
135  PRINT "GOODBYE "N$
136  PRINT 
137  GOTO 213
138  PRINT 
139  PRINT "INSTRUCTIONS:"
140  PRINT "    1) TYPE IN THE STUDENT'S NAME."
141  PRINT "    2) TYPE IN THE STUDENT'S RESPONSES, SEPARATED BY COMMAS."
142  PRINT "THANK YOU."
143  PRINT "NAME";
144  INPUT N$
145  PRINT "RESPONSES";
146  MAT  INPUT R
147  FOR Q7=1 TO 9
148  IF R[Q7]<0 OR R[Q7]>6 OR R[Q7] <> INT(R[Q7]) THEN 151
149  NEXT Q7
150  GOTO 153
151  PRINT "ERROR IN RESPONSE NO."Q7;"-- PLEASE RETYPE ALL RESPONSES"
152  GOTO 145
153  REM
154  PRINT "BEGINNING EXECUTION"
155  PRINT 
156  REM
157  IF N$="*" THEN 161
158  PRINT "--------------------"
159  PRINT "RESULTS FOR "N$":"
160  GOSUB 164
161  PRINT "--------------------"
162  PRINT "***  END OF EXECUTION"
163  GOTO 213
164  MAT  PRINT  USING 165;R
165  IMAGE "RESPONSES: ",8(D,","),D
166  PRINT 
167  PRINT 
168  MAT F=ZER
169  FOR A=9 TO 5 STEP -1
170  P=0
171  FOR B=1 TO 119
172  READ #1;E$,J$
173  IF F[B]=1 THEN 190
174  M=0
175  FOR C=1 TO 9
176  IF O$[R[C],R[C]]=E$[2*C-1,2*C-1] THEN 179
177  IF O$[R[C],R[C]]=E$[2*C,2*C] THEN 179
178  GOTO 180
179  M=M+1
180  NEXT C
181  IF M=A THEN 185
182  IF M>4 THEN 190
183  F[B]=1
184  GOTO 190
185  IF P=1 THEN 188
186  PRINT "HAVE"A;"MATCHES:"
187  P=1
188  PRINT TAB(4);J$
189  GOTO 183
190  NEXT B
191  READ #1,1
192  PRINT 
193  NEXT A
194  RETURN 
195  PRINT "WHAT DO YOU SAY ";
196  RETURN 
197  PRINT "WHAT'S YOUR DECISION ";
198  RETURN 
199  PRINT "WHICH ONE DID YOU PICK ";
200  RETURN 
201  PRINT "WHICH CHOICE FITS YOU ";
202  RETURN 
203  PRINT "WHAT IS YOUR SELECTION ";
204  RETURN 
205  GOSUB 1+(5*RND(0)) OF 195,197,199,201,203
206  PRINT N$;
207  INPUT R[Q]
208  PRINT 
209  IF R[Q]>0 AND R[Q] <= L AND R[Q]=INT(R[Q]) THEN 212
210  PRINT "SORRY, I DIDN'T UNDERSTAND THAT."
211  GOTO 205
212  RETURN 
213  IF W$#"YES" THEN 217
214  PRINT "ANOTHER ENTRY..YES OR NO";
215  INPUT W$
216  IF W$="YES" THEN 143
217  END 
