                                          /12-29-67
/CONVERSION OF FRIDEN (EIA) TO ASCII

	*400
	CLA CLL
	TLS
START,	DCA CNTRL
	DCA CNT
	DCA SWITCH
	DCA CNTRL2
CONTIN,	JMS I TABFIX
	JMS READ
	TAD SAVE
	TAD EIATR
	SZA CLA
	JMP DOWN
	ISZ CNTRL
	TAD CNT
	SZA CLA
	JMP .+2
	JMS LDTR
	TAD CNTRL
	TAD TEST1
	SZA CLA
	JMP CONTIN
	TAD CNTRL2
	SNA CLA
	JMP .+4
	JMS LDTR
	HLT
	JMP START
	DCA CNTRL
	JMP CONTIN
DOWN,	TAD CNT
	SZA CLA
	JMP CRCK
	JMS LDTR
CRCK,	TAD SAVE
	SZA CLA
	JMP .+2
	JMS CRLF
CHARCK,	TAD SAVE
	TAD NUM
	SZA CLA
	JMP .+4
	CMA
	DCA SWITCH
	JMP CONTIN
	TAD SAVE
	TAD ALFCK
	SZA CLA
	JMP .+3
	DCA SWITCH
	JMP CONTIN
	TAD SWITCH
	SZA CLA
	JMP ISNO
ALPH,	TAD SAVE
	TAD I ALFA
	SZA CLA
	JMP .+4
	DCA SWITCH
	TAD ASCII
	JMP PRINTN
	ISZ ASCII
	ISZ TABCNT
	JMP ALPH
	TAD ACHAR
	DCA ASCII
	TAD CNTFX
	DCA TABCNT
NEWALF,	TAD SAVE
	TAD I ALFA
	SZA CLA
	JMP .+4
	DCA SWITCH
	TAD I ASCII
	JMP PRINTN
	ISZ ASCII
	ISZ TABCNT
	JMP NEWALF
	JMP CONTIN
ISNO,	TAD SAVE
	TAD I NUMB
	SZA CLA
	JMP .+5
	CMA
	DCA SWITCH
	TAD ASCNO
	JMP PRINTN
	ISZ ASCNO
	ISZ CNT1
	JMP ISNO
	TAD CHANGE
	DCA NEWALF +4
	JMP ALPH
PRINTN,	JMS PRINT
	ISZ CNTRL2
	JMP CONTIN

TABFIX,	TABFX1
CHANGE,	7000
NUM,	7606
ASCNO,	0
CNT1,	0
ALFCK,	7604
ASCII,	0
TABCNT,	0
CNTFX,	7765/NO OF SPECIAL CHARS
ACHAR,	700 /ADDR OF 1ST ASCII CHAR
CNTRL,	0
CNTRL2,	0
SWITCH,	0
MASK,	0177
EIATR,	7601
TEST1,	7766


	*600
TABFX1,	0
	TAD ACSET /260
	DCA I ASCNO1
	TAD NUMSET
	DCA NUMB
	TAD I TEST2
	DCA I CNT12
	TAD FRIALF
	DCA ALFA
	TAD ASCIIX
	DCA I ASCII1
	TAD CNTFX2
	DCA I TBCNT
	TAD CHG
	DCA I NEW4
	JMP I TABFX1
NUMSET,	757/ADDR -1 FRIDEN NOS
FRIALF,	712/ADDR -1 FRIDEN CHARS
ACSET,	260
ASCIIX,	301
CNTFX2,	7746
ASCNO1,	ASCNO
TEST2,	TEST1
CNT12,	CNT1
ASCII1,	ASCII
TBCNT,	TABCNT
CHG,	DCA SWITCH
NEW4,	NEWALF +4

	*700
/ASCII CHARS - SPECIAL
	211 /TAB
	240 /SPACE
	256 /PERIOD
	254 /COMMA
	253 /PLUS
	255 /MINUS
	257 /SLASH
	244 /$
	252 /*
	275 /EQUALS
	377 /RUBOUT
/FRIDEN CHARS
	7637;7636;7615;7634;7613;7612;7631;7630;7607;7657
	7656;7675;7654;7673;7672;7651;7650;7667;7716;7735
	7714;7733;7732;7711;7710;7727;7702;7760;7625;7705
	7620;7700;7717;7774;7770;7753;7776

/FRIDEN NOS
	7740;7777;7776;7755;7774;7753;7752;7771;7770;7747

	*016
NUMB,	0
ALFA,	0

	*065
READ,	0
	KSF
	JMP.-1
	KRB
	AND I MASK1
	DCA SAVE
	JMP I READ
PRINT,	0
	TSF
	JMP.-1
	TLS
	CLA
	JMP I PRINT
CRLF,	0
	TAD CR
	JMS PRINT
	TAD LF
	JMS PRINT
	JMP I CRLF
CR,	215
LF,	212
LDTR,	0
	TAD LDR
	JMS PRINT
	ISZ CNT2
	JMP .-3
	ISZ CNT
	TAD CNT2FX
	DCA CNT2
	JMP I LDTR
LDR,	0200
SAVE,	0
CNT,	0
CNT2FX,	7704
CNT2,	7704
MASK1,	MASK

	$

/=0211

