      CPA EQ.L     COMPARE TO OCTAL 114 "L" 
      JMP ID2      YES, GO PROCESS SYMBOLS
      LDB MIN2     LOAD: B=-2 
      STB L.DLM    SET THE LITERAL COUNT FLAG.
      ADB ID1      DECREMENT SYMBOL LIMIT BY 2
      STB ID1      ALLOW SYMBOL TO BE 7 CHARS.
      LDB .EQ.     NO, LOAD THE SPECIAL "=".
      LDA EQUAL    LOAD AN "=" CHAR.
      CPA NEXT     IS THE NEW CHAR. AN "="
      STB NEXT     YES, STORE THE SPECIAL "=".
      JMP ID4      GO ENTER "=" INTO LABEL STRING.
      SPC 1 
LETMX OCT 55
LETMN OCT -6
      SPC 2 
* DIGIT DETERMINES WHETHER THE CHARACTER IN A IS A DIGIT *
SAVE. BSS 1 
      SPC 1 
DIGIT NOP 
      LDB 0         GET CHAR IN B 
      CMB,INB         AS NEGATIVE 
      ADB DIGMX     COMPARE TO MAXIMUM DIGIT (ASC9) 
      SSB 
      JMP NODIG 
      ADB DIGMN       AND TO MINIMUM DIGIT (ASC0) 
      SSB,RSS 
NODIG ISZ DIGIT     SKIP RETURN IF NOT A DIGIT
      JMP DIGIT,I 
      SPC 1 
DIGMX OCT 71
      SKP 
* CONSTANTS & VARIABLES * 
      SPC 1 
SEQNO NOP 
LABCT NOP 
.XTAB NOP 
TAPE1 OCT 004000    TAPE NUMBER  ---  INCREMENT CONSTANT. 
TAPNO NOP 
NEXT  NOP 
DEC73 DEC 73
DEC72 DEC 72
BUFAD DEF CBUF
CCNT  NOP 
CHAR1 NOP 
STAR  OCT 52
BLANK OCT 40
PLUS  OCT 53
MINUS OCT 55
SLASH OCT 57
COMMA OCT 54
LPREN OCT 50
RPREN OCT 51
BL.AS ASC 1, *
BL.EQ ASC 1, =
DOT   OCT 56
QUEST OCT 77
EQUAL OCT 75
EQ.L  OCT 114 
.EQ.  OCT 275 
L.DLM OCT 440 
SSTAR OCT 24000 
SPCLB OCT 1452
MASK8 OCT 377 
MASK9 OCT 7777
UPBLN OCT 20000 
LINES NOP 
ZERO  DEC 0 
MAXCC DEC -72 
PNTR1 NOP 
PNTR2 NOP 
ORDNL NOP 
TEMP  NOP 
.TEST DEF TEST
COUNT NOP 
..LAB DEF LABEL-1 
.LAB  DEF LABEL 
TEMP1 NOP 
HIBND BSS 1 
LOBND BSS 1 
TWO   DEC 2 
BESTL NOP 
BESTO NOP 
MSK12 OCT 003777    11 BIT SEQUENCE NUMBER MASK = 2048. 
.P10  DEF *+1 
      DEC -10000,-1000,-100,-10,-1
MIN1  EQU *-1 
MTEN  EQU *-2 
DIGMN EQU MTEN
SQ1   NOP 
MIN4  DEC -5
PCOUN NOP 
SIXTY OCT 60
CR1   NOP 
LBLCT OCT 000000
.NAME DEF BLBX
MAXLN DEC -57       MAXIMUM LINE WHEN PRINTING "DD" 
MIN57 DEC -56 
LNSKP DEC -56 
OUTBF NOP 
SETCC DEC -64 
MASK7 OCT 177 
CPNTR NOP 
FEED  OCT 12
.LOOK NOP 
LOOKC NOP 
LOOK. NOP 
MIN2  DEC -2
PUTS1 NOP 
PUTS5 NOP 
ONEBL OCT 440 
INDIR NOP           SET WHEN A COMMA IS ENCOUNTERED 
*                                     AND A MULTI-OPERAND INSTR.
*                                       IS BEING PROCESSED. 
TEMP2 NOP 
OPCNT NOP           NUMBER OF OPERANDS IN CURRENT STATEMENT 
FXEND DEF OPEND     "CODED" END OF OP-CODE TABLE
MICOP DEF EJMP      INDEX VALUE OF START OF MICRO OPS 
LABCH NOP 
HIGH1 OCT 400 
      ASC 1,
DD    ASC 1,DD
      ASC 1,
LABEL BSS 4 
CBUF  BSS 36
BLBX  ASC 2,
NAME  BSS 3 
BLBL  ASC 16,       CROSS-REFERENCE SYMBOL TA 
      ASC 8,BLE        PAGE 
PGNUM BSS 2 
      ASC 1,A 
HEDCT DEC 62
      DEC 64
RUN   BSS 1 
PAGNO BSS 1 
A.... ASC 1,A 
.TAPE BSS 1 
TPCNT BSS 1 
      SKP 
      SPC 2 
DDERR LDA LABEL     PRINT DOUBLY DEFINED MESSAGE
      AND MASK8 
      IOR UPBLN 
      STA LABEL 
      LDB MIN57 
      CLA,INA 
      ADB DDFLG     IF "DD" COUNTER IS EQUAL
      SSB             OR GREATER THAN 56
      ADA DDFLG         RESET "DD" COUNTER TO 1 
      STA DDFLG           OTHERWISE INCR  IT. 
      LDA RUN      LOAD A WITH RUN
      SZA,RSS      IF RUN IS NOT ZERO SKIP
      JMP DEER     = ZERO SKIP NEXT PART
      ISZ LNNE     INCREMENT WRITE INSTR. TO LONGER 
      JSB LNE      GO WRITE LINE
      CCA          SET A TO -1
      ADA LNNE     SUBTRACT -1 TO RESTORE WRITE LENTH 
      STA LNNE     SET TO ORIGINAL VALUE
      LDA LINES    LOAD A WITH LINE COUNT 
      CPA MIN57    SKIP IF -57
      RSS          NO, SKIP NEXT INSTRUCTION
      JMP DEER+1   SKIP NEXT SERIES OF INSTRUCTIONS 
      CCA          SET A TO -1
      ADA PAGNO    AND ADD TO PAGE NUMBER 
      STA PAGNO    STORE IN PAGE NUMBER 
      LDA HEDCT-1  LOAD A WITH HEDCT
      ADA HIGH1    SET TO NEXT ALPHA CHAR.
      STA HEDCT-1  STORE OVER OLD VALUE 
      RSS          SKIP NEXT INSTR. 
DEER  JSB LNE      IF RUN ZERO PRINT LINE NORMALLY
      LDA FEED
      ADA .2       ADD TWO
      LDB DEFDD 
      JSB WRITE 
      JMP PUTSQ,I 
      SPC 2 
DEFDD DEF DD-1
      SPC 2 
OVERR JSB EXEC
      DEF *+5 
      DEF .2
      DEF .1
      DEF OVDEF+1 
      DEF .7
      CLA 
      JMP STOP
      SPC 2 
      SPC 2 
OVDEF DEF *+1 
      ASC 7,TABLE OVERFLOW
TEST  BSS 4 
ID1   BSS 1 
* 
*     READ ROUTINE READS ONE RECORD FROM THE INPUT DEVICE SPECIFIED.
* 
*     CALLING SEQUENCE: 
* 
*         LDA <# CHARACTERS(+)> 
*         LDB <BUFFER ADDRESS>
*         JSB READ
* 
READ  NOP 
      CMA,INA 
      STA RDCNT 
      STB RD10
      JSB %READ     UTILITY READ ROUTINE
      DEF *+5 
      DEF IO/LU 
RD10  DEF * 
      DEF RDCNT 
      JMP NDFIL     END OF FILE ERROR RETURN
      STB A         SET # CHAR INA
      JMP READ,I    RETURN
RDCNT NOP 
NDFIL JSB EXEC
      DEF *+5 
      DEF .2
      DEF .1
      DEF ENDFA 
      DEF .6
      JMP STOP1 
ENDFA ASC 6,END OF FILE 
*     WRITE ROUTINE OUTPUTS ONE LINE TO OUTPUT DEVICE 
* 
*     CALLING SEQUENCE: 
*         LDA  # OF CHARS(+) OR 0 IF SINGLE SPACE 
*         LDB  BUFFER ADDRESS 
*         JSB  WRITE
* 
WRITE NOP 
      SZA,RSS       CHECK IF TO SPACE 1 LINE
      JMP WSPAC     YES 
      CMA,INA       CONVERT CHARS TO DOS CHAR COUNT 
      STA WRCNT 
      STB WRI10     STORE BUFFER ADDRESS
      JSB EXEC      OUTPUT ONE LINE 
      DEF *+5 
      DEF .2
      DEF .6
WRI10 NOP 
      DEF WRCNT 
      JMP WRITE,I   RETURN
* 
WSPAC JSB EXEC      OUTPUT SINGLE SPACE 
      DEF *+4 
      DEF .3
      DEF OCTCL 
      DEF .1
      JMP WRITE,I   RETURN
STOP  JSB EXEC
      DEF *+5 
      DEF .2
      DEF .1
      DEF BMESS 
      DEF M16 
STOP1 LDA SVSUB     GET ORIGINAL SUBCHANNEL # 
      LDB SAVE.     IF LUN IS = 2 
      CPB .2          GO RESTORE SUBCHANNEL # 
      JSB CHGSC         TO ORIGINAL VALUE.
      LDA TDEFS 
      LDB DEFS
      JSB EXEC     RESTORE ORIGINAL JFILS 
      DEF *+2 
      DEF N19 
      LDA TDEFC    RESTORE ORIGINAL JFILC 
      JSB EXEC
      DEF *+2 
      DEF N19 
      JSB EXEC     COMPLETION REQUEST 
      DEF *+2 
      DEF .6
BMESS ASC 8, X-REF COMPLETE 
* 
*     KEYBD READS INPUT FROM SYSTEM TELETYPE FOR SETTING
*   CROSS-REFERENCE GENERATION SEARCH LIMITS
* 
*     CALLING SEQUENCE: 
* 
*         LDA  <# CHARACTERS(+)>
*         LDB  <BUFFER ADDRESS
*         JSB  KEYBD
* 
KEYBD NOP 
      CMA,INA 
      STA WRCNT     FORM DOS CHARACTER COUNT
      STB *+5 
      JSB EXEC      READ IN # OF CHARACTERS 
      DEF *+5 
      DEF .1             REQUEST CODE 
      DEF CONWD          CONTROL WORD 
      NOP                BUFFER ADDRESS 
      DEF WRCNT          CHAR COUNT 
      JMP KEYBD,I   RETURN
CNDEC NOP          BINARY TO DECIMAL ASCII
      LDB .10 
      STB CNDIV 
      LDB A00 
      STB ASCI
      STB ASCI+1
      STB ASCI+2
      LDB CNMBR 
      STB CNMLC 
CNORG JSB DVUKN    DIVIDE BY 10 
      ADB CNMLC,I 
      STB CNMLC,I 
      SZA,RSS 
      JMP CNOUT 
      JSB DVUKN 
      BLF,BLF 
      ADB CNMLC,I 
      STB CNMLC,I 
      ISZ CNMLC 
      SZA 
      JMP CNORG 
CNOUT LDB CNMBR+3 
      LDA CNMBR+1 
      STA CNMBR+3 
      STB CNMBR+1 
      LDB CNMBR 
      JMP CNDEC,I 
DVUKN NOP 
      CLB          CLEAR LOOP COUNTER = QUOTIENT +
      STB DVTMP 
DVU00 STA B        FLAG ALLOW BIT 15 OF # TO BE SET 
DVU01 ADA CNDIV    DIDIDE BY SUCCESSIVE SUBTRACTION 
      ISZ DVTMP 
      SSA,RSS      DONE IF A IS NEG AND B IS POS
      JMP DVU00    CLEAR B TO ALLOW EXIT
      SSB          EXIT IF POS
      JMP DVU01    ORIGINAL # TO CONVERT WAS NEG
      LDB CNDIV    DONE 
      CMB,INB 
      ADB A        REMAINDER TO B 
      LDA DVTMP 
      ADA ..-1     QUOTIENT TO A
      JMP DVUKN,I 
DVTMP BSS 1 
CNDIV NOP 
..    EQU 53B 
.10   EQU ..-10 
CNMLC NOP 
A00   ASC 1,00
CNMBR DEF *+1 
ASCI  ASC 3,
*READS SOURCE FROM DISK (IF LUN= 2) OR OTHER DEVICE 
*RETURNS WITH: (B) = NO.OF CHARS. 
*CALLING SEQUENCE FOR %READ:  JSB %READ 
*                             DEF *+5 
*                             DEF LUNIN  LUN FOR INPUT
*                             DEF BUFFR  FWA OF READ-BUFFER 
*                             DEF RLEN  -(NO OF CHARS)
*                             EOF RETURN
*                             NORMAL RETURN 
%READ NOP 
      LDA %READ,I 
      STA EXIT      RETURN ADDRESS
      ISZ %READ 
      LDA %READ,I 
      STA LUNAD     ADDR FOR LUN OF INPUT 
      ISZ %READ 
      LDA %READ 
      LDA 0,I 
      RAL,CLE,SLA,ERA    TEST I-BIT AND CLEAR 
      JMP  *-2      INDIRECT, GO ON THRU INDIR.CHAIN
      STA RBFAD     FWA OF READ-BUFFER
      ISZ %READ 
      LDA %READ,I 
      STA RLGTH     RECORD-LENGTH ADDR
      ISZ %READ     BUMP RETURN ADDR FOR EOF RETURN 
      LDA LUNAD,I 
      CPA .2        LUN = 2 
      JMP READ1     YES 
      JSB EXEC      READ FROM OTHER THAN DISK 
      DEF *+5 
      DEF N1        REQUEST CODE-- -1 FOR READ
LUNAD BSS 1         ADDR OF INPUT-LUN OF CONTROL CARD 
RBFAD BSS 1         ADDR OF READ-BUFFER 
RLGTH BSS 1         ADDR OF ASKED-FOR RECD LENGTH 
      JMP EXIT,I    EXIT
EXIT  BSS 1         EXIT POINT
BUFFR BSS 128       SECTOR-BUFFER 
FIRST OCT 0         FIRST TIME FLAG 
READ1 LDA FIRST 
      SZA           FIRST TIME ?
      JMP READ2     NO
      JSB %JFIL 
READ2 JSB GETWD     GET RECORD HEAD 
      ALF,ALF       (A)= NO OF WORDS
      LDB A 
      SZA           END OF TAPE 
      JMP READ3     NO-GO CHECK FOR EOF 
      LDA JFILC     YES-IF NOT MULTI-FILE SOURCE
      SZA,RSS         THEN SKIP NEXT INST. AND RETURN 
      JSB %JFIL           OTHERWISE GET NEXT FILES
*                                           DISC ADDRESS. 
      CLB           SET EOF (JFILE) INDICATOR 
      JMP EXIT,I      AND RETURN. 
READ3 SSA           EOF?
      JMP %READ,I   YES, EOF RETURN 
      CMA,INA       -( NO OF WORDS IN RECORD) 
      RBL 
      STB ALGTH     RECORD LGTH IN CHARS
      LDB RLGTH,I   ASKED-FOR RECORD-LENGTH (-) 
      BRS           CONVERT TO -(WORD COUNT)
      STA RCOUN     SET CURRENT-RECORD COUNT
      STB ACOUN     SET ASKED-FOR RECORD COUNT
      JSB GETWD     GET WORD FROM DISK
      STA RBFAD,I   WORD TO USER-S BUFFER 
      ISZ RBFAD     BUMP BUFFER ADDR
      ISZ ACOUN     BUMP COUNT
      RSS 
      JMP READ4     READY, FINISH UP
      ISZ RCOUN     BUMP RECORD COUNT 
      JMP *-7       CONTINUE
      LDB ALGTH     RETURN ACTUAL RECORD-LENGTH 
      JMP *+5 
READ4 ISZ RCOUN     SKIP TO END OF RECORD 
      JMP *+5 
      LDB RLGTH,I   READY, RETURN ASKED-FOR REC.LGTH
      CMB,INB       POS LGTH
      LDA CODE      RETURN CODE-WORD IN A 
      JMP EXIT,I
      JSB GETWD     GET NEXT WORD 
      JMP READ4     AND SKIP
BFRAD BSS 1         POINTER FOR INTERNAL BUFFER 
GETWD NOP 
      LDA BFRAD,I 
      ISZ BFRAD 
      ISZ BCOUN     BUMP BUFFER COUNTER 
      JMP GETWD,I   EXIT
      ISZ SECTR     BUMP SECTOR NO. 
      LDB STYPE 
      SSB 
      JMP RTECD 
      STA SAVE
      LDB SECTR 
      CPB 116B      END OF TRACK? 
      CLB,RSS       YES,SECTOR = 0
      JMP GETW1+1 
      STB SECTR     SECTOR NO = 0 
      ISZ TRACK     BUMP TRACK NO.
      JSB EXEC
      DEF *+5 
      DEF .M16      CODE = -16 FOR STATUS 
      DEF .1        1 TRACK 
      DEF TRACK     STARTING TRACK
      DEF TRACK     NEXT GOOD TRACK 
      JMP GETW1+1 
RTECD LDB =B1755
      ADB RLUN      =1757B FOR SYST, 1760B FOR AUX. 
      LDB 1,I 
      CPB SECTR     END OF TRACK? 
      CLB,RSS       YES, SECTOR NO.= 0
      JMP GETW1 
      STA CODE      SAVE CODE-WORD
      STB SECTR     SECTOR NO =0
      LDA =D-8
      STA N 
      LDA CODE
      CLE,ELA       SHIFT UPPER 8 BITS OF 
      ELB,CLE        A INTO B, OR LSL 8 
      ISZ N 
      JMP *-3 
      ALF,ALF 
      STA TRACK     SET TRACK NO
      STB RLUN      SET LUN 
      JSB READS     READ SECTOR 
      JMP GETWD+1   GET RECORD WORD 
GETW1 STA SAVE
      JSB READS     READ NEXT SECTOR
      LDA SAVE
      JMP GETWD,I 
READS NOP 
      LDA BFWA
      STA BFRAD     BUFFER-POINTER= FWA BUFFER
      LDA MSIZE     -64 OR -128 
      STA BCOUN     BUFFER COUNTER
      JSB EXEC      READ SECTOR 
      DEF *+7 
      DEF N1        REQUEST CODE-- -1 FOR READ
      DEF RLUN      LUN 
BFWA  DEF BUFFR     FWA OF READ-BUFFER
      DEF PSIZE     64 OR 128 WORDS 
      DEF TRACK     TRACK NO. 
      DEF SECTR     SECTOR NO.
      JMP READS,I   EXIT
ACOUN BSS 1         ASKED-FOR RECD COUNT
RCOUN BSS 1         CURRENT-RECORD COUNT
ALGTH BSS 1         RECD LGTH 
TRACK BSS 1         CURRENT TRACK NO
SECTR BSS 1         CURRENT SECTOR NO 
BCOUN BSS 1         SECTOR-BUFFER COUNTER 
SAVE  BSS 1         TEMP STORAGE
RLUN  BSS 1         LUN OF CURRENT TRACK
CODE  BSS 1 
STYPE BSS 1         SAVES SYSTEM TYPE CODE FROM OPSY
N     BSS 1         COUNTER 
.M16  DEC -16 
.2OR3 DEC 2 
PSIZE DEC 64
MSIZE DEC -64 
* 
*%RDSC READS A SECTOR 
*CALLING SEQUENCE:       LDA CODE 
*                        LDB SECTR   SECTOR NO. 
*                        JSB %RDSC
*                        RETURN (A)= LAST WORD IN SECTOR
%RDSC NOP 
      STB SECTR      SECTOR NO. 
      LDB =D-8
      STB N 
      CLB 
      CLE,ELA 
      ELB,CLE       LSL 8 
      ISZ N 
      JMP *-3 
      CPB =D3       SET LU NEG IF = 3 
      CMB,INB 
      STB RLUN      LUN= 2 OR 3 
      ALF,ALF 
      STA TRACK 
      JSB READS      READ SECTOR
      LDB STYPE 
      LDA BUFFR+63  LAST WORD IN 64 WORD SECTOR 
      SLB 
      LDA BUFFR+127 LAST WORD IN 128 WORD SECTOR
      JMP %RDSC,I 
*%JFIL GETS SOURCE-FILE CODEWDRD FROM BASE PAGE, FORMS A WORD=
*LUN,TRACK AND CALLS %RDIN WITH IT. 
%JFIL NOP 
      LDA =D-8
      STA N 
      LDA STYPE 
      CLE,SSA 
      JMP RTEFL     RTE 
      LDB FIRST     IF FIRST TIME THROUGH 
      SZB             FLAG IS SET 
      JMP MFIL1         ASSUME MULTIPLE FILES.
      ISZ FIRST     SET FIRST TIME TIME THROUGH FLAG
      LDB JFILS     GET DISC ADDR OF SOURCE FILE
      LDA SAVE.     IF LUN
      CPA .2          IS NOT
      RSS               EQUAL TO 2
      JMP GTLUN           CONTINUE. 
      LDA JFILC     IF MULTIPLE FILES 
      SZA,RSS         ARE SPECIFIED IN "JFILE" DIR
      JMP MFIL0         GO ACCESS JFILE TABLE 
      LDA JFLSC 
      JMP CHGS2     GO CHANGE USER SUBCHAN IF DIFF. 
MFIL0 LDA SYSBF     GET SYSTEM BUFFER 
      AND B1774       DISC ADDRESS
      ADA B1774         AND CALCULATE 
      ALF,ALF             SCRATCH TRACK 
      STA JFTRK             ADDRESS.
      LDA .6        GET STARTING SECTOR ADDRESS 
      JMP MFIL2     GO DO INITIAL DISC READ 
MFIL1 ISZ SRCPT     BUMP PNTR TO NEXT SRC FILE ADDR.
      LDA SRCPT     IF PNTR 
      CMA,INA         IS NOT GREATER
      ADA JFEND         THAN LAST ENTRIES 
      SSA,RSS             ADDRESS 
      JMP MFIL3             CONTINUE. 
      LDA JFSEC     GET LAST SECTOR ADDRESSED 
      INA             AND INCREMENT BY 1. 
      CPA .8        IF SECTOR IS EQUAL TO "8" 
*                                     THEN SOURCE TABLE IS EXHAUSTED
      JMP %READ,I       RETURN TO PRINT "EOF" MESSAGE.
MFIL2 STA JFSEC               FOR JFILE SOURCE TABLE
      LDA TABAD     INITIALIZE PNTR TO START OF TABL
      STA SRCPT 
      JSB EXEC      GO READ 1 SECTOR
      DEF *+7 
********************POINTERS TO PARAMETERS
      DEF N1        REQUEST CODE   -1 FOR READ
      DEF CNWRD     LUN 
TABAD DEF JFTBL     FWA OF JFILE SOURCE TABLE 
      DEF TBLEN     LENGTH OF JFILE SOURCE TABLE
      DEF JFTRK     TRACK NO. 
      DEF JFSEC     SECTOR NO.
MFIL3 LDB SRCPT,I 
      SZB,RSS       IF SOURCE TABLE IS EXHAUSTED
      JMP %READ,I     RETURN TO PRINT "EOF" MESSAGE 
      ISZ SRCPT 
      LDA SRCPT,I   GET SUBCHANNEL FOR CURRENT FILE 
CHGS2 JSB CHGSC       AND SET CURRENT SUBCHANNEL. 
GTLUN LDA .2OR3     LUN = 2 OR 3
      JSB RRL       RRL 8 
      BLF,BLF 
      JMP CONTU 
CHGSC NOP 
      STB SAVEB     SAVE DISC ADDRESS OF SOURCE 
      LDB DEFCU     GET ADDRESS OF "CUDSC"
      JSB EXEC      GO SET "NEW" SUBCHANNEL 
      DEF *+2         IN BASE PAGE. 
      DEF RCODE 
      LDB SAVEB     RESTORE DISC ADDRESS OF SOURCE
      JMP CHGSC,I 
RTEFL LDB 1767B     SOURCE-FILE CODE WORD 
      CLA 
      CLE,ELB       RRL 1 
      ELA 
      ADA .2OR3 
      JSB RRL       SHIFT TRACK NO INTO A 
      STA CODE      SAVE LUN, TRACK NO. 
      CLB 
CONTU JSB %RDSC     READ SECTOR 
      JMP %JFIL,I   EXIT
RRL   NOP           PERFORMS RRL N
      CLE,SSA       IF MSB = 0, E=0 
      CCE            ELSE E=1 
      ELB           SHIFT E INTO B
      ELA           SHIFT E INTO A
      ISZ N 
      JMP RRL+1 
      JMP RRL,I 
CONWD OCT 401 
WRCNT NOP 
IO/LU NOP 
FTRAK NOP 
LTRAK NOP 
SIZE  NOP 
SVSUB BSS 1         SAVE AREA FOR CURRENT USER SUBCHANNEL 
SRCPT BSS 1         POINTER TO NEXT ENTRY IN
*                                     JFILE SOURCE TABLE. 
SAVEB BSS 1         SAVE AREA FOR "B" REG.
RCODE DEC -19       BASE PAGE STORE REQUEST CODE
CNWRD OCT 102       LUN 
TBLEN DEC 128       LENGTH OF JFILE SOURCE TABLE
JFTRK NOP           TRACK NO. 
JFSEC NOP           SECTOR NO.
JFEND DEF JFTBL+127 
JFTBL BSS 128       JFILE SOURCE ADDRESS TABLE
OCTCL OCT 1106
M16   DEC -16 
N19   DEC -19 
DEFS  OCT 124 
DEFC  OCT 125 
DEFCU OCT 161       ADDRESS OF "CUDSC"
TDEFS NOP 
TDEFC NOP 
RM1   OCT 077777
RM2   OCT 100000
RM3   RAL 
RM4   OCT 003777
RM5   OCT 004000
RM6   ALF,RAL 
DEFCB DEF CBUF
DEFLB DEF LABEL 
LETOP NOP 
DDFLG NOP 
TEMPZ NOP 
NINE  DEC 9 
EMESG ASC 9,ENTER LIMITS OR /E
SLSHE ASC 1,/E
A     EQU 0 
SWICH DEF *+1,I 
SJMP  EQU * 
      DEF RAC       0 
      DEF DOSOP     ABS 
      DEF DOSOP     ADA 
      DEF DOSOP     ADB 
      DEF DOSOP     ADX 
      DEF DOSOP     ADY 
      DEF DOSOP     AND 
      DEF DOSOP     ASC 
      DEF DOSOP     ASL 
      DEF DOSOP     ASR 
      DEF DOSOP     ATD 
      DEF DOSOP     BAD 
      DEF DOSOP     BCM 
      DEF DOSOP     BDV 
      DEF DOSOP     BMU 
      DEF DOSOP     BSB 
      DEF DOSOP     BSS 
      DEF DOSOP     BTD 
      DEF DOSOP     CBS 
      DEF DOSOP     CBT 
      DEF DOSOP     CLC 
      DEF DOSOP     CLF 
      DEF DOSOP     CMW 
      DEF DOCOM     COM 
      DEF DOSOP     CPA 
      DEF DOSOP     CPB 
      DEF DOSOP     DAD 
      DEF DOSOP     DBL 
      DEF DOSOP     DBR 
      DEF DOSOP     DCP 
      DEF DOSOP     DCS 
      DEF DOSOP     DEF 
      DEF DOSOP     DIV 
      DEF DOSOP     DJP 
      DEF DOSOP     DJS 
      DEF DOSOP     DLD 
      DEF DOSOP     DSB 
      DEF DOSOP     DSF 
      DEF DOSOP     DSN 
      DEF DOSOP     DST 
      DEF DOSOP     DTA 
      DEF DOSOP     DTB 
                      