10  REM 1040 INCOME TAX PROGRAM, BEN MENDELSOHN  VERSION 1A 4/26/1974
20  DIM A[100],P[100],A$[72],B$[72],C$[72]
30  MAT P=ZER
40  PRINT "THIS PROGRAM DOES YOUR INCOME TAX ACCORDING TO FORM 1040."
50  PRINT "TO USE THIS PROGRAM YOU MUST HAVE THE 1040 FORM AND INSTRUCTION"
60  PRINT "BOOKLET WITH YOU.  A NUMBER WILL BE PRINTED AND YOU FIND THE"
70  PRINT "CORRESPONDING ITEM ON YOUR FORM."
80  PRINT "(I.E.  9 WOULD BE WAGES, SALARIES ETC.)"
90  PRINT "OTHER QUESTIONS ARE YES OR NO ANSWERS.  IF YOU DON'T"
100  PRINT "HAVE A NUMBER TO PUT IN FOR A CERTAIN ITEM, INPUT 0 (ZERO)."
110  PRINT '10'10'13"FILING STATUS(1,2,3,4, OR 5)";
120  INPUT S
130  PRINT "HOW MANY EXEMPTIONS DO YOU CLAIM (6A,B,C)";
140  INPUT P[1]
150  PRINT "DO YOU HAVE ANY OTHER DEPENDENTS";
160  INPUT B$
170  IF B$[1,1]#"Y" THEN 210
180  PRINT "HOW MANY MORE";
190  INPUT P[27]
200  P[2]=P[27]+P[1]
210  PRINT "PART 1:  INCOME OTHER THAN WAGES, DIVIDENDS AND INTEREST"
220  RESTORE 2270
230  FOR I=28 TO 37
240  READ C$,A$
250  PRINT A$;
260  INPUT P[I]
270  P[9]=P[38]=P[38]+P[I]
280  NEXT I
290  PRINT "PART 2: ADJUSTMENTS TO INCOME"
300  RESTORE 2350
310  FOR I=39 TO 42
320  READ C$,A$
330  PRINT A$;
340  INPUT P[I]
350  P[11]=P[43]=P[43]+P[I]
360  NEXT I
370  PRINT "   INCOME"
380  RESTORE 2120
390  FOR I=3 TO 5
400  READ C$,A$
410  PRINT A$;
420  INPUT P[I]
430  NEXT I
440  P[6]=P[4]-P[5]
450  READ C$,A$
460  FOR I=7 TO 9
470  READ C$,A$
480  PRINT A$;
490  INPUT P[I]
500  NEXT I
510  P[10]=P[3]+P[6]+P[8]+P[9]
520  P[44]=P[12]=P[10]-P[11]
530  PRINT "ARE YOU GOING TO ITEMIZE DEDUCTIONS";
540  INPUT B$
550  IF B$[1,1]="Y" THEN 630
560  P[45]=P[44]*.15
570  IF P[45]<1000 THEN 1390
580  IF P[45]>2000 AND S=3 THEN 610
590  P[45]=2000
600  GOTO 1390
610  P[45]=1000
620  GOTO 1390
630  REM                 BEGIN I.D.
640  MAT A=ZER
650  PRINT '10'13"  MEDICAL AND DENTAL EXPENSES"'10'13
660  RESTORE 2550
670  FOR I=1 TO 2
680  READ C$,A$
690  PRINT A$;
700  INPUT A[I]
710  NEXT I
720  A[3]=P[12]*.01
730  A[4]=A[2]-A[3]
740  RESTORE 2580
750  FOR I=5 TO 8
760  READ C$,A$
770  PRINT A$;
780  INPUT A[I]
790  A[9]=A[9]+A[I]
800  NEXT I
810  A[9]=A[9]+A[4]
820  A[10]=P[12]*.03
830  A[11]=A[9]-A[10]
840  IF A[11] >= 0 THEN 860
850  A[11]=0
860  A[38]=A[12]=A[1]+A[11]
870  PRINT '10'13"  TAXES"'10'13
880  RESTORE 2640
890  FOR I=13 TO 18
900  READ C$,A$
910  PRINT A$;
920  INPUT A[I]
930  A[39]=A[19]=A[19]+A[I]
940  NEXT I
950  PRINT '10'13"  INTEREST EXPENSE"'10'13
960  PRINT "HOME MORTGAGE";
970  INPUT A[20]
980  PRINT "OTHER (TOTAL)";
990  INPUT A[21]
1000  A[40]=A[22]=A[21]+A[20]
1010  PRINT '10'13"  CONTRIBUTIONS"'10'13
1020  RESTORE 2710
1030  FOR I=23 TO 26
1040  READ C$,A$
1050  PRINT A$;
1060  INPUT A[I]
1070  A[41]=A[27]=A[27]+A[I]
1080  NEXT I
1090  PRINT '10'13"  CASUALTY OR THEFT LOSS"'10'13
1100  RESTORE 2760
1110  FOR I=28 TO 29
1120  READ C$,A$
1130  PRINT A$;
1140  INPUT A[I]
1150  NEXT I
1160  A[30]=A[28]-A[29]
1170  IF A[30]<0 THEN 1230
1180  IF A[30]<100 THEN 1210
1190  A[30]=A[31]=100
1200  GOTO 1260
1210  A[31]=A[30]
1220  GOTO 1260
1230  A[31]=A[30]=0
1240  A[42]=A[32]=A[30]-A[31]
1250  PRINT "  MISCELLANEOUS DEDUCTIONS"
1260  RESTORE 2800
1270  FOR I=33 TO 36
1280  READ C$,A$
1290  PRINT A$;
1300  INPUT A[I]
1310  A[43]=A[37]=A[37]+A[I]
1320  NEXT I
1330  FOR I=38 TO 43
1340  P[45]=A[44]=A[44]+A[I]
1350  NEXT I
1360  REM                END I.D.
1370  IF A[12]<10000 THEN 1470
1380  IF B$[1,1]#"Y" THEN 1470
1390  P[46]=P[44]-P[45]
1400  P[47]=P[2]*750
1410  P[48]=P[46]-P[47]
1420  IF B$[1,1]#"Y" THEN 1470
1430  PRINT "TAXABLE INCOME, FOLLOW INSTRUCTIONS AFTER LINE 48 ON FORM."
1440  PRINT "ENTER TAX NOW ";
1450  INPUT P[13]
1460  GOTO 1490
1470  PRINT "FIND YOUR TAX ON TABLES 1-12 AND ENTER NOW";
1480  INPUT P[13]
1490  PRINT '10'13"  CREDITS"'10'13
1500  RESTORE 2420
1510  FOR I=49 TO 53
1520  READ C$,A$
1530  PRINT A$;
1540  INPUT P[I]
1550  P[14]=P[54]=P[54]+P[I]
1560  NEXT I
1570  P[15]=P[13]-P[14]
1580  RESTORE 2460
1590  FOR I=55 TO 60
1600  READ C$,A$
1610  PRINT A$;
1620  INPUT P[I]
1630  P[16]=P[61]=P[61]+P[I]
1640  P[17]=P[15]+P[16]
1650  NEXT I
1660  RESTORE 2520
1670  FOR I=62 TO 64
1680  READ C$,A$
1690  PRINT A$;
1700  INPUT P[I]
1710  P[65]=P[65]+P[I]
1720  NEXT I
1730  P[15]=P[13]-P[14]
1740  P[17]=P[15]+P[16]
1750  RESTORE 2200
1760  FOR I=18 TO 21
1770  READ C$,A$
1780  PRINT A$;
1790  INPUT P[I]
1800  P[22]=P[22]+P[I]
1810  NEXT I
1820  REM BALANCE DUE OR REFUND
1830  IF P[20]>P[22] THEN 1920
1840  IF P[20]=P[22] THEN 1930
1850  P[24]=P[22]-P[20]
1860  PRINT "YOU HAVE OVERPAID ON YOUR TAXES.  THE AMOUNT OVERPAID IS";P[24]
1870  PRINT "HOW MUCH SHOULD BE REFUNDED TO YOU";
1880  INPUT P[25]
1890  PRINT "HOW MUCH CREDIT TO 1974 TAX";
1900  INPUT P[26]
1910  GOTO 1930
1920  P[23]=P[20]-P[22]
1930  RESTORE 
1940  PRINT "TEAR HERE"'10'13"---------"'10'10'10'13"          FORM 1040      1973"
1950  PRINT "-------------------------------------------------------------"
1960  PRINT "FILING STATUS";S
1970  PRINT "TOTAL EXEMPTIONS";P[2]
1980  FOR I=3 TO 65
1990  READ C$,A$
2000  PRINT  USING 2010;A$,C$,P[I]
2010  IMAGE 3AX,52A,7D.DD
2020  NEXT I
2030  PRINT '10'10'13"-------------------------------------------------------------"
2040  IF B$[1,1]#"Y" THEN 2870
2050  PRINT '10'10'10'13"                    SCHEDULE A      1973"
2060  PRINT "-------------------------------------------------------------"
2070  RESTORE 2590
2080  FOR I=1 TO 45
2090  READ C$,A$
2100  PRINT  USING 2010;A$,C$,A[I]
2110  NEXT I
2120  DATA "WAGES,SALARIES,TIPS, AND OTHER EMPLOYEE COMPENSATION"
2130  DATA "9","DIVIDENDS","10A","LESS EXCLUSION"
2140  DATA "10B","BALANCE","10C","GROSS AMOUNT RECIEVED, IF DIFFERENT FROM DIVIDENDS)"
2150  DATA "10D","INTEREST INCOME","11","INCOME OTHER THAN WAGES, DIVIDENDS, AND INTEREST"
2160  DATA "12","TOTAL","13","ADJUSTMENTS TO INCOME"
2170  DATA "14","SUBTRACT LINE 14 FROM LINE 13(ADJUSTED GROSS INCOME)"
2180  DATA "15","TAX","16","TOTAL CREDITS"
2190  DATA "17","INCOME TAX","18","OTHER TAXES","19","TOTAL","20"
2200  DATA "TOTAL FEDERAL INCOME TAX WITHHELD"
2210  DATA "21A","1973 ESTIMATED TAX PAYMENTS","21B"
2220  DATA "AMOUNT PAID WITH FORM 4868","21C","OTHER PAYMENTS"
2230  DATA "21D","TOTAL","22",'7'7'7'7"BALANCE DUE IRS"'7'7'7'7
2240  DATA "23","AMOUNT OVERPAID","24","AMOUNT TO BE REFUNDED TO YOU"
2250  DATA "25","AMOUNT TO BE CREDITED TO YOUR 1974 TAX"
2260  DATA "26","TOTAL NUMBER OF DEPENDANTS","27"
2270  DATA "BUSINESS INCOME OR LOSS","28","NET GAIN OF LOSS FROM SALE OR EXCHANGE OF CAPITAL ASSETS"
2280  DATA "29","NET GAIN OR LOSS FROM SUPPLEMENTAL SCHEDULE OF GAINS AND LOSSES"
2290  DATA "30","PENSIONS,ANNUITIES,RENTS,ROYALITIES,PARTNERSHIPS,ESTATES OR TRUSTS,ETC."
2300  DATA "31","FARM INCOME OR LOSS","32"
2310  DATA "FULLY TAXABLE PENSIONS AND ANNUITIES","33"
2320  DATA "50% OF CAPITAL GAIN DISTRIBUTUONS","34"
2330  DATA "STATE INCOME TAX REFUNDS","35","ALIMONY RECEIVED"
2340  DATA "36","OTHER","37","TOTAL","38"
2350  DATA "SICK PAY","39","MOVING EXPENSE"
2360  DATA "40","EMPLOYEE BUSINESS EXPENSE","41"
2370  DATA "PAYMENTS AS A SELF-EMPLOYED PERSON TO A RETIREMENT PLAN"
2380  DATA "42","TOTAL ADJUSTMENTS","43"
2390  DATA "ADJUSTED GROSS INCOME","44","45A OR 45B","45"
2400  DATA "SUBTRACT LINE 45 FROM 44","46","MULTIPLY TOTAL NUMBER OF EXEMPTIONS"
2410  DATA "47","TAXABLE INCOME","48"
2420  DATA "RETIREMENT INCOME CREDIT","49","INVESTMENT CREDIT"
2430  DATA "50","FOREIGN TAX CREDIT","51"
2440  DATA "CREDIT FOR CONTRIBUTIONS TO CANDIDATES FOR PUBLIC OFFICE"
2450  DATA "52","WORK INCENTIVE CREDIT","53","TOTAL CREDITS","54"
2460  DATA "SELF-EMPLOYMENT TAX","55","TAX FROM RECOMPUTING PRIOR-YEAR INVESTMENT CREDIT"
2470  DATA "56","TAX FROM RECOMPUTING PRIOR-YEAR WORK INCENTIVE CREDIT"
2480  DATA "57","MINIMUM TAX.  BESURE TO CHECK SQUARE IF FORM 4625 IS ATTACHED"
2490  DATA "58","SOCIAL SERCURITY TAX ON TIP INCOME NOT REPORTED TO EMPLOYER"
2500  DATA "59","UNCOLLECTED EMPLOYEE SOCIAL SECURITY TAX ON TIPS"
2510  DATA "60","TOTAL","61"
2520  DATA "EXCESS FICA TAX WITHHELD","62","CREDIT FOR FEDERAL TAX ON SPECIAL FUELS"
2530  DATA "63","CREDIT FROM A REGULATED INVESTMENT COMPANY"
2540  DATA "64","TOTAL","65"
2550  DATA "ONE HALF OF INSURANCE PREMIUMS FOR MEDICAL CARE."
2560  DATA "1","MEDICINE AND DRUGS","2","1% OF LINE 15 FORM 1040"
2570  DATA "3","SUBTRACT LINE 3 FROM LINE 2","4"
2580  DATA "ENTER BALANCE OF INSURANCE PREMIUMS"
2590  DATA "5","DOCTORS, DENTISIS, ETC.","6A"
2600  DATA "HOSPITALS","6B","OTHERS (TOTAL ONLY)"
2610  DATA "6C","TOTAL(LINES 4,5,6A,B,C)","7"
2620  DATA "ENTER 3% OF LINE 15 FORM 1040","8","SUBTRACT LINE 8 FROM LINE 7"
2630  DATA "9","TOTAL (ADD LINES 1 AND 9)","10"
2640  DATA "STATE AND LOCAL INCOME","11","REAL ESTATE"
2650  DATA "12","STATE AND LOCAL GASOLINE (SEE SALES TAX TABLES)"
2660  DATA "13","GENERAL SALES (SEE SALES TAX TABLES)"
2670  DATA "14","PERSONAL PROPERTY","15"
2680  DATA "OTHERS (TOTAL ONLY)","16","TOTAL"
2690  DATA "17","HOME MORTGAGE","18","OTHERS (TOTAL ONLY)"
2700  DATA "19","TOTAL","20"
2710  DATA "CASH CONTRIBUTIONS FOR WHICH YOU HAVE RECIEPTS"
2720  DATA "21A","OTHER CASH CONTRIBUTIONS (TOTAL ONLY)"
2730  DATA "21B","OTHER THAN CASH (SEE INSTRUCTIONS ON PAGE 12)"
2740  DATA "22","CARRYOVER FROM PRIOR YEARS","23"
2750  DATA "TOTAL CONTRIBUTIONS","24"
2760  DATA "LOSS BEFORE INSURANCE REIMBURSEMENT"
2770  DATA "25","INSURANCE REIMBURSEMENT","26"
2780  DATA "SUBTRACT LINE 26 FROM LINE 25. ENTER DIFFERENCE","27"
2790  DATA "ENTER $100 OR AMOUNT ON LINE 27","28","CASUALITY OR THEFT LOSS","29"
2800  DATA "ALIMONY PAID"
2810  DATA "30","UNION DUES","31","EXPENSES FOR CHILD AND DEPENDENT CARE SERVICES"
2820  DATA "32","OTHER","33","TOTAL","34","TOTAL MEDICAL AND DENTAL-LINE 10"
2830  DATA "35","TOTAL TAXES-LINE 17","36"
2840  DATA "TOTAL INTEREST-LINE 20","37","TOTAL CONTRIBUTIONS-LINE 24"
2850  DATA "38","CAUSALTY OR THEFT LOSSES-LINE 29"
2860  DATA "39","TOTAL MISCELLANEOUS-LINE 34","40","TOTAL DEDUCTIONS","41"
2870  PRINT '10'10'13"BE SURE TO CHECK ALL BOXES AND INCLUDE REQUIRED FORMS WHEN"
2880  PRINT "SENDING YOUR TAXES TO THE IRS.  DO NOT"'7'7'7" SEND IN THIS"
2890  PRINT "COMPUTER PRINTOUT.  RECOPY IT ONTO A REGULAR 1040 TAX FORM."
2900  END 
