1  COM A0$[7]
2  IF LEN(A0$)>0 THEN 5
3  A0$="$1DIGIT"
4  CHAIN X,"1.A007"
5  REM LINES 1-5 AFM MOD 2
10  REM STEVE MUNZEL,AUTHOR. PROGRAM FOR ONE DIGIT MULTIPLICATION.
20  DIM Z$[72]
30  PRINT "HI!!  MY NAME IS 1DIGIT.  BUT, YOU CAN CALL ME '1'."
40  PRINT "WHAT IS YOUR FIRST NAME";
50  INPUT Z$
60  PRINT "TRY TO SOLVE THESE ONE DIGIT MULTIPLICATION PROBLEMS,"Z$
70  N=A=0
80  W=0
90  FOR J=1 TO 100
100  FOR I=1 TO 5
110  C=0
120  X=INT(RND(0)*10)
130  Y=INT(RND(0)*10)
140  PRINT "WHAT IS";X;"X";Y;"?";
150  ENTER 30,P,A
160  PRINT 
170  IF P=-256 THEN 310
180  C=C+P
190  IF P<0 THEN 140
200  IF A=X*Y THEN 340
210  PRINT 
220  PRINT "THAT'S NOT WHAT I GOT,"Z$;". . . TRY IT AGAIN!"
230  PRINT 
240  PRINT X;"X";Y;"=";
250  ENTER 30,P,A
260  PRINT 
270  IF P=-256 THEN 310
280  C=C+P
290  IF P<0 THEN 240
300  IF A=X*Y THEN 340
310  PRINT "THE CORRECT ANSWER WAS";X*Y
320  W=W+1
330  GOTO 460
340  Q=INT(RND(0)*3+1)
350  IF Q=1 THEN 390
360  IF Q=2 THEN 410
370  PRINT "THAT ANSWER REALLY RINGS"'7'7'7'7'7'7'7'7'7'7'7'7'7'7'7'7'7'7'7'7'7'7" TRUE!! ";X*Y;"IS RIGHT, "Z$"!!"
380  GOTO 430
390  PRINT "YOU'RE F*"'7"A*"'7"N*"'7"T*"'7"A*"'7"S*"'7"T*"'7"I*"'7"C, "Z$"!!  THE CORRECT ANSWER WAS,";X*Y
400  GOTO 430
410  PRINT X*Y;"SURE SOUNDS"'7'7'7'7'7'7'7'7'7'7'7'7'7'7'7'7" RIGHT TO ME, "Z$"!!"
420  P=C
430  PRINT "THAT TOOK YOU JUST ";P;"SECOND(S)!!"
440  N=N+1
450  PRINT 
460  NEXT I
470  PRINT 
480  PRINT Z$", YOUR TOTAL NUMBER RIGHT IS NOW...";N;"YOU GOT ";W;"WRONG."
490  PRINT "I HAVE GIVEN YOU";J*5;"PROBLEMS, SO FAR. . . "
500  PRINT "YOUR TOTAL PER CENT RIGHT IS NOW,";(N*100)/(J*5)
510  PRINT 
520  PRINT "WANT TO TRY 5 MORE?? 1=YES   0=NO  ";
530  INPUT A
540  IF A=0 THEN 590
550  NEXT J
560  PRINT "THAT'S ENOUGH FOR ME!!!"
570  PRINT "SEE YA' LATER,"Z$
580  GOTO 600
590  PRINT "O.K.,"Z$", THEN YOU ARE NOW. . . "
600  END 
