10  REM  1040A TAX FORM, BY LES VOGEL, MARCH 18, 1974
20  REM
30  DIM A$[72],B$[72],A[30]
40  REM
50  PRINT "SHORT FORM, 1040A, 1974"
55  MAT A=ZER
60  PRINT 
70  PRINT "YOU SHOULD HAVE THE SHORT FORM IN FRONT OF YOU AND"
80  PRINT "INSTRUCTIONS FOR PREPARING YOUR 1973 INCOME TAX."
90  PRINT "ROUND ALL FIGURES TO WHOLE-DOLLAR AMOUNTS, IF POSSIBLE."
100  PRINT 
110  PRINT "FILING STATUS"
120  PRINT "1=SINGLE , 2=MARRIED FILING JOINT RETURN"
130  PRINT "3=MARRIED FILING SEPERATELY , 4=UNMARRIED HEAD OF HOUSE HOLD"
140  PRINT "5=WIDOW (ER)";
150  PRINT '10'13'1'1"WHICH ONE";
160  INPUT A[6]
170  IF A[6]>5 OR A[6]<1 THEN 120
180  PRINT "IN THE NEXT SEVEN QUESTIONS, INPUT A NUMBER AFTER EACH"
190  PRINT "QUESTION MARK:"
200  PRINT 
210  FOR Z=1 TO 7
220  READ C,B$
230  PRINT B$;
240  INPUT A[C]
250  NEXT Z
260  A[4]=A[1]+A[2]+A[3]
270  A[9]=A[7]-A[8]
280  A[11]=A[10]+A[9]+A[5]
290  IF A[11]<0 THEN 380
300  A[12]=A[11]*.15
310  A[12]=A[12] MIN 2000
320  IF A[6]#3 THEN 340
330  A[12]=A[12] MIN 1000
340  A[13]=A[11]-A[12]
350  A[14]=A[4]*750
360  A[15]=A[13]-A[14]
370  GOTO 390
380  A[15]=A[11]
390  PRINT "TAXABLE INCOME="A[15]
400  PRINT "WHAT IS YOUR TAX";
410  INPUT A[17]
420  PRINT "...TAX PERCENTAGE (ZERO IF A TABLE IS USED)";
430  INPUT A[18]
440  PRINT "...EXCESS (ZERO IF A TABLE IS USED)";
450  A[17]=A[17]+((A[15]-A[19])*(A[18]/100))
460  PRINT "INPUT HALF THE MONEY YOU GAVE TO HELP"
470  PRINT "PAY CAMPAIGN EXPENSES FOR PERSONS"
480  PRINT "RUNNING FOR PUBLIC OFFICE UP TO 12.50";
490  INPUT A[20]
500  A[21]=(A[17]-A[20]) MAX 0
510  FOR X=1 TO 3
520  READ C,B$
530  PRINT B$;
540  INPUT A[C]
550  NEXT X
560  A[25]=A[22]+A[23]+A[24]
570  PRINT LIN(3)
580  REM  ===== OUTPUT =====
590  FOR Z=1 TO 22
600  READ X,B$
610  PRINT B$;TAB(35);A[X]
620  NEXT Z
630  FOR Z=1 TO 2
640  READ X,Y,B$
650  IF A[X]>A[Y] THEN 680
660  PRINT B$;TAB(35);" LEAVE BLANK"
670  GOTO 690
680  PRINT B$;TAB(35);A[X]
690  NEXT Z
700  PRINT LIN(4)
710  STOP 
720  DATA 3,"BOXES CHECKED. SEE PAGE 3,6A,6B"
730  DATA 1,"DEPENDENT CHILDREN"
740  DATA 2,"OTHER DEPENDENTS"
750  DATA 5,"WAGES, TIPS AND OTHER EMPLOYEE COMP. (SEE PAGE 3, LINE 9)"
760  DATA 7,"TOTAL DIVIDENDS"
770  DATA 8,"TOTAL EXCLUSIONS"
780  DATA 10,"INTEREST"
790  DATA 22,"FEDERAL INCOME TAX WITHHELD"
800  DATA 23,"EXCESS FICA WITHHELD (SEE PAGE 4)"
810  DATA 24,"1973 ESTIMATED TAX"
820  DATA 6,"1-5      FILING STATUS"
830  DATA 3,"6        NO. OF BOXES"
840  DATA 1,"6C       NO. OF CHILDREN"
850  DATA 2,"6D       NO. OF OTHER DEPENDENTS"
860  DATA 4,"7        TOTAL EXEMPTIONS CLAIMED"
870  DATA 5,"9        WAGES, SALARIES, TIPS"
880  DATA 7,"10A      DIVIDENDS"
890  DATA 8,"10B      LESS EXCLUSION"
900  DATA 9,"10C      BALANCE"
910  DATA 10,"11       INTEREST INCOME"
920  DATA 11,"12       ADJUSTED GROSS INCOME"
930  DATA 12,"13       15% OF LINE 12"
940  DATA 13,"14       LINE 12 - LINE 13"
950  DATA 14,"15       LINE 7 * 750"
960  DATA 15,"16       TAXABLE INCOME"
970  DATA 17,"17       TAX"
980  DATA 20,"18       CONTRIBUTIONS TO CANDIDATES"
990  DATA 21,"19       INCOME TAX"
1000  DATA 22,"20A      TAX WITHHELD"
1010  DATA 23,"20B      EXCESS F.I.C.A."
1020  DATA 24,"20C      1973 EST. TAX PAYMENTS"
1030  DATA 25,"21       20A + 20B + 20C"
1040  DATA 21,25,"22       BALANCE DUE IRS"
1050  DATA 25,21,"23       AMOUNT OVERPAID"
1060  END 
