
*                                   * 
**  REQUEST SYSTEM IDENTIFICATION  ** 
*                                   * 
* 
*  THE SYSTEM ID IS A STRING OF UP TO 10 CHARACTERS, ALL OF WHICH 
*  MUST BE PRINTING CHARACTERS. A NULL LINE WILL LEAVE THE ID 
*  UNCHANGED. 
* 
LDR75 LDA .24       REQUEST 
      LDB SYIDA 
      JSB ASR35,I     SYSTEM
      CLA 
      JSB ASR35,I       ID
      LDA M5        SET FOR 
      STA TEMP0       10 CHARACTERS 
      LDA DSYID     POINTER TO
      STA TEMP2       ID IN EQT 
      CLB           ALLOW 
      STB BLNKA,I     BLANKS
LDR77 JSB GETCA,I   NEXT CHARACTER
      JMP LDR78     CR
      LDB A         NON-
      ADB M40B
      SSB             PRINTING? 
      JMP ERR8      YES 
      ALF,ALF       NO, ROTATE
      STA TEMP1       AND SAVE
      JSB GETCA,I   NEXT CHARACTER
      JMP LDR79     CR
      LDB A         NON-
      ADB M40B
      SSB             PRINTING? 
      JMP ERR8      YES 
      IOR TEMP1     NO, SAVE
      STA TEMP2,I     IT
      ISZ TEMP2     BUMP POINTER
      ISZ TEMP0     10 CHARACTERS DONE? 
      JMP LDR77     NO
      JSB GETCA,I   YES, CARRIAGE RETURN FOLLOWS? 
      JMP LDR80     YES 
ERR8  LDA .15       OUTPUT
      LDB ILINA       ERROR 
      JSB ASR35,I       MESSAGE 
      JMP LDR75     REQUEST ID AGAIN
LDR78 LDA M5        ANY 
      CPA TEMP0       INPUT?
      JMP LDR80     NO
      LDA B20K      YES, BLANK
      STA TEMP1       FILL
LDR79 LDA B40       BLANK 
      IOR TEMP1       FILL
      STA TEMP2,I   SAVE IT 
      ISZ TEMP2     BUMP POINTER
      ISZ TEMP0     10 CHARACTERS DONE? 
      JMP LDR78     NO
      SKP 
* 
*  REQUEST CONFIGURATION OPTIONS IF PAPER TAPE LOAD 
* 
LDR80 EQU * 
      LDA B40       SKIP
      STA BLNKA,I     BLANKS
      LDA MTFLG     MAG TAPE
      SSA,RSS         RELOAD? 
      JMP *+3       YES 
      JSB RCOPA,I   NO, REQUEST CONFIGURATION OPTIONS 
      JMP LD200     NOT WANTED
      LDA COFLG     OPTIONS 
      SZA,RSS         WANTED? 
      JMP LD200     NO
      SPC 3 
*                           * 
**  REQUEST DISC COMMANDS  ** 
*                           * 
* 
*  DISC COMMANDS MAY ADD OR REMOVE DISCS. 
*  DISC 0 MAY ONLY BE REFERENCED ALONG WITH SELECT CODE 15 OCT; 
*  I.E. DISC 0 MAY NOT BE MOVED OR REMOVED. DISCS 1-7 MAY NOT HAVE
*  A SELECT CODE BELOW 15 OR ABOVE 26 OCT. THE SEQUENCE OF DISC 
*  COMMANDS IS TERMINATED BY A CARRIAGE RETURN. 
* 
LDR8  LDA .22 
      LDB DISMA 
      JSB ASR35,I   DISC
      CLA 
      JSB ASR35,I       COMMANDS
      JSB GETCA,I   ANY?
      JMP LD200     NO
      CPA N         YES, 'N'? 
      JMP LD200     YES 
      CPA D         NO, 'D'?
      JSB GETCA,I   YES 
      JMP ERR3      NO
      CPA I         'I'?
      JSB GETCA,I   YES 
      JMP ERR3      NO
      CPA S         'S'?
      JMP LDR81     YES 
ERR3  LDA .19 
      LDB RQSTA     PRINT 
      JSB ASR35,I     ERROR 
      JMP LDR8
LDR13 LDA .21       PRINT 
      LDB ILSCA       ERROR 
      JMP ERR3+2
      SKP 
* 
*  PROCESS DISC COMMAND 
* 
LDR81 JSB GTDNA,I   GET DISC #. 
      JMP LDR8      NONE FOUND. 
      STA TEMP1     SAVE IT 
      JSB GETCA,I   NEXT
      NOP             CHARACTER 
      CPA B60           A ZERO? 
      JMP LDR87     YES 
      JSB SELCA,I   NO, GET 
BSDTA ABS BSDAT       SELECT CODE IN
      OCT 26            [15 OCT, 26 OCT]
      JMP LDR8      NOT FOUND 
      CPA COMMA     FOUND, COMMA FOLLOWING? 
      JMP LDR82     YES 
      LDA .15       NO, 
      LDB BDLA        ERROR 
      JMP ERR3+2
LDR82 STB TEMP2     SAVE SELECT CODE
      JSB GETCA,I   GET UNIT NUMBER 
      JMP LDR83     NONE FOUND
      ADA M60B      SAVE UNIT 
      STA TEMP3       NUMBER
      SSA           TEST FOR
      JMP LDR83       VALID 
      ADA MXUNA,I       UNIT
      SSA                 NUMBER
      JMP LDR84     OK
LDR83 LDA .21       ILLEGAL 
      LDB ILUNA       UNIT
      JMP ERR3+2        NUMBER
LDR84 EQU * 
      JSB GETCA,I   CARRIAGE RETURN FOLLOWS?
      RSS           YES 
      JMP LDR83     NO, ERROR 
      CLA           DISC
      CPA TEMP1       0?
      JMP LDR86     YES 
LDR85 EQU * 
      LDA TEMP2     NO, MERGE 
      ALF,ALF         SELECT
      IOR TEMP3         CODE AND
      STA TEMP4           UNIT NUMBER.
      LDA M8        EIGHT ENTRIES IN
      STA TEMP5       DISC EQT
      LDB DKTBA     => DISC SELECT CODE TABLE 
LDR88 LDA B,I       GET SELECT CODE.
      CPA TEMP4     SAME AS THIS ONE? 
      JMP LDR89     YES, ERROR. 
      INB           ADVANCE TO NEXT ENTRY 
      ISZ TEMP5     FINISHED ALL EIGHT? 
      JMP LDR88     NO
      JSB STDIA,I   YES, SET DISC ENTRY 
      JMP LDR8      ASK AGAIN 
      SKP 
LDR86 LDB TEMP2     SELECT CODE 
      CPB BSDTA       17 OCT? 
      RSS           YES 
      JMP LDR8E     NO
      CLA 
      CPA TEMP3     UNIT 0? 
      JMP LDR85     YES 
LDR8E EQU * 
      LDA .25       NO, 
      LDB DZMSA       ERROR 
      JMP ERR3+2
LDR87 JSB GETCA,I   CARRIAGE RETURN 
      CLA,RSS 
      JMP LDR13     NO
      STA TEMP2     SET SELECT CODE.
      CPA TEMP1     DISC NUMBER ZERO? 
      JMP LDR8E 
      JSB STDIA,I   CLEAR DISC ENTRY
      JMP LDR8
LDR89 LDA .21       THIS DISC 
      LDB DAIVA       IS ALREADY
      JMP ERR3+2        IN USE. 
      SPC 3 
*                                  *
**  CHECK DISCS FOR VALID LABELS  **
*                                  *
* 
*  CHECK EACH DISC WITH A NON-ZERO SELECT CODE TO INSURE THAT IT
*  HAS A VALID TSB LABEL WITH THE CURRENT SYSTEM IDENTIFICATION.
*  IF NOT, REPORT THIS TO THE OPERATOR AND RELABEL THE DISC IF HE 
*  SO DESIRES; OTHERWISE REMOVE THE DISC FROM THE EQT.
* 
LD200 LDB MHAD      => FIRST WORD OF DISC EQT 
      STB TEMP3 
LD201 JSB FNZSA,I   FIND NEXT NON-ZERO SELECT CODE
      JMP LD221     NONE FOUND
      JSB RDLBA,I   READ LABEL
      JMP LD202     CHECKSUM ERROR
      LDB LBUFA 
      LDA B,I       FIRST WORD OF LABEL 
      CPA LB        'LB'? 
      RSS           YES 
      JMP LD202     NO
      INB 
      LDA B,I       SECOND WORD OF LABEL
      CPA TS        'TS'? 
      JMP LD210     YES 
LD202 LDA TEMP1     PUT DISC
      ADA ASCB0       NUMBER IN 
      STA DIS#A,I       ERROR MESSAGE 
LD203 EQU * 
      LDA .34       NOT 
      LDB BDLBA       LABELED 
      JSB ASR35,I       FOR TSB 
      LDB LBUFA 
      INB           DOS 
      LDA B,I 
      CPA DO          LABEL?
      RSS           YES 
      JMP LD208     NO
      LDA .24       LABELED 
      LDB LBDOA       FOR 
      JSB ASR35,I       DOS 
LD208 LDA .26       DO YOU
      LDB DYWLA       WANT IT 
      JSB ASR35,I       LABELED?
      CLA           GET 
      JSB ASR35,I     RESPONSE
      JSB GETCA,I   FIRST 
      JMP LD205       CHARACTER 
      CPA Y             'Y' ? 
      JMP LD206     YES 
      CPA N         NO, 'N' ? 
      JMP LD214     YES 
LD205 LDA .15       NO
      LDB ILINA     ILLEGAL 
      JSB ASR35,I     INPUT 
      JMP LD203     TRY AGAIN 
LD206 LDA M256      256 WORDS IN
      STA TEMP4     BAD BLOCKS TABLE
      LDB MTRLA     POINTER TO BUFFER 
      CLA           ZERO
LD207 STA B,I         BAD 
      INB               BLOCKS
      ISZ TEMP4           TABLE 
      JMP LD207 
      LDB .3        THIRD BLOCK IS BADTRAX. 
      LDA M256
      JSB DAIRA,I   FIX DISC ADDRESS
      LDB MTRLA 
      JSB DISCC,I   WRITE TO DISC 
      SKP 
* 
* SET  UP LABEL BUFFER
* 
LD210 LDB LBUFA 
      LDA LB
      STA B,I       FIRST WORD = 'LB' 
      INB 
      LDA TS
      STA B,I       SECOND WORD = 'TS'
      INB 
      LDA TEMP1 
      STA B,I       THIRD WORD = LOGICAL DISC # 
      LDA M5        5 WORDS 
      STA TEMP4       IN ID 
      LDA DSYID 
      STA TEMP0 
LD211 LDA TEMP0,I   MOVE ID 
      INB 
      STA B,I         TO LABEL
      ISZ TEMP0 
      ISZ TEMP4         BUFFER
      JMP LD211 
      LDA M23       23 WORDS
      STA TEMP4       LEFT
      CLA           ZERO
LD212 INB 
      STA B,I         REST OF 
      ISZ TEMP4 
      JMP LD212         BUFFER
      JSB WTLBA,I   WRITE LABEL TO DISC 
LD213 LDA TEMP3     FINISHED
      CPA MHAD        DISC EQT? 
      JMP LD221     YES 
      JMP LD201     NO
* 
LD214 LDA TEMP1     DISC
      SZA,RSS         ZERO? 
      JMP LD215     YES, DON'T ALLOW REMOVAL
      CLA           NO, 
      STA TEMP2       REMOVE
      JSB STDIA,I       DISC
      JMP LD213 
LD215 EQU * 
      LDA .24       DISC ZERO 
      LDB DZMPA       MUST BE 
      JSB ASR35,I       PRESENT.
      JMP LD208 
* 
*  CHECK CONFIGURATION OPTION FLAG
* 
LD221 EQU * 
      LDA COFLG     OPTIONS 
      SZA,RSS         WANTED? 
      JMP LDR14     NO
      SKP 
* 
*  DO MLOCK/MUNLOCK AND NUMBER OF PORTS 
* 
      JSB RLUM      PROCESS MLOCK/MUNLOCK 
      JSB RNPRT     GET NUMBER OF PORTS 
*                                             * 
**  GET NUMBER OF DIRECTORY TRACKS PER DISC  ** 
*                                             * 
* 
*  REQUEST THE NUMBER OF DIRECTORY TRACKS PER DISC.  CHECK FOR
*  A RESPONSE BETWEEN 1 AND 10. A SIMPLE CARRIAGE RETURN IMPLIES
*  NO CHANGE
* 
LD230 EQU * 
      LDA .38       REQUEST NUMBER
      LDB NDITA       OF DIRECTORY
      JSB ASR35,I       TRACKS PER DISC 
      CLA,INA       RANGE IS
      LDB .10         1-10
      JSB RQINA,I   GET RESPONSE
      JMP LD230     ERROR 
      RSS           CR IMPLIES NO CHANGE
      STA NDIRT     SAVE ANSWER 
*                             * 
**  GET NUMBER OF ID TRACKS  ** 
*                             * 
* 
*  REQUEST THE NUMBER OF ID TRACKS.  CHECK FOR A RESPONSE 
*  BETWEEN 1 AND 3. A SIMPLE CARRIAGE RETURN IMPLIES NO CHANGE. 
* 
LD231 EQU * 
      LDA .22       REQUEST NUMBER
      LDB NIDA        OF ID 
      JSB ASR35,I       TRACKS
      CLA,INA       RANGE IS
      LDB .3          1-3 
      JSB RQINA,I   GET RESPONSE
      JMP LD231     ERROR 
      RSS           CR IMPLIES NO CHANGE
      STA NIDT      SAVE ANSWER 
* 
* 
*                    *
**  BUILD DISC ADT  **
*                    *
* 
*  STARTING AT LOCATION 32000B, BUILD AN ADT FOR EACH ACTIVE
*  DISC (SELECT CODE # 0), USING 1400B WORDS FOR EACH ADT.
*  THE DISC ADT CONSISTS OF 3-WORD ENTRIES, THE FIRST 2 WORDS 
*  CONTAINING THE DISC ADDRESS AND THE LAST WORD THE LENGTH OF THE
*  AVAILABLE BLOCK. 
* 
LDR14 LDA DADTA     INITIALIZE ADT BUFFER POINTER 
      STA FADTC       FOR DISC 0
      LDA MHAD      => FIRST ENTRY
      STA TEMP3       IN DISC EQT 
LD241 JSB FNZSA,I   FIND AN ACTIVE DISC 
      JMP CLMDS     NONE FOUND
      LDA TEMP1     GET POINTER 
      ALS             TO
      ADA TEMP1         ADT LENGTH WORD 
      ADA DALNA           IN EQT
      STA TEMP5     SAVE POINTER TO LENGTH
      LDB M3        SET LENGTH
      STB A,I         TO 3 WORDS
      LDA M256      WORD COUNT FOR LOCKED BLOCKS TBL
      LDB .3        WHICH IS BLOCK THREE. 
      JSB DAIRA,I   FIX DISC ADDRESS AND
      LDB MTRLI       READ LOCKED BLOCKS TABLE
      JSB DISCC,I       FROM DISC 
      LDB FADTC     CURRENT ADT 
      STB TEMP1       BUFFER POINTER
      LDB MTRLA     LOCKED BLOCKS 
      STB TEMP0       BUFFER POINTER
      LDB TEMP0,I   FIRST AVAILABLE 
      CPB .4          BLOCK LOCKED? 
      JMP LD242     YES 
      LDB .4        NO, BLOCK 
      JSB DAIRA,I     4 IS
      LDA ADTMP         FIRST 
      DST TEMP1,I         BLOCK 
      LDA MXDAA,I   MAX # OF BLOCKS 
      JMP LD243 
LD242 EQU * 
      ISZ TEMP0     COMPUTE FIRST 
      ADB TEMP0,I     AVAILABLE BLOCK 
      JSB DAIRA,I   CONVERT FOR 
      LDA ADTMP       THIS DISC 
      DST TEMP1,I       AND SAVE
      LDA TEMP0,I   COMPUTE # 
      CMA,INA         OF BLOCKS 
      ADA MXDAA,I   AVAILABLE 
      SZA,RSS       CHECK FOR A COMPLETELY
      JMP LD245       LOCKED DISC 
      ISZ TEMP0 
LD243 EQU * 
      LDB TEMP1     SAVE LENGTH 
      ADB .2          OF FIRST
      STA B,I           ENTRY 
LD244 EQU * 
      LDB TEMP0     END OF LOCKED 
      CPB MTRND       BLOCKS TABLE? 
      JMP LD247     YES 
      LDB TEMP0,I   NO, ALL 
      SZB,RSS         ENTRIES DONE? 
      JMP LD247     YES 
      JSB DAIRA,I   NO, CONVERT ADDRESS 
      LDA ADTMP       OF LOCKED BLOCK 
      SKP 
      DST ABSEC     COMPUTE NEW 
      DLD TEMP1,I     LENGTH OF 
      JSB DBSBA,I       ADT ENTRY 
      ISZ TEMP1 
      ISZ TEMP1 
      STB TEMP1,I   STORE NEW LENGTH
      LDB TEMP0,I   COMPUTE 
      ISZ TEMP0       ADDRESS 
      ADB TEMP0,I       OF NEW
      ISZ TEMP0 
      JSB DAIRA,I         ADT ENTRY 
      LDA ADTMP 
      ISZ TEMP1 
      DST TEMP1,I   SAVE IT 
      LDB .4        COMPUTE 
      ADB MXDAA,I          LENGTH 
      JSB DAIRA,I       OF
      LDA ADTMP           NEW 
      DST ABSEC             ADT 
      DLD TEMP1,I             ENTRY 
      JSB DBSBA,I   ZERO
      SZB,RSS         LENGTH? 
      JMP LD247     YES, FORGET IT
      LDA TEMP1     NO, 
      ADA .2          SAVE
      STB A,I           LENGTH
      LDA TEMP5,I   INCREASE
      ADA M3          DISC ADT
      STA TEMP5,I       LENGTH
      JMP LD244     GO LOOK AT NEXT LOCKED BLOCK
LD247 EQU * 
      LDB TEMP3     FINISHED
      CPB MHAD        ALL DISCS?
      JMP CLMDS     YES. CLAIM DISC SPACE 
      LDA FADTC     BUMP ADT BUFFER POINTER FOR 
      ADA O1400       BUILDING NEXT ADT 
      STA FADTC 
      JMP LD241     NO
* 
LD245 CLA 
      STA TEMP5,I   SAY NO ROOM AT ALL
      JMP LD247 
      SKP 
*                       * 
**  CLAIM DISC BLOCKS  ** 
*                       * 
* 
*  CLAIM BLOCKS ON DISC 0 FOR THE SYSTEM, AND STORE THEIR ADDRESSES 
*  IN SST IF PAPER TAPE LOAD OR IN A TEMPORARY TABLE IF MAG TAPE
*  RELOAD.  THEN CLAIM BLOCKS FOR IDT, ADT & DIRECTORY TRACKS,
*  WHICH HAVE TO START ON CYLINDER BOUNDARIES OF 7900 DISC. 
*  IF ISS DISC IS USED, THE DISC SPACE ALLOCATED MUST NOT CROSS 
*  CYLINDER BOUNDARY. 
* 
CLMDS LDA DADTA     => ADT BUFFER 
      STA DCADA,I   SAVE FOR FSDAD
      CLB           SAY NOT ALTERNATE ALLOCATION
      DST DCFLG       AND TO REMOVE SPACE 
      LDA DMLTB,I   GET TOTAL 
      ADA ELDSA,I     NUMBER OF 
      STA TEMP0         SYSTEM SEGMENTS 
      LDB EMLTB     => LENGTH OF
      STB TEMP1       FIRST SEGMENT 
GET1  EQU * 
      CLA           SET FOR 
      STA LTP1A,I     FSDAD 
      LDA TEMP1,I   FIND SPACE
      AND M256
      CMA,INA         ON DISC 0 
      ALF,ALF 
      LDB DALNA         FOR THIS SEGMENT
      JSB FSDAC,I 
      JMP LDRWI,I   NO ROOM ON THIS DISC
      ISZ TEMP1     SAVE
      ISZ TEMP1       DISC ADDRESS
      DST TEMP1,I       IN SST
      ISZ TEMP1 
      ISZ TEMP1 
      ISZ TEMP0     FINISHED ALL SEGMENTS?
      JMP GET1      NO
* 
*                              *
**  CLAIM DISC SPACE FOR IDTS **
*                              *
      LDA NIDT      INITIALIZE COUNTER
      CMA,INA 
      STA CNTER 
      LDA IDECA     SET PTR TO
      INA             DISC ADDR 
GET3  STA PTR           IN IDEC ENTRY 
      LDA BUMPA     SET SUBROUTINE POINTER
      STA CLMFA,I     FOR ALL ADT'S IN CORE 
      LDA .32       CLAIM 32 BLOCKS 
      JSB CLAMA,I     FOR EACH ID TRACK 
      DST PTR,I     SAVE DISC ADDR ALLOCATED
      SKP 
      LDA PTR       => NEXT 
      ADA .4          IDEC ENTRY
      ISZ CNTER     ALL DONE ?
      JMP GET3      NO
* 
*                                *
**  CLAIM DISC SPACE FOR ADT'S  **
*                                *
      CLA           INIT. COUNTER 
      STA ADISC       FOR # LOGICAL DISC
      LDA TRKTC     => TEMPORARY TABLE
      STA PTR         FOR SAVING POINTERS 
      LDA MHAD      SET FOR 
      STA TEMP3       FNZSC 
GET4  JSB FNZSA,I   FIND AN ACTIVE DISC 
      JMP GET5      NO MORE. START CLAIMING 
      ISZ ADISC     BUMP COUNTER FOR ACTIVE DISC
      LDA TEMP1     GET LOGICAL DISC #
      MPY .3          AND COMPUTE POINTER TO
      ADA DALCA         DISC ADDR OF ADT IN EQT 
      STA PTR,I     AND SAVE IN TEMPORARY TABLE 
      ISZ PTR       => NEXT LOCATION IN TEMP. TABLE 
      LDA TEMP3     HAVE WE GONE THROUGH
      CPA MHAD        ALL THE DISCS?
      RSS           YES. START CLAIMING.
      JMP GET4      LOOK FOR MORE ACTIVE DISCS
GET5  LDA ADISC     SET COUNTER TO
      CMA,INA         # ACTIVE
      STA CNTER         DISCS 
      LDA TRKTC     => BEGINNING OF 
      STA PTR         TEMPORARY TABLE 
GET51 LDA PTR,I     GET POINTER TO ENTRY FOR
      STA EPTR        ADT'S DISC ADDRESS
      LDA .32       CLAIM 32 BLOCKS FOR 
      JSB CLAMA,I     EACH ADT
      DST EPTR,I    SAVE DISC ADDR ALLOCATED
      ISZ PTR       => NEXT ENTRY IN TEMP. TABLE
      ISZ CNTER     ALL DISCS TAKEN CARE OF?
      JMP GET51     NO. 
* 
*                                           * 
**  CLAIM DISC SPACE FOR DIRECTORY TRACKS  ** 
*                                           * 
      LDA ADISC     COMPUTE TOTAL 
      MPY NDIRT       # DIRECTORY TRACKS NEEDED 
      CMA,INA 
      STA CNTER 
      LDA DIRCA     => WORD IN DIREC FOR
      ADA .5          SAVING DISC ADDR ALLOCATED
GET6  STA PTR 
      LDA .32       CLAIM 32 BLOCKS 
      JSB CLAMA,I     FOR EACH DIRECTORY TRACK
      SKP 
      DST PTR,I 
      LDA PTR       => NEXT ENTRY 
      ADA .7          IN DIREC
      ISZ CNTER     ALL TRACKS CLAIMED? 
      JMP GET6      NO
* 
*                                       * 
**  WRITE PSUEDO ENTRIES TO DIRECTORY  ** 
*                                       * 
      LDB M24 
      STB MWORD     24 WORDS FOR 2 ENTRIES
      LDA DIRCA     => DISC ADDRESS 
      ADA .5          OF 1ST DIRECTORY TRACK
      LDB PSEUA     => PSEUDO ENTRIES TEMPLET 
      JSB DISCC,I   WRITE IT OUT
* 
*                         * 
**  WRITE ADT'S TO DISC  ** 
*                         * 
      LDA ADISC     SET COUNTER 
      CMA,INA         TO # OF 
      STA CNTER         ACTIVE DISCS
      LDA TRKTC     => TABLE OF POINTERS TO 
      STA PTR         DISC ADDR OF ADT IN EQT 
      LDA DADTA     INITIALIZE POINTER
GET9  STA FADTC       TO FIRST ADT IN ADT BUFFER
      LDA PTR,I     => DOUBLE WORD DISC ADDR
      LDB A 
      ADB .2        => LENGTH IN -WORDS OF ADT
      LDB B,I       SET WORD COUNT
      STB MWORD       FOR DISC DRIVER 
      LDB FADTC     => FIRST ENTRY OF ADT 
      JSB DISCC,I   WRITE ADT TO DISC 
      LDA FADTC     BUMP POINTER
      ADA O1400       TO ADT IN CORE
      ISZ PTR       => NEXT ENTRY IN POINTER TABLE
      ISZ CNTER     FINISHED ALL DISCS? 
      JMP GET9      NO. WRITE NEXT ONE
      JMP LDR25,I   YES.
