10  REM **** HP TIME-SHARED BASIC PROGRAM LIBRARY **********************
20  REM
30  REM          DROS:  GENETIC CHARACTERISTICS
40  REM
50  REM          36300 (A833) REV A -- 10/71
60  REM
70  REM **** CONTRIBUTED PROGRAM  *****************************************
80  REM-DROS--COPYRIGHT 1970--POLYTECHNIC INSTITUTE OF BROOKLYN
90  REM THIS PROGRAM DEVELOPED BY R. COOPERMAN--JOHN GLENN HIGH SCHOOL
100  REM  REVISED BY C.LOSIK  7-9-70
110  LET C=0
120  REM  C IS THE RUN COUNTER, ALL INPUTS ARE TEMPORARY
130  LET B=0
140  REM WE ASSIGN EACH GENE A "WEIGHT",
150  REM AND COMBINE THE WEIGHTS TO GIVE RESULTS !
160  PRINT "THIS PROGRAM IS DESIGNED TO GIVE THE GENETIC RESULTANT TRAITS"
170  PRINT "OF OFFSPRING WHOSE PARENTAGE WAS DISCUSSED IN PROGRAM 'GAMGN'"
180  PRINT 
190  PRINT "ARE YOU READY? HERE WE GO."
200  PRINT 
210  PRINT "FOR THE SPERM CELL, WHAT IS 'A'? (TYPE 1 OR 2)";
220  INPUT X
230  IF X=1 THEN 260
240  LET X=5
250  GOTO 270
260  LET X=10
270  PRINT "                    WHAT IS 'B'";
280  INPUT Y
290  IF Y=1 THEN 320
300  LET Y=100
310  GOTO 330
320  LET Y=50
330  PRINT "                    WHAT IS 'C'";
340  INPUT W
350  IF W=1 THEN 380
360  LET W=0
370  GOTO 390
380  LET W=500
390  PRINT "                    WHAT IS 'D'";
400  INPUT Z
410  PRINT "FOR THE EGG CELL, WHAT IS 'A'? (TYPE 1 OR 2)";
420  INPUT L
430  IF L=1 THEN 460
440  LET L=5
450  GOTO 470
460  LET L=10
470  PRINT "                  WHAT IS 'B'";
480  INPUT M
490  IF M=1 THEN 520
500  LET M=100
510  GOTO 530
520  LET M=50
530  PRINT "                  WHAT IS 'C'";
540  INPUT N
550  IF N=1 THEN 580
560  LET N=0
570  GOTO 590
580  LET N=500
590  PRINT "                  WHAT IS 'D'";
600  INPUT O
610  LET T=W+N
620  LET S=Y+M
630  LET R=X+L
640  LET C=C+1
650  IF T<999 THEN 680
660  PRINT "DEVELOPING EMBRYO HAS DIED DUE TO LETHAL GENE ACTION."
670  GOTO 760
680  IF R<19 THEN 710
690  PRINT "OFFSPRING HAS VESTIGIAL WINGS"
700  GOTO 720
710  PRINT "OFFSPRING HAS NORMAL WINGS"
720  IF S<199 THEN 750
730  PRINT "AND IS WHITE EYED"
740  GOTO 760
750  PRINT "AND IS RED EYED."
760  PRINT 
770  IF C>1 THEN 800
780  PRINT "     LET'S TRY THIS SEVERAL TIMES AND SEE THE RESULTS WE GET"
790  PRINT "OVER SEVERAL TRIALS. KEEP A RECORD."
800  PRINT "SHALL WE TRY AGAIN? IF YES TYPE 1, IF NO TYPE 0."
810  INPUT I
820  IF I=1 THEN 210
830  IF I=0 THEN 850
840  GOTO 800
850  PRINT "     I HOPE THAT I HAVE BEEN OF SOME HELP TO YOU,"
860  PRINT "AND THAT"C"RUNS PROVIDE ENOUGH INFORMATION."
870  END 
