                                                             /
/  SAMPLE PROBLEM USING TRIPLE PRECISION PACKAGE
/
/   MORTGAGE CALCULATION
/
/   TYPE IN PRINCIPLE IN DOLLARS AND CENTS (2000000=$20,000.00)
/  TYPE IN YEARLY INTEREST PERCENTAGE TIMES 100
/  EG 4-1/4% = 425
/     10% = 1000
/   TYPE IN MONTHLY PAYMENT IN DOLLARS AND CENTS
/
/   DEFINE 36 BIT ACCUMULATOR
ACH=40
ACM=41
ACL=42
/   DEFINE 36 BIT MULTIPLIER QUOTIENT REGISTER
MQH=43
MQM=44
MQL=45
/   DEFINE LINKAGE LOCATIONS FOR TRANSFERS
MULT=53
DIVD=54
ADD=55
SUB=56
OUT=57
IN=60
/
STRT, CLA CLL
TAD CR   /RETURN CARRIGE
JMS TYPE
TAD LF
JMS TYPE
JMS I IN /OBTAIN PRINCIPLE
JMS STO
PRIN
JMS I IN /OBTAIN PERCENTAGE INTEREST
JMS STO
PINT
JMS I IN /OBTAIN MONTHLY PAYMENT
JMS STO
PYMT
DCA TOTL /ZERO TOTAL PAID
DCA TOTL+1
DCA TOTL+2
/   NOW TYPE OUT A HEADING
TAD ACHR
DCA 10
TAD CHRC
DCA TEMP
TAD I 10
JMS TYPE
ISZ TEMP
JMP .-3
/   THE COMPUTATION NOW BEGINS
MORE, CLA
TAD CR  /RETURN CARRIGE
JMS TYPE
TAD CR
JMS TYPE
TAD LF
JMS TYPE
TAD PRIN  /HAS PRINCIPLE GONE NEGATIVE
SPA
JMP HALT /YES ... OVER 
CLA
TAD PRIN /MOVE PRINCIPLE TO MQ REGISTER
DCA MQH
TAD PRIN+1
DCA MQM
TAD PRIN+2
DCA MQL
JMS I MULT /MULTIPLY BY INTEREST PERCENTAGE
PINT
JMS I DIVD /DIVIDE BY 120000 TO LINE UP DECIMAL POINT
TWLV       /AND BECAUSE 12 MONTHS IN A YEAR
CLA
TAD MQH    /MOVE RESULT TO STORAGE
DCA AINT
TAD MQM
DCA AINT+1
TAD MQL
DCA AINT+2
JMS I OUT /CONVERT TO DECIMAL AND TYPE PRINCIPLE
PRIN
JMS I OUT /CONVERT AND TYPE OUT AMOUNT INTEREST
AINT
CLA
DCA ACH /CLEAR 36 BIT AC
DCA ACM
DCA ACL
JMS I ADD /PAYMENT
PYMT
JMS I SUB /-AMOUNT OF INTEREST
AINT
JMS STO /TO A TEMPORARY
TEMP
JMS I OUT /CONVERT AND TYPE APPLIED PAYMENT
TEMP
CLA
DCA ACH /CLEAR 36 BIT ACCUMULATOR
DCA ACM
DCA ACL
JMS I ADD /PRINCIPLE
PRIN
JMS I SUB /-APPLED PAYMENT
TEMP
JMS STO /GIVES NEW PRINCIPLE
PRIN
JMS I OUT /CONVERT AND TYPE NEW PRINCIPLE
PRIN
CLA
DCA ACH /CLEAR 36 BIT AC
DCA ACM
DCA ACL
JMS I ADD /TOTAL PAID
TOTL
JMS I ADD /+THIS PAYMENT
PYMT
JMS STO
TOTL
JMS I OUT /TYPE TOTAL PAID
TOTL
JMP MORE
/
STO, 0 /SUBROUTINE TO STORE A 36 BIT NUMBER
CLA
TAD I STO
DCA ERAS
TAD ACH
DCA I ERAS
ISZ ERAS
TAD ACM
DCA I ERAS
ISZ ERAS
TAD ACL
DCA I ERAS
ISZ STO
JMP I STO
/
TYPE, 0 /TYPE A CHAR
TSF
JMP .-1
TLS
CLA 
JMP I TYPE
/
/   VARIABLE STORAGE
/
*100
PRIN, 0 /PRINCIPLE
0
0
PYMT, 0 /PAYMENT
0
0
PINT, 0 /PERCENT INTEREST
0
0
AINT, 0 /AMOUNT INTEREST
0
0
TOTL, 0 /TOTAL PAID
0
0
CR, 215
LF, 212
ACHR, 377
CHRC, 0-76
TWLV, 0 /120000 DECIMAL
35
2300
TEMP, 0
0
0
*375
ERAS, 0
HALT, HLT
JMP STRT
*400
215
212
240
240
240
240
240
302
301
314
301
316
303
305
240
240
240
240
311
316
324
305
322
305
323
324
240
240
240
301
320
320
314
240
320
331
315
324
240
240
240
240
240
302
301
314
301
316
303
305
240
240
240
324
317
324
314
240
320
301
311
304
$
                                                             