      LDA IR13      IR13 = DEF X13
      JSB A,I 
P13   HLT 0         JSB A,I FAILED
X13   NOP 
      CPA IR13
      RSS 
      HLT 0         JSB A,I FAILED - A REG. CHANGED 
      LDB ADR13     ADR13 = DEF P13 
      CPB X13 
      RSS 
      HLT 0         JSB A,I FAILED - BAD RETURN ADDR
* 
      CLB 
      STB X14       X14 _ NOP 
      LDB IR14      IR14 = DEF X14
      JSB B,I 
P14   HLT 0         JSB B,I FAILED
X14   NOP 
      CPB IR14
      RSS 
      HLT 0         JSB B,I FAILED - B REG. CHANGED 
      LDB ADR14     ADR14 = DEF P14 
      CPB X14 
      RSS 
      HLT 0         JSB B,I FAILED - BAD RETURN ADDR
* 
      LDA K1
      STA T1        T1 = K1 = 052524
      LDA IA9       IA9 = DEF T1
      ISZ A,I 
      RSS 
      HLT 0         ISZ A,I FAILED - IT SKIPPED 
      LDB T1
      CPB EVEN1     EVEN1 = 052525
      RSS 
      HLT 0         ISZ A,I FAILED - T1 NOT 052525
* 
      CCB 
      STB T1        T1 = 177777 
      LDB IA9       IA9 = DEF M1,  M1 = 177777
      ISZ B,I 
      HLT 0         ISZ B,I FAILED - DID NOT SKIP 
      LDA T1
      SZA 
      HLT 0         ISZ B,I FAILED - T1 NOT 0 
* 
      NOP ***** MODULE LOOP 
      HED ITERATIVE TESTS 
* THESE TESTS TRY TO FIND INTERMITTANT ERRORS 
* 
* LDA/CPA ITERATIVE TESTS 
* 
      CLB 
LP1   LDA EVEN1     A=052525
      CPA EVEN1 
      RSS 
      HLT 0         LDA/CPA FAILED
      ISZ B 
      JMP LP1 
* 
      CLB 
LP2   LDA ODD1      A=125252
      CPA ODD1
      RSS 
      HLT 0         LDA/CPA FAILED
      ISZ B 
      JMP LP2 
* 
* LDB/CPB ITERATIVE TESTS 
* 
      CLA 
LP3   LDB EVEN1     B=052525
      CPB EVEN1 
      RSS 
      HLT 0         LDB/CPB FAILED
      ISZ A 
      JMP LP3 
* 
      CLA 
LP4   LDB ODD1      B=125252
      CPB ODD1
      RSS 
      HLT 0         LDB/CPB FAILED
      ISZ A 
      JMP LP4 
* 
* LDA/STA/CPA ITERATIVE TESTS 
* 
      CLB 
LP5   LDA EVEN1     A=052525
      STA T1
      CPA T1
      RSS 
      HLT 0         LDA/STA/CPA FAILED
      ISZ B 
      JMP LP5 
* 
      CLB 
LP6   LDA ODD1      A=125252
      STA T1
      CPA T1
      RSS 
      HLT 0         LDA/STA/CPA FAILED
      ISZ B 
      JMP LP6 
* 
* LDB/STB/CPB ITERATIVE TESTS 
* 
      CLA 
LP7   LDB EVEN1     B=052525
      STB T1
      CPB T1
      RSS 
      HLT 0         LDB/STB/CPB FAILED
      ISZ A 
      JMP LP7 
* 
      CLA 
LP8   LDB ODD1      B=125252
      STB T1
      CPB T1
      RSS 
      HLT 0         LDB/STB/CPB FAILED
      ISZ A 
      JMP LP8 
* 
* AND ITERATIVE TESTS 
* 
      CLB 
LP9   LDA EVEN1 
      AND ODD1
      SZA 
      HLT 0         AND FAILED
      ISZ B 
      JMP LP9 
* 
      CLB 
LP10  LDA EVEN1 
      AND EVEN1 
      CPA EVEN1 
      RSS 
      HLT 0         AND FAILED
      ISZ B 
      JMP LP10
* 
      CLB 
LP11  LDA ODD1
      AND ODD1
      CPA ODD1
      RSS 
      HLT 0         AND FAILED
      ISZ B 
      JMP LP11
* 
* IOR ITERATIVE TESTS 
* 
      CLB 
LP12  LDA EVEN1 
      IOR ODD1
      CPA M1
      RSS 
      HLT 0         IOR FAILED
      ISZ B 
      JMP LP12
* 
      CLB 
LP13  LDA ODD1
      IOR EVEN1 
      CPA M1
      RSS 
      HLT 0         IOR FAILED
      ISZ B 
      JMP LP13
* 
      CLB 
LP14  LDA EVEN1 
      IOR EVEN1 
      CPA EVEN1 
      RSS 
      HLT 0         IOR FAILED
      ISZ B 
      JMP LP14
* 
      CLB 
LP15  LDA ODD1
      IOR ODD1
      CPA ODD1
      RSS 
      HLT 0 
      ISZ B         IOR FAILED
      JMP LP15
* 
* XOR ITERATIVE TESTS 
* 
      CLB 
LP16  LDA EVEN1 
      XOR EVEN1 
      SZA 
      HLT 0         XOR FAILED
      ISZ B 
      JMP LP16
* 
      CLB 
LP17  LDA ODD1
      XOR ODD1
      SZA 
      HLT 0         XOR FAILED
      ISZ B 
      JMP LP17
* 
      CLB 
LP18  LDA EVEN1 
      XOR ODD1
      CPA M1
      RSS 
      HLT 0         XOR FAILED
      ISZ B 
      JMP LP18
* 
* ADA ITERATIVE TESTS 
* 
      CLB 
LP19  CLE 
      CLO 
      LDA EVEN1 
      ADA ODD1      052525 + 125252 = 177777
      CPA M1
      RSS 
      HLT 0         SUM NOT 177777
      SEZ 
      HLT 0         E NOT 0 
      SOC 
      HLT 0         OV NOT 0
      ISZ B 
      JMP LP19
* 
      CLB 
LP20  STO           OV=1
      CCE           E=1 
      LDA ODD1
      ADA EVEN1     125252 + 052525 = 177777
      CPA M1
      RSS 
      HLT 0         SUM NOT 177777
      SEZ,RSS 
      HLT 0         E NOT 1 
      SOS 
      HLT 0         OV NOT 1
      ISZ B 
      JMP LP20
* 
      CLB 
LP21  CLE           E=0 
      CLO           OV=1
      LDA EVEN1     052525 + 052525 = 125252
      ADA EVEN1 
      CPA ODD1
      RSS 
      HLT 0         SUM NOT 125252
      SEZ 
      HLT 0         E NOT 0 
      SOS 
      HLT 0         OV NOT 1
      ISZ B 
      JMP LP21
* 
      CLB 
LP22  CLE           E=0 
      CLO           OV=0
      LDA ODD1      125252 + 125252 = 052524
      ADA ODD1
      CPA K1
      RSS 
      HLT 0         SUM NOT 052524
      SEZ,RSS 
      HLT 0         E NOT 1 
      SOS 
      HLT 0         OV NOT 1
      ISZ B 
      JMP LP22
* 
* ADB ITERATIVE TESTS 
* 
      CLA 
LP23  CLE           E=0 
      CLO           OV=0
      LDB EVEN1 
      ADB ODD1      052525 + 125252 = 177777
      CPB M1
      RSS 
      HLT 0         SUM NOT 177777
      SEZ 
      HLT 0         E NOT 0 
      SOC 
      HLT 0         OV NOT 0
      ISZ A 
      JMP LP23
* 
      CLA 
LP24  CCE           E=1 
      STO           OV=1
      LDB ODD1
      ADB EVEN1     125252 + 052525 = 177777
      CPB M1
      RSS 
      HLT 0         SUM NOT 177777
      SEZ,RSS 
      HLT 0         E NOT 1 
      SOS 
      HLT 0         OV NOT 1
      ISZ A 
      JMP LP24
* 
      CLA 
LP25  CLE           E=0 
      CLO           OV=0
      LDB EVEN1 
      ADB EVEN1     052525 + 052525 = 125252
      CPB ODD1
      RSS 
      HLT 0         SUM NOT 125252
      SEZ 
      HLT 0         E NOT 0 
      SOS 
      HLT 0         OV NOT 1
      ISZ A 
      JMP LP25
* 
      CLA 
LP26  CLE           E=0 
      CLO           OV=0
      LDB ODD1
      ADB ODD1      125252 + 125252 = 052524
      CPB K1
      RSS 
      HLT 0         SUM NOT 052524
      SEZ,RSS 
      HLT 0         E NOT 1 
      SOS 
      HLT 0         OV NOT 1
      ISZ A 
      JMP LP26
* 
* JSB ITERATIVE TEST
* 
      CLB 
LP27  CLA 
      STA Z2        Z2 _ NOP
      JSB *+2       JSB FAILED - DID NOT JUMP 
Z1    HLT 0 
Z2    NOP 
      LDA Z2
      CPA ADDR7     ADDR7 = ADDRESS Z1
      RSS 
      HLT 0         JSB FAILED - BAD RETURN ADDRESS 
      ISZ B 
      JMP LP27
* 
* ADA & ISZ ITERATIVE TEST
* 
      CLA 
      STA T1
      ADA K7        000000 + 034075 * 65K = 000000
      ISZ T1
      JMP *-2 
      SZA 
      HLT 0         ADA OR ISZ FAILED 
* 
* ADB & ISZ ITERATIVE TEST
* 
      CLB 
      STB T1
      ADB K7        000000 + (64K) * 034075 = 000000
      ISZ T1
      JMP *-2 
      SZB 
      HLT 0         ADB OR ISZ FAILED 
* 
      NOP ***** MODULE LOOP 
      HED SOME DATA PATTERN TESTS 
* LDA/CPA - ALL OF CORE - 1ST 2 PAGES 
* 
      LDB FCA       1ST CORE ADDRESS = 000002 
PT1   LDA B,I 
      CPA B,I 
      RSS 
      HLT 0         LDA/CPA FAILED:  B = ADDRESS
      CPB LCA       LAST CORE ADDRESS = 003677
      JMP PT2 
      INB           NEXT CORE ADDRESS 
      JMP PT1       CONTINUE
* 
* LDB/CPB/STB/CPB - ALL OF CORE - 1ST 2 PAGES 
* 
PT2   LDA FCA       1ST CORE ADDRESS = 000002 
PT3   LDB A,I 
      CPB A,I 
      RSS 
      HLT 0         LDB/CPB FAILED:  A = ADDRESS
      STB A,I 
      CPB A,I 
      RSS 
      HLT 0         STB/CPB FAILED:  A = ADDRESS
      CPA LCA       LAST CORE ADDRESS = 003677
      JMP PT4 
      INA           NEXT CORE ADDRESS 
      JMP PT3       CONTINUE
* 
* ADA - ADB - IOR - XOR - AND USING TABLE VALUES
* 
PT4   LDB TBLA      FWA TABLE 
PT5   STB A1A       ARG 1 ADDRESS 
      INB 
      STB A2A       ARG 2 ADDRESS 
      INB 
      STB SUMA      SUM ADDRESS 
      INB 
      STB IORA      IOR RESULT ADDRESS
      INB 
      STB XORA      XOR RESULT ADDRESS
      INB 
      STB ANDA      AND RESULT ADDRESS
      LDA A1A,I 
      ADA A2A,I 
      CPA SUMA,I
      RSS 
      HLT 0         ADA FAILED
      LDB A1A,I 
      ADB A2A,I 
      CPB SUMA,I
      RSS 
      HLT 0         ADB FAILED
      LDA A1A,I 
      IOR A2A,I 
      CPA IORA,I
      RSS 
      HLT 0         IOR FAILED
      LDA A1A,I 
      XOR A2A,I 
      CPA XORA,I
      RSS 
      HLT 0         XOR FAILED
      LDA A1A,I 
      AND A2A,I 
      CPA ANDA,I
      RSS 
      HLT 0         AND FAILED
      LDB ANDA
      INB 
      CPB TBLE
      RSS           END OF TABLE
      JMP PT5 
* 
      NOP ***** MODULE LOOP 
      SPC 3 
* END OF DIAGNOSTIC CYCLE 
* 
      LIA 1 
      AND BIT12 
      SZA,RSS 
      HLT 77B       END OF PASS HALT
      JMP START     DO AGAIN
      SPC 3 
A1A   NOP      ARGUMENT POINTER 
A2A   NOP      ARGUMENT POINTER 
SUMA  NOP      SUM POINTER
IORA  NOP      IOR RESULT POINTER 
XORA  NOP      XOR RESULT POINTER 
ANDA  NOP      AND RESULT POINTER 
K10A  DEF K10 
K11A  DEF K11 
T1A   DEF T1
K12A  DEF K12 
JMP5A DEF JMP5
JSB7A DEF JSB7
P7A   DEF P7
* 
TBLA  DEF TBL.1     1ST TABLE ADDRESS 
TBL.1 OCT 15366     ARG 1 - 1ST PAIR
      OCT 127541    ARG 2 
      OCT 145127    SUM 
      OCT 137767    IOR RESULT
      OCT 132627    XOR RESULT
      OCT 5140      AND RESULT
TBL.2 OCT 51463     ARG 1 - 2ND PAIR
      OCT 31465 
      OCT 103150
      OCT 71467 
      OCT 60006 
      OCT 11461 
TBL.3 OCT 161271    ARG 1 - 3TH PAIR
      OCT 25636     ARG 2 
      OCT 7127      SUM 
      OCT 165677    IOR RESULT
      OCT 144447    XOR RESULT
      OCT 21230     AND RESULT
TBL.4 OCT 105560    ARG 1 - 4TH PAIR
      OCT 133410
      OCT 41170 
      OCT 137570
      OCT 36170 
      OCT 101400
TBL.5 OCT 141655    ARG 1 - 5TH PAIR
      OCT 35334 
      OCT 177211
      OCT 175775
      OCT 174561
      OCT 1214
TBL.6 OCT 175752    ARG 1 - 6TH PAIR
      OCT 137257
      OCT 135231
      OCT 177757
      OCT 42505 
      OCT 135252
TBL.7 OCT 32047     ARG 1 - 7TH PAIR
      OCT 41163 
      OCT 73232 
      OCT 73167 
      OCT 73124 
      OCT 43
TBL.8 OCT 66144     ARG 1 - 8TH PAIR
      OCT 143106
      OCT 31252 
      OCT 167146
      OCT 125042
      OCT 42104 
TBL.9 OCT 122241    ARG 1 - 9TH PAIR
      OCT 45032 
      OCT 167273
      OCT 167273
      OCT 167273
      OCT 0 
TB.10 OCT 156336    ARG 1 - 10TH PAIR 
      OCT 146755
      OCT 125313
      OCT 156777
      OCT 10463 
      OCT 146314
TBLE  DEF *         LWA TABLE 
* 
T2    NOP           TEMPORARY STORAGE 
SR1   NOP           SUBROUTINE FROM BASE PAGE 
      JMP .P4         GO BACK 
JMP1  JMP JMP2      GO BACK TO BASE PAGE
* 
      END 
                                                                    