10  REM  COLLEG:  COLLEGE QUIZES, ENHANCED BY MR. WILLIAM K. CHAR,
15  REM  DECEMBER 2, 1974.
20  REM
25  DIM A$[72],B$[72],N$[72],A[100]
30  IF TIM(1)>11 THEN 45
35  PRINT "GOOD MORNING, ";
40  GOTO 65
45  IF TIM(1)>13 THEN 60
50  PRINT "GOOD AFTERNOON, ";
55  GOTO 65
60  PRINT "GOOD EVENING, ";
65  PRINT "WHAT'S YOUR FIRST NAME";
70  INPUT N$
75  PRINT "DO YOU NEED THE INSTRUCTIONS, "N$;
80  INPUT A$
85  IF A$[1,1]="N" THEN 155
90  PRINT 
95  PRINT "     $COLLEG IS A SIMPLE QUIZ WHICH CONTAINS QUESTIONS IN"
100  PRINT "THE FOLLOWING CATEGORIES:"
105  PRINT 
110  PRINT " 1.  GENERAL COLLEGE OPINIONS;"
115  PRINT " 2.  COLLEGE ADMISSIONS PROCEDURES;"
120  PRINT " 3.  COLLEGE ADMISSIONS REQUIREMENTS; AND"
125  PRINT " 4.  FINANCIAL ASSISTANCE."
130  PRINT 
135  PRINT "     PLEASE ANSWER 'Y' OR 'N' TO EACH STATEMENT."
140  PRINT "QUESTIONS ANSWERED INCORRECTLY WILL BE REPEATED."
145  PRINT 
150  PRINT "====="
155  PRINT 
160  PRINT "IN WHICH CATEGORY WOULD YOU LIKE TO BE TESTED";
165  PRINT " (1-4, 5 TO STOP)";
170  INPUT A
175  IF A<1 OR A>4 THEN 470
180  GOSUB 500
185  N=0
190  READ B$
195  IF B$="$END" THEN 215
200  IF B$[1,1] <> "$" THEN 190
205  N=N+1
210  GOTO 190
215  PRINT 
220  PRINT "     THERE ARE  "N"QUESTIONS IN THIS CATEGORY."
225  MAT A=ZER
230  E=0
235  REM  (ADVANCE MISTAKE POINTERS)
240  FOR I=1 TO N
245  IF A[I]=0 OR A[I]=100 THEN 255
250  A[I]=A[I]+1
255  NEXT I
260  FOR I=1 TO N
265  IF A[I]>3 AND A[I]<100 THEN 360
270  NEXT I
275  REM  (CHECK IF ANY QUESTIONS REMAIN)
280  FOR I=1 TO N
285  IF A[I]=0 THEN 345
290  NEXT I
295  REM  (CHECK IF ANY MISTAKES OUTSTANDING)"
300  FOR I=1 TO N
305  IF A[I]>0 AND A[I]<100 THEN 240
310  NEXT I
315  PRINT 
320  PRINT "     YOU HAVE COMPLETED THIS SECTION WITH ";
325  PRINT  USING "DD";E
330  PRINT "ERRORS."
335  GOTO 145
340  REM  (RANDOMLY SELECT QUESTION)
345  I=INT(N*RND(0)+1)
350  IF A[I] THEN 345
355  REM  ===== READ AND PRINT QUESTION =====
360  GOSUB 500
365  FOR J=1 TO I
370  READ B$
375  IF B$[1,1] <> "$" THEN 370
380  NEXT J
385  PRINT 
390  PRINT B$[2]
395  READ B$
400  IF B$[1,1]="?" THEN 415
405  PRINT B$
410  GOTO 395
415  PRINT " ";
420  INPUT A$
425  IF A$[1,1]=B$[2,2] THEN 450
430  PRINT " WRONG; THE ANSWER IS '"B$[2,2]"'"
435  A[I]=1
440  E=E+1
445  GOTO 240
450  PRINT " RIGHT!"
455  A[I]=100
460  GOTO 240
465  REM  ===== END OF JOB =====
470  PRINT 
475  PRINT "     I THANK YOU FOR SPENDING SOME TIME WITH ME, "N$"."
480  PRINT "TAKE THIS OUTPUT WITH YOU AND SEE YOUR COUNSELOR IF YOU"
485  PRINT "HAVE ANY QUESTIONS."
490  STOP 
495  REM  ===== RESTORE DATA TO CORRECT TEST =====
500  GOTO A OF 505,515,525,535
505  RESTORE 1000
510  RETURN 
515  RESTORE 2000
520  RETURN 
525  RESTORE 3000
530  RETURN 
535  RESTORE 4000
540  RETURN 
1000  DATA "$LESS THAN HALF THE PEOPLE WHO ENTER COLLEGE RECEIVE A 'BA'"
1010  DATA "DEGREE.","?Y"
1020  DATA "$A COLLEGE DEGREE IS A GUARANTEE FOR A GOOD PAYING JOB."
1030  DATA "?N"
1040  DATA "$STUDENTS WHO ATTEND TWO-YEAR COLLEGES ARE USUALLY NOT GOOD"
1050  DATA "STUDENTS.","?N"
1060  DATA "$YOUR PERSONAL VALUES WILL BE AFFECTED BY YOUR COLLEGE"
1070  DATA "EXPERIENCE.","?Y"
1080  DATA "$TO BE EDUCATED TO THE LIMIT OF YOUR ABILITY YOU MUST ATTEND"
1090  DATA "COLLEGE.","?N"
1100  DATA "$MOST COLLEGES HAVE FEW COMMON COURSES THAT ALL STUDENTS"
1110  DATA "MUST TAKE.","?Y"
1120  DATA "$COLLEGE SELECTION SHOULD BE BASED ONLY ON FINANCIAL FACTORS."
1130  DATA "?N"
1140  DATA "$SUCCESS IN COLLEGE IS LARGELY DEPENDENT UPON THE STUDENT'S"
1150  DATA "SELF-DIRECTION.","?Y"
1160  DATA "$MOST STUDENTS ENTER COLLEGE KNOWING WHAT THEY WILL DO AS A"
1170  DATA "CAREER.","?Y"
1180  DATA "$GENERALLY, COLLEGE TEACHERS ARE BETTER TEACHERS THAN HIGH"
1190  DATA "SCHOOL TEACHERS.","?N"
1200  DATA "$YOUR TEACHERS ARE PROBABLY THE BEST JUDGE OF YOUR ABILITY"
1210  DATA "TO DO COLLEGE WORK.","?N"
1220  DATA "$SINCE COLLEGES ARE SO SIMILAR, SELECTION IS NOT A VERY"
1230  DATA "SERIOUS DECISION.","?N"
1240  DATA "$FEW PEOPLE CONTINUE THEIR EDUCATION AFTER HIGH SCHOOL UNLESS"
1250  DATA "THEY GO TO COLLEGE.","?N"
1260  DATA "$THE MAIN PURPOSE FOR ATTENDING COLLEGE IS TO ACQUIRE JOB"
1270  DATA "SKILLS.","?Y"
1280  DATA "$MOST STUDENTS KNOW IF THEY ARE GOING TO COLLEGE BY THEIR"
1290  DATA "9TH-GRADE YEAR.","?N"
1300  END 
1310  DATA "$END"
2000  DATA "$A DEFINITE PLAN OF ACTION IS BENEFICIAL WHILE SELECTING"
2010  DATA "A COLLEGE TO ATTEND.","?Y"
2020  DATA "$ADMISSIONS OFFICERS ARE OF LITTLE ASSISTANCE TO STUDENTS"
2030  DATA "IN THE ADMISSIONS PROCESS.","?N"
2040  DATA "$IF POSSIBLE, A STUDENT MAY WISH TO APPLY TO MORE THAN ONE"
2050  DATA "COLLEGE.","?Y"
2060  DATA "$PARENTS CAN BE HELPFUL IN COMPLETING THE COLLEGE ADMISSIONS"
2070  DATA "PROCESS.","?Y"
2080  DATA "$BEFORE YOU ARE ADMITTED, A COLLEGE WILL CHECK YOUR HIGH"
2090  DATA "SCHOOL RECORD.","?Y"
2100  DATA "$COLLEGE CATALOGS INCLUDE SPECIFIC ADMISSIONS PROCEDURES"
2110  DATA "TO FOLLOW.","?Y"
2120  DATA "$STUDENTS ATTENDING COLLEGE ARE USUALLY AWARE OF PROPER"
2130  DATA "ADMISSIONS PROCEDURES.","?Y"
2140  DATA "$A VISIT TO THE CAMPUS OF THE COLLEGE YOU WISH TO ATTEND IS"
2150  DATA "USUALLY BENEFICIAL.","?Y"
2160  DATA "$IT IS BEST TO COMPLETE ADMISSIONS PROCEDURES EARLY IN THE"
2170  DATA "SENIOR YEAR.","?Y"
2180  DATA "$YOUR COUNSELOR HAS CURRENT INFORMATION ABOUT ADMISSIONS"
2190  DATA "FOR MOST SCHOOLS.","?Y"
2200  DATA "$MOST COLLEGES HAVE DEADLINES FOR RECEIVING AND PROCESSING"
2210  DATA "ADMISSIONS APPLICATIONS.","?Y"
2220  DATA "$COMPLETING A HEALTH RECORD IS A PART OF THE ADMISSIONS"
2230  DATA "PROCESS.","?Y"
2240  DATA "$MOST SCHOOLS REQUIRE A NON-REFUNDABLE DEPOSIT TO ACCOMPANY"
2250  DATA "EACH APPLICATION.","?Y"
2260  DATA "$THE ADMISSIONS PROCESS IS COMPLETED WHEN YOU START TO"
2270  DATA "ATTEND CLASS.","?N"
2280  DATA "$YOU MUST RE-APPLY FOR ADMISSION EACH YEAR YOU ARE IN"
2290  DATA "COLLEGE.","?N"
2300  DATA "$END"
3000  DATA "$THE A.C.T. TEST IS REQUIRED OF ALL STUDENTS PLANNING TO GO"
3010  DATA "TO COLLEGE.","?N"
3020  DATA "$ALL STUDENTS MUST HAVE AT LEAST A 2.5 GRADE POINT AVERAGE"
3030  DATA "TO BE ADMITTED TO COLLEGE.","?N"
3040  DATA "$ALL STUDENTS MUST HAVE A HIGH SCHOOL DIPLOMA TO BE ADMITTED"
3050  DATA "TO COLLEGE.","?N"
3060  DATA "$MOST COLLEGES REQUIRE THREE YEARS OF SCIENCE AND MATH FOR"
3070  DATA "A STUDENT SEEKING ADMISSION.","?N"
3080  DATA "$A STUDENT MUST TAKE THREE YEARS OF HIGH SCHOOL ENGLISH TO"
3090  DATA "BE ADMITTED TO COLLEGE.","?N"
3100  DATA "$A FOREIGN LANGUAGE IS REQUIRED FOR ADMISSION TO THE"
3110  DATA "MAJORITY OF COLLEGES.","?N"
3120  DATA "$HIGH SCHOOL SCORES ON COLLEGE ADMISSIONS TESTS ARE A"
3130  DATA "NECESSITY FOR ADMISSION TO COLLEGE.","?N"
3140  DATA "$A STUDENT MUST STATE HIS MAJOR AREA OF STUDY AT THE TIME"
3150  DATA "HE IS ADMITTED.","?N"
3160  DATA "$THE GREATEST SINGLE DETERMINER FOR ADMISSION TO COLLEGE IS"
3170  DATA "HIGH SCHOOL ACHIEVEMENT.","?Y"
3180  DATA "$ALL COLLEGES HAVE THE SAME ADMISSION REQUIREMENTS.","?N"
3190  DATA "$IT IS EASIER TO BE ADMITTED TO PRIVATE COLLEGES THAN TO"
3200  DATA "PUBLIC COLLEGES.","?N"
3210  DATA "$COLLEGES EXPECT STUDENTS TO KNOW HOW TO USE THE LIBRARY"
3220  DATA "PRIOR TO ADMISSION.","?N"
3230  DATA "$PRIOR TO ADMISSION, A STUDENT MUST VISIT THE CAMPUS AND"
3240  DATA "MEET THE DEAN.","?N"
3250  DATA "$A PERSON MAY BE ADMITTED TO COLLEGE ONLY IF HE PLANS TO"
3260  DATA "ATTEND FULL-TIME.","?N"
3270  DATA "$A PERSON CAN ONLY ENTER COLLEGE IMMEDIATELY AFTER HE"
3280  DATA "GRADUATES FROM HIGH SCHOOL.","?N"
3290  DATA "$END"
4000  DATA "$ALL STUDENTS WHO ARE ADMITTED TO COLLEGE ARE GIVEN"
4010  DATA "FINANCIAL AID.","?N"
4020  DATA "$FINANCIAL AID IS GRANTED ONLY ON THE BASIS OF FINANCIAL"
4030  DATA "NEED.","?N"
4040  DATA "$MOST HIGH SCHOOLS HAVE SCHOLARSHIP FUNDS FOR"
4050  DATA "THEIR GRADUATING SENIORS.","?Y"
4060  DATA "$THE AVERAGE TOTAL COST FOR ONE YEAR AT A FOUR YEAR COLLEGE"
4070  DATA "IS OVER $2000.","?Y"
4080  DATA "$MOST STUDENTS SHOULD HAVE THEIR PARENTS FILE A PARENTS'"
4090  DATA "FINANCIAL STATEMENT.","?Y"
4100  DATA "$A STUDENT'S PARENTS MUST FILE A PARENTS' FINANCIAL STATE-"
4110  DATA "MENT EACH YEAR.","?Y"
4120  DATA "$A SCHOLARSHIP IS AN OUTRIGHT GIFT OF MONEY.","?Y"
4130  DATA "$ALL FINANCIAL AID FUNDS RECEIVED MUST BE REPAYED.","?N"
4140  DATA "$MOST FAMILIES TEND TO UNDERESTIMATE THEIR ABILITY TO"
4150  DATA "CONTRIBUTE MONETARY AID.","?Y"
4160  DATA "$THE FEDERAL GOVERNMENT IS THE PRIMARY SUPPLIER OF FINANCIAL"
4170  DATA "AID TO STUDENTS.","?Y"
4180  DATA "$A STUDENT IS LIMITED IN THE TOTAL AMOUNT OF FINANCIAL AID"
4190  DATA "HE MAY RECEIVE.","?Y"
4200  DATA "$THERE ARE SEVERAL WAYS THAT A STUDENT MAY FINANCE HIS"
4210  DATA "COLLEGE EDUCATION.","?Y"
4220  DATA "$FINANCIAL PLANNING IS OF LESS IMPORTANCE THAN COLLEGE"
4230  DATA "SELECTION.","?N"
4240  DATA "$MOST COLLEGES HAVE A DEADLINE FOR APPLYING FOR FINANCIAL"
4250  DATA "AID.","?Y"
4260  DATA "$END"
9999  END 
